Suppress AppKit error message about adding an unknown subview.

chrome/browser/ui/cocoa/full_size_content_window.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/full_size_content_window.h"
 
 #include "base/logging.h"
 #include "base/mac/foundation_util.h"
+#include "base/mac/scoped_objc_class_swizzler.h"
 
 @interface FullSizeContentWindow ()
 
 + (BOOL)shouldUseFullSizeContentViewForStyle:(NSUInteger)windowStyle;
 
 @end
 
 // This view always takes the size of its superview. It is intended to be used
 // as a NSWindow's contentView.  It is needed because NSWindow's implementation
 // explicitly resizes the contentView at inopportune times.
@@ skipping 18 matching lines @@
 }
 
 - (void)forceFrame:(NSRect)frame {
   forceFrameFlag_ = YES;
   [super setFrame:frame];
   forceFrameFlag_ = NO;
 }
 
 @end
 
+static BOOL disableSymbolication = NO;

[Robert Sesek, 2016/01/05 22:17:00]

naming: g_disable_symbolication, same as below

[shrike, 2016/01/05 22:53:01]

Thank you - I had looked for the naming convention for globals but couldn't find
it.

The IMP below it is also a static - I preprended "g_" but wasn't sure if I
should do anything else to it. The g_ makes it not want to be camel case but
it's an ObjectiveC variable type in an ObjectiveC chunk of code. Or should maybe
it be gOriginalDescriptionWithLocaleImplementation?

+static IMP originalDescriptionWithLocaleImplementation;
+
+@interface FullSizeContentWindowSwizzlingSupport : NSObject
+@end
+
+@implementation FullSizeContentWindowSwizzlingSupport
+
+// This method replaces [_NSCallStackArray descriptionWithLocale:indent:] via
+// swizzling - see +load below.
+- (NSString*)descriptionWithLocale:(id)aLocale
+                            indent:(unsigned long long)indent {
+  return disableSymbolication ?
+    @"" :
+    originalDescriptionWithLocaleImplementation(
+        self, @selector(descriptionWithLocale:indent:), aLocale, indent);
+}
+
+@end
+
 @implementation FullSizeContentWindow
 
 #pragma mark - Lifecycle
 
+// In initWithContentRect:styleMask:backing:defer:, the call to
+// [NSView addSubview:positioned:relativeTo:] causes NSWindow to complain that
+// an unknown view is being added to it, and to generate a stack trace.
+// Not only does this stack trace pollute the console, it can also take hundreds
+// of milliseconds to generate (because of symbolication). The AppKit uses an
+// _NSCallStackArray to dump the symbols to the console - by swizzling
+// descriptionWithLocale:indent: we can disable this output. See
+// crbug.com/520373 .
++ (void)load {

[Robert Sesek, 2016/01/05 22:16:59]

Can you limit this to just the browser process, like here:

https://code.google.com/p/chromium/codesearch#chromium/src/chrome/browser/ui/...

[shrike, 2016/01/05 22:53:01]

Thank you. I wondered about this but didn't see how to tell so early on if the
process was browser or renderer.

+  static dispatch_once_t onceToken;
+  dispatch_once(&onceToken, ^{
+    Class callStackArrayClass = NSClassFromString(@"_NSCallStackArray");
+    Class swizzleClass = [FullSizeContentWindowSwizzlingSupport class];
+    SEL targetSelector = @selector(descriptionWithLocale:indent:);
+
+    if (callStackArrayClass) {
+      CR_DEFINE_STATIC_LOCAL(base::mac::ScopedObjCClassSwizzler,
+                             callStackSuppressor, (callStackArrayClass,
+                             swizzleClass, targetSelector));
+      originalDescriptionWithLocaleImplementation =
+          callStackSuppressor.GetOriginalImplementation();
+    }
+  });
+}
+
 - (instancetype)init {
   NOTREACHED();
   return nil;
 }
 
 - (instancetype)initWithContentRect:(NSRect)contentRect
                           styleMask:(NSUInteger)windowStyle
                             backing:(NSBackingStoreType)bufferingType
                               defer:(BOOL)deferCreation {
   return [self initWithContentRect:contentRect
@@ skipping 19 matching lines @@
       chromeWindowView_.reset([[FullSizeContentView alloc] init]);
       [chromeWindowView_
           setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
       [self setContentView:chromeWindowView_];
       [chromeWindowView_ setFrame:[[chromeWindowView_ superview] bounds]];
 
       // Our content view overlaps the window control buttons, so we must ensure
       // it is positioned below the buttons.
       NSView* superview = [chromeWindowView_ superview];
       [chromeWindowView_ removeFromSuperview];
+
+      // Prevent the AppKit from generating a backtrace to include in it's
+      // complaint about our upcoming call to addSubview:positioned:relativeTo:.
+      // See +load for more info.
+      disableSymbolication = YES;

[Robert Sesek, 2016/01/05 22:16:59]

You can use base::AutoReset<BOOL>

[shrike, 2016/01/05 22:53:01]

Thank you again! I wondered if there was a mechanism like this to guard against
forgetting to reset the bool.

+
       [superview addSubview:chromeWindowView_
                  positioned:NSWindowBelow
                  relativeTo:nil];
+
+      // Clean up from the AppKit console message workaround.
+      disableSymbolication = NO;
     }
   }
   return self;
 }
 
 - (void)forceContentViewFrame:(NSRect)frame {
   FullSizeContentView* contentView =
       base::mac::ObjCCast<FullSizeContentView>(chromeWindowView_);
   [contentView forceFrame:frame];
 }
@@ skipping 24 matching lines @@
   return [super contentRectForFrameRect:fRect styleMask:aStyle];
 }
 
 - (NSRect)contentRectForFrameRect:(NSRect)frameRect {
   if (chromeWindowView_)
     return frameRect;
   return [super contentRectForFrameRect:frameRect];
 }
 
 @end