Add chrome crash service to GN build on Windows.

chrome/tools/crash_service/BUILD.gn

Index: chrome/tools/crash_service/BUILD.gn
diff --git a/chrome/tools/crash_service/BUILD.gn b/chrome/tools/crash_service/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..287909b05a2a96798e7e7c964369c24c80eabe72
--- /dev/null
+++ b/chrome/tools/crash_service/BUILD.gn
@@ -0,0 +1,43 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+assert(is_win)
+
+executable("crash_service") {
+  sources = [
+    "main.cc",
+  ]
+
+  configs -= [ "//build/config/win:console" ]
+  configs += [ "//build/config/win:windowed" ]
+
+  deps = [
+    "//base",
+    "//chrome/common:constants",
+    "//chrome/installer/util",
+    "//components/crash/content/tools:crash_service",
+    "//content/public/common:static_switches",
+  ]
+}
+
+if (target_cpu == "x86" && current_cpu == "x86") {
+  # Cross-compile a 64-bit version when compiling a 64-bit target.
+  copy("crash_service_win64") {
+    crash_service_64_target = ":crash_service(//build/toolchain/win:x64)"
+
+    sources = [
+      # It would be nice if get_target_outputs would work on the executable,
+      # but instead we have to manually compute the executable name.
+      get_label_info(crash_service_64_target, "root_out_dir") +
+          "/crash_service.exe",
+    ]
+    outputs = [
+      "$root_build_dir/crash_service_win64.exe",
+    ]
+
+    deps = [
+      crash_service_64_target,
+    ]
+  }
+}