Plumb system_libdir variable from GN to pkg-config.py

build/config/linux/pkg_config.gni

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/sysroot.gni")
 
 # Defines a config specifying the result of running pkg-config for the given
 # packages. Put the package names you want to query in the "packages" variable
 # inside the template invocation.
 #
@@ skipping 13 matching lines @@
 # when doing manual dynamic linking), set:
 #   ignore_libs = true
 
 declare_args() {
   # A pkg-config wrapper to call instead of trying to find and call the right
   # pkg-config directly. Wrappers like this are common in cross-compilation
   # environments.
   # Leaving it blank defaults to searching PATH for 'pkg-config' and relying on
   # the sysroot mechanism to find the right .pc files.
   pkg_config = ""
+
+  # CrOS systemroots place pkgconfig files at <systemroot>/usr/share/pkgconfig
+  # and one of <systemroot>/usr/lib/pkgconfig or <systemroot>/usr/lib64/pkgconfig
+  # depending on whether the systemroot is for a 32 or 64 bit architecture.
+  #
+  # When build under GYP, CrOS board builds specify the 'system_libdir' variable
+  # as part of the GYP_DEFINES provided by the CrOS emerge build or simple
+  # chrome build scheme. This variable permits controlling this for GN builds
+  # in similar fashion by setting the `system_libdir` variable in the build's
+  # args.gn file to 'lib' or 'lib64' as appropriate for the target architecture.
+  system_libdir = "lib"
 }
 
 pkg_config_script = "//build/config/linux/pkg-config.py"
 
 # Define the args we pass to the pkg-config script for other build files that
 # need to invoke it manually.
 if (sysroot != "") {
   # Pass the sysroot if we're using one (it requires the CPU arch also).
   pkg_config_args = [
     "-s",
     sysroot,
     "-a",
     current_cpu,
+    "--system_libdir",
+    system_libdir,
   ]
 } else if (pkg_config != "") {
   pkg_config_args = [
     "-p",
     pkg_config,
+    "--system_libdir",
+    system_libdir,
   ]
 } else {
   pkg_config_args = []
 }
 
 template("pkg_config") {
   assert(defined(invoker.packages),
          "Variable |packages| must be defined to be a list in pkg_config.")
   config(target_name) {
     args = pkg_config_args + invoker.packages
@@ skipping 11 matching lines @@
       ldflags = pkgresult[4]
     }
 
     forward_variables_from(invoker,
                            [
                              "defines",
                              "visibility",
                            ])
   }
 }