[Chromecast] Include all stdlibc++/libgcc symbols in cast_shell.

build/config/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/allocator.gni")
 import("//build/config/chrome_build.gni")
+import("//build/config/chromecast_build.gni")
 import("//build/config/crypto.gni")
 import("//build/config/features.gni")
 import("//build/config/sanitizers/sanitizers.gni")
 import("//build/config/ui.gni")
 import("//build/toolchain/goma.gni")
 
 declare_args() {
   # When set (the default) enables C++ iterator debugging in debug builds.
   # Iterator debugging is always off in release builds (technically, this flag
   # affects the "debug" config, which is always available but applied by
@@ skipping 384 matching lines @@
       "CoreFoundation.framework",
       "CoreGraphics.framework",
       "CoreText.framework",
       "Foundation.framework",
     ]
   } else if (is_linux) {
     libs = [ "dl" ]
   }
 }
 
+# Executable configs -----------------------------------------------------------
+
+# Windows linker setup for EXEs and DLLs.
+if (is_win) {
+  _windows_linker_configs = [
+    "//build/config/win:default_incremental_linking",
+    "//build/config/win:sdk_link",
+    "//build/config/win:common_linker_setup",
+
+    # Default to console-mode apps. Most of our targets are tests and such
+    # that shouldn't use the windows subsystem.
+    "//build/config/win:console",
+  ]
+}
+
+# This config defines the configs applied to all executables.
+config("executable_config") {

[slan, 2015/12/07 16:13:32]

Hmmm. Though it appears to be legal, (meaning GN throws no warning and seems to
forward things correctly) I'm not certain that having recursive configs is good
style. I will defer to Brett and Dirk on this one, but I have not seen this
pattern, and it is not explicitly called out in 'gn help config' as a legal
design.

If this is indeed invalid, then may I propose as an alternative: 
BUILDCONFIG.gn remains unchanged, except that
//builg/config/linux:executable_configs is added to the list of configs if
is_linux, where this target has the form:

config("executable_config") {
  if (is_chromecast) {
    # Ample comments and all needed properties go here directly.
    ldflags = [ ... ]
  }
}

You would then no longer need the build/config/chromecast/* targets, and
BUILDCONFIG would not change much.

However, if the design in PS12 is valid, feel free to ignore this comment :)

[Dirk Pranke, 2015/12/07 21:03:42]

This is valid and recommended in some cases.

See the discussion of "Configs on a config" in `gn help configs` (with an s).

(The feature is relatively new, so it's not used as widely as it should be).

[slan, 2015/12/07 21:07:47]

Thanks for the tip! bcf@, feel free to ignore my suggestion, it sounds like this
is a good use case for "configs on a config".

+  configs = []
+
+  if (is_win) {
+    configs += _windows_linker_configs
+  } else if (is_mac) {
+    configs += [
+      "//build/config/mac:mac_dynamic_flags",
+      "//build/config/mac:mac_executable_flags",
+    ]
+  } else if (is_linux || is_android || is_chromecast) {

[slan, 2015/12/07 16:13:32]

is_chromecast not needed here. The OS flags should be enough.

[bcf, 2015/12/07 21:39:49]

Done.

+    configs += [ "//build/config/gcc:executable_ldconfig" ]
+    if (is_android) {
+      configs += [ "//build/config/android:executable_config" ]
+    } else if (is_chromecast) {
+      configs += [ "//build/config/chromecast:executable_config" ]
+    }
+  }
+}
+
+# Shared library configs -------------------------------------------------------
+
+# This config defines the configs applied to all shared libraries.
+config("shared_library_config") {
+  configs = []
+
+  if (is_win) {
+    configs += _windows_linker_configs
+  } else if (is_mac) {
+    configs += [ "//build/config/mac:mac_dynamic_flags" ]
+  } else if (is_android) {
+    # Strip native JNI exports from shared libraries by default. Binaries that
+    # want this can remove this config.
+    configs += [ "//build/config/android:hide_native_jni_exports" ]
+  } else if (is_chromecast) {
+    configs += [ "//build/config/chromecast:shlib_config" ]

[slan, 2015/12/07 16:13:32]

nit: Can this be shared_library_config to match the style elsewhere?

[bcf, 2015/12/07 21:39:49]

Done.

+  }
+}
+
 # Add this config to your target to enable precompiled headers.
 #
 # Precompiled headers are done on a per-target basis. If you have just a couple
 # of files, the time it takes to precompile (~2 seconds) can actually be longer
 # than the time saved. On a Z620, a 100 file target compiles about 2 seconds
 # faster with precompiled headers, with greater savings for larger targets.
 #
 # Recommend precompiled headers for targets with more than 50 .cc files.
 config("precompiled_headers") {
   if (is_win && !is_official_build && !use_goma) {
@@ skipping 18 matching lines @@
     # This error doesn't happen every time. In VS2013, it seems if the .pch
     # file doesn't exist, no error will be generated (probably MS tested this
     # case but forgot the other one?). To reproduce this error, do a build,
     # then delete the precompile.c.obj file, then build again.
     cflags_c = [ "/wd4206" ]
   } else if (is_mac && !is_official_build && !use_goma) {
     precompiled_header = "build/precompile.h"
     precompiled_source = "//build/precompile.h"
   }
 }