Fix RTL issues in javascript alerts.

chrome/browser/ui/cocoa/javascript_app_modal_dialog_cocoa.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/ui/cocoa/javascript_app_modal_dialog_cocoa.h"
 
 #import <Cocoa/Cocoa.h>
 
+#include "base/i18n/rtl.h"
 #include "base/logging.h"
+#import "base/mac/foundation_util.h"
 #include "base/strings/sys_string_conversions.h"
 #import "chrome/browser/chrome_browser_application_mac.h"
 #include "chrome/browser/ui/app_modal_dialogs/javascript_app_modal_dialog.h"
 #include "grit/generated_resources.h"
 #include "grit/ui_strings.h"
 #include "ui/base/l10n/l10n_util_mac.h"
 #include "ui/base/ui_base_types.h"
 
 // Helper object that receives the notification that the dialog/sheet is
 // going away. Is responsible for cleaning itself up.
@@ skipping 115 matching lines @@
 
   // Show the modal dialog.
   alert_ = [helper_ alert];
   NSTextField* field = nil;
   if (text_field) {
     field = [helper_ textField];
     [field setStringValue:base::SysUTF16ToNSString(
         dialog_->default_prompt_text())];
   }
   [alert_ setDelegate:helper_];
-  [alert_ setInformativeText:base::SysUTF16ToNSString(dialog_->message_text())];
+  NSString* informative_text =
+      base::SysUTF16ToNSString(dialog_->message_text());
+  [alert_ setInformativeText:informative_text];
   [alert_ setMessageText:base::SysUTF16ToNSString(dialog_->title())];
   [alert_ addButtonWithTitle:default_button];
   if (!one_button) {
     NSButton* other = [alert_ addButtonWithTitle:other_button];
     [other setKeyEquivalent:@"\e"];
   }
   if (dialog_->display_suppress_checkbox()) {
     [alert_ setShowsSuppressionButton:YES];
     NSString* suppression_title = l10n_util::GetNSStringWithFixup(
         IDS_JAVASCRIPT_MESSAGEBOX_SUPPRESS_OPTION);
     [[alert_ suppressionButton] setTitle:suppression_title];
   }
+
+  // Fix RTL dialogs.
+  //
+  // Mac OS X will always display an NSAlert's informative text as LTR. A
+  // workaround is to manually set the informative text as an attributed string
+  // in the implementing NSTextField. This is a basic correctness issue.
+  //
+  // In addition, for readability, the overall alignment is set based on the
+  // directionality of the first strongly-directional character.
+  //
+  // See http://crbug.com/70806 for more details.
+
+  if (base::i18n::StringContainsStrongRTLChars(dialog_->message_text())) {
+    // Force layout of the dialog. NSAlert leaves its dialog alone once laid
+    // out; if this is not done then all the modifications that are to come will
+    // be un-done when the dialog is finally displayed.
+   [alert_ layout];

[Mark Mentovai, 2013/05/17 01:32:57]

The indentation is wrong on this line.

[Avi (use Gerrit), 2013/05/20 21:55:29]

Done.

+
+    // Locate the NSTextField that implements the informative text. This is
+    // actually available as the ivar |_informationField| of the NSAlert, but it
+    // is safer (and more forward-compatible) to search for it in the subviews.
+    NSTextField* informative_text_field = nil;
+    for (NSView* view in [[[alert_ window] contentView] subviews]) {
+      NSTextField* text_field = base::mac::ObjCCast<NSTextField>(view);
+      if ([[text_field stringValue] isEqualTo:informative_text]) {
+        informative_text_field = text_field;
+        break;
+      }
+    }
+    // This may fail in future OS releases, but it will still work for shipped
+    // versions of Chromium.
+    DCHECK(informative_text_field);
+
+    if (informative_text_field) {
+      base::i18n::TextDirection direction =
+          base::i18n::GetFirstStrongCharacterDirection(dialog_->message_text());
+      scoped_nsobject<NSMutableParagraphStyle> alignment(
+          [[NSParagraphStyle defaultParagraphStyle] mutableCopy]);
+      [alignment setAlignment:
+          (direction == base::i18n::RIGHT_TO_LEFT) ? NSRightTextAlignment
+                                                   : NSLeftTextAlignment];

[jeremy, 2013/05/19 10:51:50]

Do you also need to manually set the directionality of the string  -
NSWritingDirectionAttributeName?

[Avi (use Gerrit), 2013/05/20 21:55:29]

It turns out that I don't need to.

As soon as you set the attributed string, even if it has no attributes, the
directionality magically starts working again.

+
+      NSDictionary* alignment_attributes =
+          @{ NSParagraphStyleAttributeName : alignment };
+      scoped_nsobject<NSAttributedString> attr_string(
+          [[NSAttributedString alloc] initWithString:informative_text
+                                          attributes:alignment_attributes]);
+
+      [informative_text_field setAttributedStringValue:attr_string];
+    }
+  }
 }
 
 JavaScriptAppModalDialogCocoa::~JavaScriptAppModalDialogCocoa() {
 }
 
 ////////////////////////////////////////////////////////////////////////////////
 // JavaScriptAppModalDialogCocoa, NativeAppModalDialog implementation:
 
 int JavaScriptAppModalDialogCocoa::GetAppModalDialogButtons() const {
   // From the above, it is the case that if there is 1 button, it is always the
@@ skipping 45 matching lines @@
 
 ////////////////////////////////////////////////////////////////////////////////
 // NativeAppModalDialog, public:
 
 // static
 NativeAppModalDialog* NativeAppModalDialog::CreateNativeJavaScriptPrompt(
     JavaScriptAppModalDialog* dialog,
     gfx::NativeWindow parent_window) {
   return new JavaScriptAppModalDialogCocoa(dialog);
 }