Implement the downloads in progress at exit dialog for Mac

chrome/browser/app_controller_mac.mm

 // Copyright (c) 2009 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/app_controller_mac.h"
 
+#include "app/l10n_util.h"
 #include "base/command_line.h"
+#include "base/mac_util.h"
 #include "base/message_loop.h"
 #include "base/sys_string_conversions.h"
 #include "chrome/app/chrome_dll_resource.h"
 #include "chrome/browser/browser.h"
 #include "chrome/browser/browser_init.h"
 #include "chrome/browser/browser_list.h"
 #include "chrome/browser/browser_process.h"
 #include "chrome/browser/browser_shutdown.h"
 #include "chrome/browser/browser_window.h"
 #import "chrome/browser/cocoa/about_window_controller.h"
 #import "chrome/browser/cocoa/bookmark_menu_bridge.h"
 #import "chrome/browser/cocoa/history_menu_bridge.h"
 #import "chrome/browser/cocoa/clear_browsing_data_controller.h"
 #import "chrome/browser/cocoa/encoding_menu_controller_delegate_mac.h"
 #import "chrome/browser/cocoa/preferences_window_controller.h"
 #import "chrome/browser/cocoa/tab_strip_controller.h"
 #import "chrome/browser/cocoa/tab_window_controller.h"
 #include "chrome/browser/command_updater.h"
+#include "chrome/browser/download/download_manager.h"
 #include "chrome/browser/sessions/tab_restore_service.h"
 #include "chrome/common/pref_names.h"
 #include "chrome/common/pref_service.h"
 #include "chrome/browser/profile_manager.h"
 #include "chrome/common/temp_scaffolding_stubs.h"
+#include "grit/generated_resources.h"
 #import "xib_localizers/main_menu_localizer.h"
 
 @interface AppController(PRIVATE)
 - (void)initMenuState;
 - (void)openURLs:(const std::vector<GURL>&)urls;
 - (void)openPendingURLs;
 - (void)getUrl:(NSAppleEventDescriptor*)event
      withReply:(NSAppleEventDescriptor*)reply;
 - (void)openFiles:(NSAppleEventDescriptor*)event
         withReply:(NSAppleEventDescriptor*)reply;
 - (void)windowLayeringDidChange:(NSNotification*)inNotification;
+- (BOOL)shouldQuitWithInProgressDownloads;
 @end
 
 @implementation AppController
 
 // This method is called very early in application startup (ie, before
 // the profile is loaded or any preferences have been registered). Defer any
 // user-data initialization until -applicationDidFinishLaunching:.
 - (void)awakeFromNib {
   pendingURLs_.reset(new std::vector<GURL>());
 
@@ skipping 183 matching lines @@
   // Build up the encoding menu, the order of the items differs based on the
   // current locale (see http://crbug.com/7647 for details).
   // We need a valid g_browser_process to get the profile which is why we can't
   // call this from awakeFromNib.
   EncodingMenuControllerDelegate::BuildEncodingMenu([self defaultProfile]);
 
   // Now that we're initialized we can open any URLs we've been holding onto.
   [self openPendingURLs];
 }
 
+// Check all browsers for in progress downloads, and if we find any, prompt the
+// user to see if we should continue to exit (and thus cancel the downloads), or
+// if we should wait.
+- (BOOL)shouldQuitWithInProgressDownloads {
+  BrowserList::const_iterator it = BrowserList::begin();
+  for (; it != BrowserList::end(); ++it) {
+    Browser* browser = *it;
+    Profile* profile = browser->profile();
+    if (!profile)
+      continue;
+
+    DownloadManager* download_manager = profile->GetDownloadManager();
+    if (!download_manager || download_manager->in_progress_count() == 0)
+      continue;
+
+    // There are downloads in progress so run the dialog asking if we should
+    // exit. There can be multiple windows (i.e. browsers) open, but we don't
+    // want to prompt for each one. Use the first browser with downloads in
+    // progress.
+    NSString* descriptionText = nil;
+    NSString* waitButton = nil;
+    NSString* exitButton = nil;
+
+    // Set the dialog text based on whether or not there are multiple downloads.
+    if (download_manager->in_progress_count() == 1) {
+      // Dialog text.
+      descriptionText =
+          base::SysWideToNSString(
+              l10n_util::GetString(IDS_SINGLE_DOWNLOAD_REMOVE_CONFIRM_TITLE));
+
+      // Cancel downloads and exit button text.
+      exitButton =
+          base::SysWideToNSString(
+              l10n_util::GetString(
+                  IDS_SINGLE_DOWNLOAD_REMOVE_CONFIRM_OK_BUTTON_LABEL));
+
+      // Wait for downloads button text.
+      waitButton =
+          base::SysWideToNSString(
+              l10n_util::GetString(
+                  IDS_SINGLE_DOWNLOAD_REMOVE_CONFIRM_CANCEL_BUTTON_LABEL));
+    } else {
+      // Dialog text.
+      descriptionText =
+          base::SysWideToNSString(
+              l10n_util::GetStringF(IDS_MULTIPLE_DOWNLOADS_REMOVE_CONFIRM_TITLE,
+                                    download_manager->in_progress_count()));
+
+      // Cancel downloads and exit button text.
+      exitButton =
+          base::SysWideToNSString(
+              l10n_util::GetString(
+                  IDS_MULTIPLE_DOWNLOADS_REMOVE_CONFIRM_OK_BUTTON_LABEL));
+
+      // Wait for downloads button text.
+      waitButton =
+          base::SysWideToNSString(
+              l10n_util::GetString(
+                  IDS_MULTIPLE_DOWNLOADS_REMOVE_CONFIRM_CANCEL_BUTTON_LABEL));
+    }
+
+    // 'waitButton' is the default choice.
+    int choice = NSRunAlertPanel(nil, descriptionText,
+                                 waitButton, exitButton, nil);
+    if (choice == NSAlertDefaultReturn) {
+      // We're not going to exit, so show the user the download page so they can
+      // see the in progress downloads.
+      browser->ShowDownloadsTab();
+      return NO;
+    }
+    break;
+  }
+
+  // Okay to exit.
+  return YES;
+}
+
 // We can't use the standard terminate: method because it will abruptly exit
 // the app and leave things on the stack in an unfinalized state. We need to
 // post a quit message to our run loop so the stack can gracefully unwind.
 - (IBAction)quit:(id)sender {
   // TODO(pinkerton):
   // since we have to roll it ourselves, ask the delegate (ourselves, really)
   // if we should terminate. For example, we might not want to if the user
   // has ongoing downloads or multiple windows/tabs open. However, this would
   // require posting UI and may require spinning up another run loop to
   // handle it. If it says to continue, post the quit message, otherwise
   // go back to normal.
 
+  // Check for in-progress downloads, and prompt the user if they really want to
+  // quit (and thus cancel the downloads).
+  if (![self shouldQuitWithInProgressDownloads])
+    return;

[Nico, 2009/08/04 04:26:07]

Isn't this something that should be done in |applicationShouldTerminate:|? I'm
asking because I'm about to add something there, and I'm wondering if there's a
problem with this method in chromiume.

+
   NSAppleEventManager* em = [NSAppleEventManager sharedAppleEventManager];
   [em removeEventHandlerForEventClass:kInternetEventClass
                            andEventID:kAEGetURL];
   [em removeEventHandlerForEventClass:'WWW!'
                            andEventID:'OURL'];
   [em removeEventHandlerForEventClass:kCoreEventClass
                            andEventID:kAEOpenDocuments];
 
   // TODO(pinkerton): Not sure where this should live, including it here
   // causes all sorts of asserts from the open renderers. On Windows, it
@@ skipping 261 matching lines @@
                name:kUserClosedAboutNotification
              object:aboutController_.get()];
   }
   if (![[aboutController_ window] isVisible])
     [[aboutController_ window] center];
   [aboutController_ showWindow:self];
 #endif
 }
 
 @end