Port android_webview_tests.gypi to GN.

android_webview/test/BUILD.gn

+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/android/rules.gni")
+import("//testing/test.gni")
+
+# Mark all targets as test only.
+testonly = true
+
+group("test") {
+  deps = [
+    ":android_webview_test_apk",
+    ":android_webview_unittests",
+  ]
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:android_webview_apk
+android_apk("android_webview_apk") {
+  deps = [
+    ":android_webview_apk_assets",
+    ":android_webview_apk_resources",
+    ":libdrawgl",
+    ":libstandalonelibwebviewchromium",
+    "//android_webview:android_webview_java",
+    "//base:base_java",
+    "//base:base_java_test_support",
+    "//components/policy/android:policy_java_test_support",
+    "//content/public/android:content_java",
+    "//ui/android:ui_java",
+  ]
+
+  apk_name = "AndroidWebView"
+  android_manifest = "shell/AndroidManifest.xml"
+  DEPRECATED_java_in_dir = "shell/src"
+  native_libs = [
+    "libdrawgl.so",
+    "libstandalonelibwebviewchromium.so",
+  ]
+
+  native_lib_version_rule = "//build/util:chrome_version_json"
+  _native_lib_file =
+      rebase_path("$root_gen_dir/CHROME_VERSION.json", root_build_dir)
+  native_lib_version_arg = "@FileArg($_native_lib_file:full-quoted)"
+
+  extensions_to_not_compress = ".dat,.bin,.pak,.lpak"
+}
+
+android_resources("android_webview_apk_resources") {
+  resource_dirs = [ "shell/res" ]
+  custom_package = "org.chromium.android_webview.shell"
+}
+
+android_assets("android_webview_apk_assets") {
+  deps = [
+    "//android_webview:pak_file_assets",
+    "//third_party/icu:icu_assets",
+    "//v8:v8_external_startup_data_assets",
+  ]
+  sources = [
+    "shell/assets/asset_file.html",
+    "shell/assets/asset_icon.png",
+    "shell/assets/cookie_test.html",
+    "shell/assets/full_screen_video.js",
+    "shell/assets/full_screen_video_inside_div_test.html",
+    "shell/assets/full_screen_video_test.html",
+    "shell/assets/multiple_videos_test.html",
+    "shell/assets/video.mp4",
+    "shell/assets/visual_state_during_fullscreen_test.html",
+    "shell/assets/visual_state_on_page_commit_visible_test.html",
+    "shell/assets/visual_state_waits_for_js_detached_test.html",
+    "shell/assets/visual_state_waits_for_js_test.html",
+  ]
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:libstandalonelibwebviewchromium
+shared_library("libstandalonelibwebviewchromium") {
+  sources = [
+    "../lib/main/webview_entry_point.cc",
+  ]
+  ldflags = [ "-Wl,-shared,-Bsymbolic" ]
+  deps = [
+    "//android_webview:common",
+  ]
+  configs -= [ "//build/config/android:hide_native_jni_exports" ]
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:android_webview_test_apk
+instrumentation_test_apk("android_webview_test_apk") {
+  apk_name = "AndroidWebViewTest"
+  apk_under_test = ":android_webview_apk"
+  android_manifest = "../javatests/AndroidManifest.xml"
+  deps = [
+    "//android_webview:android_webview_java",
+    "//base:base_java",
+    "//base:base_java_test_support",
+    "//components/external_video_surface:java",
+    "//components/policy/android:policy_java",
+    "//components/policy/android:policy_java_test_support",
+    "//components/web_contents_delegate_android:web_contents_delegate_android_java",
+    "//content/public/android:content_java",
+    "//content/public/test/android:content_java_test_support",
+    "//net/android:net_java",
+    "//net/android:net_java_test_support",
+    "//third_party/android_tools:legacy_http_javalib",
+    "//ui/android:ui_java",
+  ]
+  DEPRECATED_java_in_dir = "../javatests/src"
+  isolate_file = "../android_webview_test_apk.isolate"
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:android_webview_unittests
+test("android_webview_unittests") {
+  deps = [
+    ":android_webview_unittests_assets",
+    ":android_webview_unittests_java",
+    ":android_webview_unittests_jni",
+    "//android_webview:common",
+    "//base/test:test_support",
+    "//content/test:test_support",
+    "//net:test_support",
+    "//ui/base:ui_base_jni_headers",
+    "//ui/gl",
+    "//ui/gl:test_support",
+  ]
+
+  sources = [
+    "../browser/aw_form_database_service_unittest.cc",
+    "../browser/aw_static_cookie_policy_unittest.cc",
+    "../browser/browser_view_renderer_unittest.cc",
+    "../browser/net/android_stream_reader_url_request_job_unittest.cc",
+    "../browser/net/input_stream_reader_unittest.cc",
+    "../browser/test/fake_window.cc",
+    "../browser/test/fake_window.h",
+    "../browser/test/rendering_test.cc",
+    "../browser/test/rendering_test.h",
+    "../lib/main/webview_tests.cc",
+    "../native/aw_contents_client_bridge_unittest.cc",
+    "../native/aw_media_url_interceptor_unittest.cc",
+    "../native/input_stream_unittest.cc",
+    "../native/permission/media_access_permission_request_unittest.cc",
+    "../native/permission/permission_request_handler_unittest.cc",
+    "../native/state_serializer_unittest.cc",
+  ]
+}
+
+android_assets("android_webview_unittests_assets") {
+  sources = [
+    "unittest/assets/asset_file.ogg",
+  ]
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:android_webview_unittests_java
+android_library("android_webview_unittests_java") {
+  deps = [
+    "//android_webview:android_webview_java",
+    "//base:base_java",
+    "//base:base_java_test_support",
+    "//content/public/test/android:content_java_test_support",
+  ]
+  DEPRECATED_java_in_dir = "../unittestjava/src"
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:android_webview_unittests_jni
+generate_jni("android_webview_unittests_jni") {
+  jni_package = "android_webview_unittests"
+  sources = [
+    "../unittestjava/src/org/chromium/android_webview/unittest/InputStreamUnittest.java",
+    "../unittestjava/src/org/chromium/android_webview/unittest/MockAwContentsClientBridge.java",
+  ]
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:libdrawgl
+shared_library("libdrawgl") {
+  sources = [
+    "shell/src/draw_gl/draw_gl.cc",
+  ]
+  configs -= [ "//build/config/android:hide_native_jni_exports" ]
+}