GN: Build nacl_helper_nonsfi unit tests

components/nacl/BUILD.gn

 # Copyright (c) 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//build/config/nacl/config.gni")
 import("//build/config/ui.gni")
 import("//testing/test.gni")
 
 if (enable_nacl) {
@@ skipping 161 matching lines @@
       "loader/run_all_unittests.cc",
     ]
 
     deps = [
       ":nacl",
       "//base/test:test_support",
       "//ipc:test_support",
       "//ppapi/c",
       "//testing/gtest",
     ]
+
+    if (is_nacl_nonsfi) {
+      sources += [
+        # TODO(hamaji): Currently, we build them twice. Stop building
+        # them for components_unittests. See crbug.com/364751
+        "loader/nonsfi/nonsfi_sandbox_sigsys_unittest.cc",
+        "loader/nonsfi/nonsfi_sandbox_unittest.cc",
+      ]
+
+      deps += [
+        ":nacl_linux",
+        "//sandbox/linux:sandbox_linux_test_utils",
+      ]
+    }
   }
 
   if (is_linux) {
     executable("nacl_helper") {
       sources = [
         "loader/nacl_helper_linux.cc",
         "loader/nacl_helper_linux.h",
       ]
 
       deps = [
@@ skipping 48 matching lines @@
       ]
 
       if (use_glib) {
         configs += [ "//build/config/linux:glib" ]
       }
 
       if (use_seccomp_bpf) {
         defines += [ "USE_SECCOMP_BPF" ]
       }
     }
+
+    test("nacl_helper_nonsfi_unittests") {
+      sources = [
+        "loader/nonsfi/nacl_helper_nonsfi_unittests.cc",
+      ]
+      deps = [
+        "//base",
+        "//base/test:test_launcher_nacl_nonsfi",
+      ]
+    }
   }
 
   if (is_nacl_nonsfi) {
     executable("nacl_helper_nonsfi_nexe") {
       output_name = "nacl_helper_nonsfi"
       set_sources_assignment_filter([])
       sources = [
         "common/nacl_messages.cc",
         "common/nacl_messages.h",
         "common/nacl_types.cc",
@@ skipping 45 matching lines @@
       sources = [
         "${root_out_dir}/nacl_helper_nonsfi",
       ]
       outputs = [
         "${root_build_dir}/{{source_file_part}}",
       ]
       deps = [
         ":nacl_helper_nonsfi_nexe",
       ]
     }
+
+    test("nacl_helper_nonsfi_unittests_main") {
+      sources = [
+        "loader/nonsfi/nonsfi_sandbox_sigsys_unittest.cc",
+        "loader/nonsfi/nonsfi_sandbox_unittest.cc",
+        "loader/nonsfi/run_all_unittests.cc",
+      ]
+      deps = [
+        ":nacl_helper_nonsfi_sandbox",
+        "//base",
+        "//base/test:test_support_nonsfi",
+        "//content",
+        "//native_client/src/nonsfi/irt:nacl_sys_private",
+        "//native_client/src/untrusted/nacl:nacl",
+        "//sandbox/linux:sandbox",
+        "//sandbox/linux:sandbox_linux_test_utils",
+        "//testing/gtest",
+      ]
+    }
+
+    copy("nacl_helper_nonsfi_unittests_main_copy") {
+      testonly = true
+      sources = [
+        "${root_out_dir}/nacl_helper_nonsfi_unittests_main",
+      ]
+      outputs = [
+        "${root_build_dir}/{{source_file_part}}",

[Mark Seaborn, 2015/12/03 19:05:07]

Does {{source_file_part}} expand to "nacl_helper_nonsfi_unittests_main"?  If so,
would it be clearer to write the latter?

[Petr Hosek, 2015/12/04 05:57:46]

Yes and no, this is the preferred GN way.

+      ]
+      deps = [
+        ":nacl_helper_nonsfi_unittests_main",
+      ]
+    }
   }
 
   group("helper_nonsfi") {
     deps = [
       ":nacl_helper_nonsfi_copy(//build/toolchain/nacl:newlib_pnacl_nonsfi)",
     ]
   }
+
+  group("helper_nonsfi_unittests") {
+    testonly = true
+    deps = [
+      ":nacl_helper_nonsfi_unittests",
+      ":nacl_helper_nonsfi_unittests_main_copy(//build/toolchain/nacl:newlib_pnacl_nonsfi)",
+    ]
+  }
 }
 
 # TODO(brettw) move to //components/nacl/common:switches
 source_set("nacl_switches") {
   sources = [
     "common/nacl_switches.cc",
     "common/nacl_switches.h",
   ]
 }
 
@@ skipping 32 matching lines @@
 
   if (is_linux) {
     sources += [
       "common/nacl_paths.cc",
       "common/nacl_paths.h",
     ]
 
     defines = [ "__STDC_LIMIT_MACROS=1" ]
   }
 }