Add missing data_deps to webkit_unit_tests

third_party/WebKit/Source/web/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/ui.gni")
 import("//testing/test.gni")
 import("//third_party/WebKit/Source/bindings/bindings.gni")
 import("//third_party/WebKit/Source/config.gni")
 import("//third_party/WebKit/Source/core/core.gni")
 import("//third_party/WebKit/Source/modules/modules.gni")
@@ skipping 88 matching lines @@
 
 # TODO(GYP): Delete this after we've converted everything to GN.
 # The _run targets exist only for compatibility w/ GYP.
 group("webkit_unit_tests_run") {
   testonly = true
   deps = [
     ":webkit_unit_tests",
   ]
 }
 
+group("webkit_unit_tests_data") {
+  data = [
+    "tests/data/",
+    "../core/paint/test_data/",

[Dirk Pranke, 2015/12/10 17:28:36]

nit: these should be src-relative paths, like
//third_party/WebKit/Source/core/paint/test_data .

+
+    # Required by some image decoder tests.
+    "../platform/image-decoders/testing/",
+    "../../LayoutTests/fast/images/resources/",
+
+    # Required by some font tests.
+    "../platform/testing/data/",
+  ]
+}
+
 # GYP version: WebKit/Source/web/web_tests.gyp:webkit_unit_tests
 test("webkit_unit_tests") {
   visibility = []  # Allow re-assignment of list.
   visibility = [ "*" ]
 
   deps = [
     ":test_support",
     ":web",
     "//base",
     "//base:i18n",
     "//base/test:test_support",
     "//content/test:test_support",
     "//testing/gmock",
     "//testing/gtest",
     "//third_party/WebKit/Source/platform:test_support",
     "//third_party/WebKit/Source/wtf",
     "//third_party/WebKit/Source/wtf:test_support",
     "//third_party/libwebp",
     "//third_party/zlib",
     "//url",
     "//v8",
   ]
 
+  data_deps = [
+    "//content/shell:pak",
+    ":webkit_unit_tests_data",

[Dirk Pranke, 2015/12/10 17:28:36]

and the presubmit check should've complained that this was sorted wrong; maybe
there's a bug there where we're not sorting data_deps ...

+  ]
+
   sources = [
     "tests/RunAllTests.cpp",
   ]
 
   configs += [ "//third_party/WebKit/Source:config" ]
 
   if (!is_component_build) {
     deps += [ "//third_party/WebKit/Source/core" ]
 
     configs += [ "//third_party/WebKit/Source:inside_blink" ]
 
     sources += web_unittest_files
     sources += bindings_unittest_files
     sources += core_unittest_files
     sources += modules_unittest_files
     sources += platform_unittest_support_files
     sources += platform_web_unittest_files
   }
 
   if (is_android) {
     deps += [
       "//base:base_java",
       "//content/shell/android:content_shell_assets",
       "//net/android:net_java",
     ]
   }
 }