Follow El Capitan Dock settings for double-click in window title bar.

ui/base/cocoa/appkit_utils.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/base/cocoa/appkit_utils.h"
 
 #include "base/mac/mac_util.h"
 #include "ui/base/resource/resource_bundle.h"
 
 namespace {
 
 // Gets an NSImage given an image id.
 NSImage* GetImage(int image_id) {
   return ui::ResourceBundle::GetSharedInstance().GetNativeImageNamed(image_id)
       .ToNSImage();
 }
 
-// Whether windows should miniaturize on a double-click on the title bar.
-bool ShouldWindowsMiniaturizeOnDoubleClick() {
-  // We use an undocumented method in Cocoa; if it doesn't exist, default to
-  // |true|. If it ever goes away, we can do (using an undocumented pref key):
-  //   NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
-  //   return ![defaults objectForKey:@"AppleMiniaturizeOnDoubleClick"] ||
-  //          [defaults boolForKey:@"AppleMiniaturizeOnDoubleClick"];
+// Double-click in window title bar actions.
+const int kNoAction = 0;

[tapted, 2016/01/21 00:27:20]

enum class DoubleClickAction {
  NONE,
  MINIMIZE,
  MAXIMIZE,
};

? It's a bit more verbose, but it feels unusual to use integer constants for
this :/

Then the switch can have a `case DoubleClickAction::NONE:` instead of a
`default` case (the advantage - [in general - it's a stretch to apply it here]
would be that adding a possible action to the enum would result in compile
errors in any switch statement that didn't handle it).

[shrike, 2016/01/21 00:52:50]

This is great, actually. I wasn't sure of the right way to declare these
symbols. I like that it means generating an error in the switch statement if
more items get added to the enum, and in my own code I prefer labels like
DoubleClickActionNone, DoubleClickActionMinimize - that's not the convention in
Chrome, but declaring the enum this way gets me the equivalent.

+const int kMinimize = 1;
+const int kMaximize = 2;
+
+// The action to take when the user double-clicks in the window title bar.
+int WindowTitleBarDoubleClickAction() {
+  // El Capitan introduced a Dock preference to configure the window title bar
+  // double-click action (Minimize, Maximize, or nothing).
+  if (base::mac::IsOSElCapitanOrLater()) {
+    NSString* doubleClickAction = [[NSUserDefaults standardUserDefaults]
+                                      objectForKey:@"AppleActionOnDoubleClick"];
+
+    if ([doubleClickAction isEqualToString:@"Minimize"]) {
+      return kMinimize;
+    } else if ([doubleClickAction isEqualToString:@"Maximize"]) {
+      return kMaximize;
+    }
+
+    return kNoAction;
+  }
+
+  // Determine minimize using an undocumented method in Cocoa. If we're
+  // running on an earlier version of the OS that doesn't implement it,
+  // just default to the minimize action.
   BOOL methodImplemented =
       [NSWindow respondsToSelector:@selector(_shouldMiniaturizeOnDoubleClick)];
-  DCHECK(methodImplemented);
-  return !methodImplemented ||
-         [NSWindow performSelector:@selector(_shouldMiniaturizeOnDoubleClick)];
+  if (!methodImplemented ||
+      [NSWindow performSelector:@selector(_shouldMiniaturizeOnDoubleClick)]) {
+    return kMinimize;
+  }
+
+  // At this point _shouldMiniaturizeOnDoubleClick has returned |NO|. On
+  // Yosemite, that means a double-click should Maximize the window, and on
+  // all prior OSes a double-click should do nothing.
+  return base::mac::IsOSYosemite() ? kMaximize : kNoAction;
 }
 
 }  // namespace
 
 namespace ui {
 
 void DrawNinePartImage(NSRect frame,
                        const NinePartImageIds& image_ids,
                        NSCompositingOperation operation,
                        CGFloat alpha,
                        BOOL flipped) {
   NSDrawNinePartImage(frame,
                       GetImage(image_ids.top_left),
                       GetImage(image_ids.top),
                       GetImage(image_ids.top_right),
                       GetImage(image_ids.left),
                       GetImage(image_ids.center),
                       GetImage(image_ids.right),
                       GetImage(image_ids.bottom_left),
                       GetImage(image_ids.bottom),
                       GetImage(image_ids.bottom_right),
                       operation,
                       alpha,
                       flipped);
 }
 
 void WindowTitlebarReceivedDoubleClick(NSWindow* window, id sender) {
-  if (ShouldWindowsMiniaturizeOnDoubleClick()) {
-    [window performMiniaturize:sender];
-  } else if (base::mac::IsOSYosemiteOrLater()) {
-    [window performZoom:sender];
+  switch (WindowTitleBarDoubleClickAction()) {
+    case kMinimize:
+      [window performMiniaturize:sender];
+      break;
+
+    case kMaximize:
+      [window performZoom:sender];
+      break;
+
+    default:
+      break;
   }
 }
 
 }  // namespace ui