[Mac] AppController needs to update its "last profile" pointer when the active profile is deleted

chrome/browser/app_controller_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/app_controller_mac.h"
 
 #include "base/auto_reset.h"
 #include "base/bind.h"
 #include "base/command_line.h"
 #include "base/files/file_path.h"
@@ skipping 10 matching lines @@
 #include "chrome/browser/browser_process.h"
 #include "chrome/browser/browser_shutdown.h"
 #include "chrome/browser/command_updater.h"
 #include "chrome/browser/download/download_service.h"
 #include "chrome/browser/download/download_service_factory.h"
 #include "chrome/browser/extensions/extension_service.h"
 #include "chrome/browser/extensions/extension_system.h"
 #include "chrome/browser/first_run/first_run.h"
 #include "chrome/browser/lifetime/application_lifetime.h"
 #include "chrome/browser/printing/print_dialog_cloud.h"
+#include "chrome/browser/profiles/profile_info_cache_observer.h"
 #include "chrome/browser/profiles/profile_manager.h"
 #include "chrome/browser/service/service_process_control.h"
 #include "chrome/browser/sessions/session_restore.h"
 #include "chrome/browser/sessions/session_service.h"
 #include "chrome/browser/sessions/session_service_factory.h"
 #include "chrome/browser/sessions/tab_restore_service.h"
 #include "chrome/browser/sessions/tab_restore_service_factory.h"
 #include "chrome/browser/signin/signin_manager.h"
 #include "chrome/browser/signin/signin_manager_factory.h"
 #include "chrome/browser/sync/profile_sync_service.h"
@@ skipping 142 matching lines @@
 - (void)openUrls:(const std::vector<GURL>&)urls;
 - (void)getUrl:(NSAppleEventDescriptor*)event
      withReply:(NSAppleEventDescriptor*)reply;
 - (void)submitCloudPrintJob:(NSAppleEventDescriptor*)event;
 - (void)windowLayeringDidChange:(NSNotification*)inNotification;
 - (void)windowChangedToProfile:(Profile*)profile;
 - (void)checkForAnyKeyWindows;
 - (BOOL)userWillWaitForInProgressDownloads:(int)downloadCount;
 - (BOOL)shouldQuitWithInProgressDownloads;
 - (void)executeApplication:(id)sender;
+- (void)profileWasRemoved:(const string16&)profileName;
 @end
 
+class AppControllerProfileObserver : public ProfileInfoCacheObserver {
+ public:
+  AppControllerProfileObserver(
+      ProfileManager* profile_manager, AppController* app_controller)
+          : profile_manager_(profile_manager),
+            app_controller_(app_controller) {
+    DCHECK(profile_manager_);
+    DCHECK(app_controller_);
+    profile_manager_->GetProfileInfoCache().AddObserver(this);
+  }
+
+  virtual ~AppControllerProfileObserver() {
+    DCHECK(profile_manager_);
+    profile_manager_->GetProfileInfoCache().RemoveObserver(this);
+  }
+
+ private:
+  // ProfileInfoCacheObserver implementation:
+
+  virtual void OnProfileAdded(const base::FilePath& profile_path) OVERRIDE {
+  }
+
+  virtual void OnProfileWasRemoved(const base::FilePath& profile_path,
+                                   const string16& profile_name) OVERRIDE {
+    // When a profile is deleted we need to notify the AppController,
+    // so that it can correctly update its pointer to the last used profile.
+    [app_controller_ profileWasRemoved:profile_name];
+  }
+
+  virtual void OnProfileWillBeRemoved(
+      const base::FilePath& profile_path) OVERRIDE {
+  }
+
+  virtual void OnProfileNameChanged(const base::FilePath& profile_path,
+                                    const string16& old_profile_name) OVERRIDE {
+  }
+
+  virtual void OnProfileAvatarChanged(
+      const base::FilePath& profile_path) OVERRIDE {
+  }
+
+  ProfileManager* profile_manager_;
+
+  AppController* app_controller_;  // Weak; owns us.
+
+  DISALLOW_COPY_AND_ASSIGN(AppControllerProfileObserver);
+};
+
 @implementation AppController
 
 @synthesize startupComplete = startupComplete_;
 
 // This method is called very early in application startup (ie, before
 // the profile is loaded or any preferences have been registered). Defer any
 // user-data initialization until -applicationDidFinishLaunching:.
 - (void)awakeFromNib {
   // We need to register the handlers early to catch events fired on launch.
   NSAppleEventManager* em = [NSAppleEventManager sharedAppleEventManager];
@@ skipping 293 matching lines @@
 - (void)popoverDidClose:(NSNotification*)notify {
   hasPopover_ = NO;
   [self fixCloseMenuItemKeyEquivalents];
 }
 
 // Called when the user has changed browser windows, meaning the backing profile
 // may have changed. This can cause a rebuild of the user-data menus. This is a
 // no-op if the new profile is the same as the current one. This will always be
 // the original profile and never incognito.
 - (void)windowChangedToProfile:(Profile*)profile {
-  if (lastProfile_ == profile)
+  if (lastProfile_ == profile && !lastProfileWasDeleted_)
     return;
 
   // Before tearing down the menu controller bridges, return the Cocoa menus to
   // their initial state.
   if (bookmarkMenuBridge_.get())
     bookmarkMenuBridge_->ResetMenu();
   if (historyMenuBridge_.get())
     historyMenuBridge_->ResetMenu();
 
   // Rebuild the menus with the new profile.
   lastProfile_ = profile;
 
+  if (lastProfileWasDeleted_)
+    lastProfileWasDeleted_ = NO;
+
   bookmarkMenuBridge_.reset(new BookmarkMenuBridge(lastProfile_,
       [[[NSApp mainMenu] itemWithTag:IDC_BOOKMARKS_MENU] submenu]));
   // No need to |BuildMenu| here.  It is done lazily upon menu access.
 
   historyMenuBridge_.reset(new HistoryMenuBridge(lastProfile_));
   historyMenuBridge_->BuildMenu();
 
   chrome::BrowserCommandController::
       UpdateSharedCommandsForIncognitoAvailability(
           menuState_.get(), lastProfile_);
@@ skipping 47 matching lines @@
   // Build up the encoding menu, the order of the items differs based on the
   // current locale (see http://crbug.com/7647 for details).
   // We need a valid g_browser_process to get the profile which is why we can't
   // call this from awakeFromNib.
   NSMenu* viewMenu = [[[NSApp mainMenu] itemWithTag:IDC_VIEW_MENU] submenu];
   NSMenuItem* encodingMenuItem = [viewMenu itemWithTag:IDC_ENCODING_MENU];
   NSMenu* encodingMenu = [encodingMenuItem submenu];
   EncodingMenuControllerDelegate::BuildEncodingMenu([self lastProfile],
                                                     encodingMenu);
 
+  // Instantiate the ProfileInfoCache observer so that we can get
+  // notified when a profile is deleted.
+  lastProfileWasDeleted_ = NO;
+  profileInfoCacheObserver_.reset(new AppControllerProfileObserver(
+      g_browser_process->profile_manager(), self));
+
   // Since Chrome is localized to more languages than the OS, tell Cocoa which
   // menu is the Help so it can add the search item to it.
   [NSApp setHelpMenu:helpMenu_];
 
   // Record the path to the (browser) app bundle; this is used by the app mode
   // shim.
   RecordLastRunAppBundlePath();
 
   // Makes "Services" menu items available.
   [self registerServicesMenuTypesTo:[notify object]];
@@ skipping 109 matching lines @@
 
 // Called to determine if we should enable the "restore tab" menu item.
 // Checks with the TabRestoreService to see if there's anything there to
 // restore and returns YES if so.
 - (BOOL)canRestoreTab {
   TabRestoreService* service =
       TabRestoreServiceFactory::GetForProfile([self lastProfile]);
   return service && !service->entries().empty();
 }
 
+// Called from the AppControllerProfileObserver every time a profile is deleted.
+- (void)profileWasRemoved:(const string16&)profileName {
+  Profile* lastProfile = [self lastProfile];
+  string16 lastProfileName = UTF8ToUTF16(lastProfile->GetPrefs()->GetString(
+      prefs::kProfileName));
+
+  // If the last profile has been deleted, we must NULL out our pointer
+  // otherwise we will try to start up a browser window with a pointer
+  // to the old profile.
+  if (profileName == lastProfileName) {
+    lastProfileWasDeleted_ = YES;

[Alexei Svitkine (slow), 2013/06/05 20:00:52]

Instead of introducing this variable to track this, can't you just update
lastProfile_ here? (via 
g_browser_process->profile_manager()->GetLastUsedProfile())

With your changes to profile_manager.cc, it should be loaded already, right?

[noms (inactive), 2013/06/11 19:32:17]

yup, you're right. Done. On 2013/06/05 20:00:52, Alexei Svitkine wrote:

+    lastProfile_ = NULL;
+  }
+}
+
 // Returns true if there is a modal window (either window- or application-
 // modal) blocking the active browser. Note that tab modal dialogs (HTTP auth
 // sheets) will not count as blocking the browser. But things like open/save
 // dialogs that are window modal will block the browser.
 - (BOOL)keyWindowIsModal {
   if ([NSApp modalWindow])
     return YES;
 
   Browser* browser = chrome::GetLastActiveBrowser();
   return browser &&
@@ skipping 357 matching lines @@
   // handles requests from services.
   NSArray* types = [NSArray arrayWithObjects:NSStringPboardType, nil];
   [app registerServicesMenuSendTypes:types returnTypes:types];
 }
 
 - (Profile*)lastProfile {
   // Return the profile of the last-used BrowserWindowController, if available.
   if (lastProfile_)
     return lastProfile_;
 
+  if (!g_browser_process->profile_manager())
+    return NULL;
+
   // On first launch, no profile will be stored, so use last from Local State.
-  if (g_browser_process->profile_manager())
-    return g_browser_process->profile_manager()->GetLastUsedProfile();
+  Profile* lastUsedProfile =
+      g_browser_process->profile_manager()->GetLastUsedProfile();
 
-  return NULL;
+  // If the last profile was deleted, we've already loaded the next active one,
+  // so we should update the pointer; otherwise we will try to open the old one.
+  // We unset lastProfileWasDeleted_ when the window is actually loaded, so that
+  // all the profile preferences/menus are re-created.
+  if (lastProfileWasDeleted_)
+    lastProfile_ = lastUsedProfile;
+
+  return lastUsedProfile;
 }
 
 // Various methods to open URLs that we get in a native fashion. We use
 // StartupBrowserCreator here because on the other platforms, URLs to open come
 // through the ProcessSingleton, and it calls StartupBrowserCreator. It's best
 // to bottleneck the openings through that for uniform handling.
 
 - (void)openUrls:(const std::vector<GURL>&)urls {
   // If the browser hasn't started yet, just queue up the URLs.
   if (!startupComplete_) {
@@ skipping 207 matching lines @@
 
 //---------------------------------------------------------------------------
 
 namespace app_controller_mac {
 
 bool IsOpeningNewWindow() {
   return g_is_opening_new_window;
 }
 
 }  // namespace app_controller_mac