[Chromecast] Include all stdlibc++/libgcc symbols in cast_shell.

build/config/chromecast/BUILD.gn

Index: build/config/chromecast/BUILD.gn
diff --git a/build/config/chromecast/BUILD.gn b/build/config/chromecast/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..c230b199a30130d77e4ede00b0165fa443e8eb7b
--- /dev/null
+++ b/build/config/chromecast/BUILD.gn
@@ -0,0 +1,40 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+assert(is_chromecast)

[slan, 2015/12/02 15:25:24]

I'm surprised you don't need to import //build/config/chromecast_build.gni for
this gn arg. No error here?

[brettw, 2015/12/02 18:43:35]

externally set build args are implicitly global (this is a bug I want to fix).
But this means that if you're chromecast, the variable will be set. So the
assert is "correct" but the failure case won't be an assertion failed, it will
be an undefined variable. We probably want the import here.

+
+config("static_config") {
+  ldflags = [
+    # We want to statically link libstdc++/libgcc.
+    "-static-libstdc++",
+    "-static-libgcc",
+  ]
+}
+
+config("executable_config") {
+  ldflags = [
+    # Export stdlibc++ and libgcc symbols to force shlibs to refer to these
+    # symbols from the executable.
+    "-Wl,--export-dynamic",

[brettw, 2015/12/02 18:43:35]

I'd like to understand why this is so different than other systems like linux,
android, and chromeos. This looks completely different from all of them, which
seems suspicious to me.

[bcf, 2015/12/02 19:12:27]

The main issue is we are forced to use -static-libstdc++ due to licensing
reasons. This was previously defined in common.gypi, but is currently absent
from GN (so the ":static_config" options need to be added regardless).

We communicate with some shared libraries using C++ APIs so when both the main
executable and shlibs are compiled with -static-libstdc++, it causes subtle bugs
when there are duplicate copies of libstdc++ symbols. The goal of this CL is to
force all libstdc++/libgcc symbols to be exported by the executables to avoid
these issues.

The linked doc provides some background on this issue.
https://docs.google.com/a/google.com/document/d/1ptjOlC5fH8G-DkHTEaO6GWnAXztf...

+
+    "-lm",  # stdlibc++ requires math.h
+
+    # In case we redefined stdlibc++ symbols (e.g. tc_malloc)
+    "-Wl,--allow-multiple-definition",
+
+    "-Wl,--whole-archive",
+    "-l:libstdc++.a",
+    "-l:libgcc.a",
+    "-Wl,--no-whole-archive",
+  ]
+
+  # Despite including libstdc++/libgcc archives, we still need to specify
+  # static linking for them in order to prevent the executable from having a
+  # dynamic dependency on them.
+  configs = [ ":static_config" ]
+}
+
+config("shlib_config") {
+  configs = [ ":static_config" ]
+}