Port ChromeSyncShell build rules to GN

chrome/android/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/android/config.gni")
 import("//build/config/android/rules.gni")
 import("//build_overrides/v8.gni")
 import("//chrome/android/chrome_public_apk_tmpl.gni")
 import("//chrome/version.gni")
 import("//testing/test.gni")
 import("//third_party/icu/config.gni")
 import("//third_party/protobuf/proto_library.gni")
 import("channel.gni")
 
 manifest_package = "org.chromium.chrome"
 if (enable_configuration_policy) {
   configuration_policy = 1
 } else {
   configuration_policy = 0
 }
 
-jinja_variables = [
+chrome_public_jinja_variables = [
   "channel=$android_channel",
   "manifest_package=$manifest_package",
   "configuration_policy=$configuration_policy",
 ]
 
+chrome_sync_shell_jinja_variables = [
+  "channel=$android_channel",
+  "manifest_package=org.chromium.chrome.sync_shell",
+  "configuration_policy=$configuration_policy",
+]
+
 chrome_android_paks_gypi =
     exec_script("//build/gypi_to_gn.py",
                 [
                   rebase_path("//chrome/chrome_android_paks.gypi"),
                   "--replace=<(PRODUCT_DIR)=$root_out_dir",
                 ],
                 "scope",
                 [ "//chrome/chrome_android_paks.gypi" ])
 
 locale_pak_resources("chrome_locale_paks") {
   sources = chrome_android_paks_gypi.chrome_android_pak_locale_resources
 
   deps = [
     "//chrome:packed_resources",
   ]
 }
 
 # GYP: //chrome/chrome.gyp:chrome_java (resources part)
 android_resources("chrome_java_resources") {
   resource_dirs = [
     "java/res",
     "//chrome/android/java/res_chromium",
   ]
   deps = [
     ":chrome_locale_paks",
     ":chrome_strings_grd",
+    "//chrome/app:java_strings_grd",
     "//components/policy:app_restrictions_resources",
     "//content/public/android:content_java_resources",
-    "//chrome/app:java_strings_grd",
     "//third_party/android_data_chart:android_data_chart_java_resources",
     "//third_party/android_media:android_media_resources",
   ]
   if (!enable_configuration_policy) {
     deps -= [ "//components/policy:app_restrictions_resources" ]
   }
   custom_package = "org.chromium.chrome"
 }
 
 # GYP: //chrome/chrome.gyp:chrome_strings_grd
@@ skipping 46 matching lines @@
     "values-zh-rTW/android_chrome_strings.xml",
   ]
 }
 
 # GYP: //chrome/chrome.gyp:chrome_java
 android_library("chrome_java") {
   deps = [
     ":chrome_java_resources",
     ":document_tab_model_info_proto_java",
     "//base:base_java",
-    "//net/android:net_java",
     "//components/bookmarks/common/android:bookmarks_java",
     "//components/dom_distiller/android:dom_distiller_content_java",
     "//components/dom_distiller/android:dom_distiller_core_java",
     "//components/gcm_driver/android:gcm_driver_java",
     "//components/invalidation/impl:java",
     "//components/navigation_interception/android:navigation_interception_java",
     "//components/policy/android:policy_java",
     "//components/precache/android:precache_java",
     "//components/safe_json/android:safe_json_java",
     "//components/service_tab_launcher:service_tab_launcher_java",
     "//components/signin/core/browser/android:java",
     "//components/variations/android:variations_java",
     "//components/web_contents_delegate_android:web_contents_delegate_android_java",
     "//content/public/android:content_java",
     "//media/base/android:media_java",
+    "//media/base/android:media_java",
+    "//media/midi:midi_java",
+    "//net/android:net_java",
     "//printing:printing_java",
     "//sync/android:sync_java",
+    "//third_party/WebKit/public:blink_headers_java",
     "//third_party/android_data_chart:android_data_chart_java",
     "//third_party/android_media:android_media_java",
     "//third_party/android_protobuf:protobuf_nano_javalib",
     "//third_party/android_swipe_refresh:android_swipe_refresh_java",
     "//third_party/android_tools:android_gcm_java",
     "//third_party/android_tools:android_support_v13_java",
     "//third_party/android_tools:android_support_v7_appcompat_java",
     "//third_party/android_tools:android_support_v7_mediarouter_java",
     "//third_party/android_tools:android_support_v7_mediarouter_resources",
     "//third_party/android_tools:android_support_v7_recyclerview_java",
     "//third_party/cacheinvalidation:cacheinvalidation_javalib",
     "//third_party/cacheinvalidation:cacheinvalidation_proto_java",
     "//third_party/gif_player:gif_player_java",
     "//third_party/jsr-305:jsr_305_javalib",
-    "//third_party/WebKit/public:blink_headers_java",
-    "//media/base/android:media_java",
-    "//media/midi:midi_java",
     "//ui/android:ui_java",
     "//ui/android:ui_java_resources",
     google_play_services_library,
   ]
 
   srcjar_deps = [
     ":chrome_android_java_enums_srcjar",
     ":chrome_android_java_google_api_keys_srcjar",
     ":chrome_version_srcjar",
     ":custom_tabs_service_aidl",
@@ skipping 82 matching lines @@
     "junit/src/org/chromium/chrome/browser/webapps/WebappRegistryTest.java",
   ]
   deps = [
     ":chrome_java",
     "//base:base_java",
     "//base:base_java_test_support",
     "//base:base_junit_test_support",
     "//components/invalidation/impl:java",
     "//sync:sync_java_test_support",
     "//sync/android:sync_java",
+    "//third_party/android_tools:android_support_v7_mediarouter_java",
     "//third_party/cacheinvalidation:cacheinvalidation_javalib",
     "//third_party/junit:hamcrest",
-    "//third_party/android_tools:android_support_v7_mediarouter_java",
     google_play_services_library,
   ]
 }
 
 # GYP: //chrome/chrome_android.gypi:chrome_version_java
 chrome_version_java_dir = "$root_gen_dir/templates/chrome_version_java"
 chrome_version_java_file = "$chrome_version_java_dir/org/chromium/chrome/browser/ChromeVersionConstants.java"
 process_version("chrome_version_java") {
   template_file = "java/ChromeVersionConstants.java.version"
   output = chrome_version_java_file
@@ skipping 42 matching lines @@
     "//components/navigation_interception/android:navigation_interception_java",
     "//components/policy/android:policy_java",
     "//components/precache/android:precache_java",
     "//components/precache/android:precache_javatests",
     "//components/web_contents_delegate_android:web_contents_delegate_android_java",
     "//content/public/android:content_java",
     "//content/public/test/android:content_java_test_support",
     "//net/android:net_java",
     "//net/android:net_java_test_support",
     "//printing:printing_java",
+    "//sync:sync_java_test_support",
     "//sync/android:sync_java",
     "//sync/android:sync_javatests",
-    "//sync:sync_java_test_support",
+    "//third_party/android_tools:android_support_v13_java",
     "//third_party/android_tools:android_support_v7_appcompat_java",
     "//third_party/android_tools:android_support_v7_recyclerview_java",
-    "//third_party/android_tools:android_support_v13_java",
     "//third_party/android_tools:legacy_http_javalib",
     "//third_party/cacheinvalidation:cacheinvalidation_javalib",
     "//third_party/jsr-305:jsr_305_javalib",
     "//ui/android:ui_java",
     "//ui/android:ui_javatests",
     google_play_services_library,
   ]
 }
 
 # Overrides icon / name defined in chrome_java_resources.
@@ skipping 16 matching lines @@
     "//chrome:packed_resources",
     "//third_party/icu:icu_assets",
     "//v8:v8_external_startup_data_assets",
   ]
 }
 
 # GYP: //chrome/android/chrome_apk.gyp:chrome_apk_manifest
 jinja_template("chrome_public_apk_manifest") {
   input = "java/AndroidManifest.xml"
   output = "$root_gen_dir/chrome_public_apk_manifest/AndroidManifest.xml"
-  variables = jinja_variables
+  variables = chrome_public_jinja_variables
   variables += [
     "min_sdk_version=16",
     "target_sdk_version=23",
   ]
 }
 
-# GYP: //chrome/android/chrome_apk.gyp:chrome_public_template_resources
-jinja_template_resources("chrome_public_template_resources") {
+# GYP: //chrome/android/chrome_apk.gyp:chrome_sync_shell_apk_manifest
+jinja_template("chrome_sync_shell_apk_manifest") {
+  input = "java/AndroidManifest.xml"
+  output = "$root_gen_dir/chrome_sync_shell_apk_manifest/AndroidManifest.xml"
+  variables = chrome_sync_shell_jinja_variables
+  variables += [
+    "min_sdk_version=16",
+    "target_sdk_version=23",
+  ]
+}
+
+# GYP: //chrome/android/chrome_apk.gyp:chrome_public_apk_template_resources
+jinja_template_resources("chrome_public_apk_template_resources") {
   resources = [
     "java/res_template/xml/searchable.xml",
     "java/res_template/xml/syncadapter.xml",
   ]
   res_dir = "java/res_template"
-  variables = jinja_variables
+  variables = chrome_public_jinja_variables
+}
+
+# GYP: //chrome/android/chrome_apk.gyp:chrome_sync_shell_apk_template_resources
+jinja_template_resources("chrome_sync_shell_apk_template_resources") {
+  resources = [
+    "java/res_template/xml/searchable.xml",
+    "java/res_template/xml/syncadapter.xml",
+  ]
+  res_dir = "java/res_template"
+  variables = chrome_sync_shell_jinja_variables
 }
 
 # GYP: //chrome/android/chrome_apk.gyp:libchrome_public
 shared_library("chrome_public") {
   deps = [
     "//build/config/sanitizers:deps",
     "//chrome:chrome_android_core",
   ]
-  gypi_values = exec_script(
-          "//build/gypi_to_gn.py",
-          [
-            rebase_path("chrome_apk.gyp"),
-            "--replace=<(chrome_native_sources_dir)=../browser/android/",
-          ],
-          "scope",
-          [ "chrome_apk.gyp" ])
+  gypi_values = exec_script("//build/gypi_to_gn.py",

[agrieve, 2015/11/20 15:09:25]

Can you move this to be top-level so that the exec_script can be shared between
targets?

+                            [ rebase_path("chrome_apk.gyp") ],
+                            "scope",
+                            [ "chrome_apk.gyp" ])
   sources = gypi_values.chrome_public_app_native_sources
 }
 
-chrome_public_apk_tmpl("chrome_public_apk") {
-  version_name = "Developer Build"
-  version_code = "1"
+# GYP: //chrome/android/chrome_apk.gyp:libchrome_sync_shell
+shared_library("chrome_sync_shell") {
+  testonly = true
+  deps = [
+    "//build/config/sanitizers:deps",
+    "//chrome:chrome_android_core",
+    "//sync",
+    "//sync:test_support_sync_fake_server_android",
+  ]
+  gypi_values = exec_script("//build/gypi_to_gn.py",
+                            [ rebase_path("chrome_apk.gyp") ],
+                            "scope",
+                            [ "chrome_apk.gyp" ])
+  sources = gypi_values.chrome_sync_shell_app_native_sources
+}
+
+# Contains rules common to chrome_public_apk and chrome_sync_shell_apk
+template("chrome_public_apk_tmpl_shared") {
+  chrome_public_apk_tmpl(target_name) {
+    forward_variables_from(invoker, "*")
+
+    version_name = "Developer Build"

[agrieve, 2015/11/20 15:09:25]

nit: this is already the default value for version_name and version_code, can
just delete.

+    version_code = "1"
+    native_lib_version_rule = "//build/util:chrome_version_json"
+
+    # Only attempt loading the library from the APK for 64 bit devices
+    # until the number of 32 bit devices which don't support this
+    # approach falls to a minimal level -  http://crbug.com/390618.
+    if (chromium_linker_supported &&
+        (target_cpu == "arm64" || target_cpu == "x64")) {
+      load_library_from_apk = chrome_public_apk_load_library_from_apk
+    }
+  }
+}
+
+chrome_public_apk_tmpl_shared("chrome_public_apk") {
   android_manifest = get_target_outputs(":chrome_public_apk_manifest")
   android_manifest = android_manifest[1]
   apk_name = "ChromePublic"
   native_libs = [ "libchrome_public.so" ]
-  native_lib_version_rule = "//build/util:chrome_version_json"
-
-  # Only attempt loading the library from the APK for 64 bit devices
-  # until the number of 32 bit devices which don't support this
-  # approach falls to a minimal level -  http://crbug.com/390618.
-  if (chromium_linker_supported &&
-      (target_cpu == "arm64" || target_cpu == "x64")) {
-    load_library_from_apk = chrome_public_apk_load_library_from_apk
-  }
 
   deps = [
     ":chrome_java",
     ":chrome_public",
     ":chrome_public_apk_assets",
     ":chrome_public_apk_manifest",
     ":chrome_public_apk_resources",
-    ":chrome_public_template_resources",
+    ":chrome_public_apk_template_resources",
     "//base:base_java",
     google_play_services_resources,
   ]
 }
 
+chrome_public_apk_tmpl_shared("chrome_sync_shell_apk") {
+  testonly = true
+  android_manifest = get_target_outputs(":chrome_sync_shell_apk_manifest")
+  android_manifest = android_manifest[1]
+  apk_name = "ChromeSyncShell"
+  native_libs = [ "libchrome_sync_shell.so" ]
+
+  deps = [
+    ":chrome_java",

[agrieve, 2015/11/20 15:09:25]

nit: move some of these deps to chrome_public_apk_tmpl_shared?

+    ":chrome_public_apk_assets",
+    ":chrome_public_apk_resources",
+    ":chrome_sync_shell",
+    ":chrome_sync_shell_apk_manifest",
+    ":chrome_sync_shell_apk_template_resources",
+    "//base:base_java",
+
+    # This exists here because com.google.protobuf.nano is needed in tests,
+    # but that code is stripped out via proguard. Adding this deps adds
+    # usages and prevents removal of the proto code.
+    "//sync:test_support_sync_proto_java",
+    google_play_services_resources,
+  ]
+}
+
 chrome_public_test_apk_manifest =
     "$root_gen_dir/chrome_public_test_apk_manifest/AndroidManifest.xml"
+chrome_sync_shell_test_apk_manifest =
+    "$root_gen_dir/chrome_sync_shell_test_apk_manifest/AndroidManifest.xml"
 
 # GYP: //chrome/android/chrome_apk.gyp:chrome_public_test_apk_manifest
 jinja_template("chrome_public_test_apk_manifest") {
   input = "javatests/AndroidManifest.xml"
   output = chrome_public_test_apk_manifest
-  variables = jinja_variables
+  variables = chrome_public_jinja_variables
+}
+
+# GYP: //chrome/android/chrome_apk.gyp:chrome_sync_shell_test_apk_manifest
+jinja_template("chrome_sync_shell_test_apk_manifest") {
+  input = "sync_shell/javatests/AndroidManifest.xml"
+  output = chrome_sync_shell_test_apk_manifest
+  variables = chrome_sync_shell_jinja_variables
 }
 
 # GYP: //chrome/android/chrome_apk.gyp:chrome_public_test_apk
 instrumentation_test_apk("chrome_public_test_apk") {
   apk_name = "ChromePublicTest"
   apk_under_test = ":chrome_public_apk"
   android_manifest = chrome_public_test_apk_manifest
   deps = [
     ":chrome_public_test_apk_manifest",
-    "//chrome/android:chrome_shared_test_java",
+    ":chrome_shared_test_java",
   ]
   isolate_file = "../chrome_public_test_apk.isolate"
   proguard_enabled = !is_debug
 }
+
+android_library("chrome_sync_shell_test_apk_java") {
+  testonly = true
+  DEPRECATED_java_in_dir = "sync_shell/javatests/src"
+
+  deps = [
+    "//base:base_java",
+    "//base:base_java_test_support",
+    "//chrome/android:chrome_java",
+    "//chrome/android:chrome_java_resources",
+    "//chrome/test/android:chrome_java_test_support",
+    "//components/bookmarks/common/android:bookmarks_java",
+    "//components/policy/android:policy_java",
+    "//content/public/android:content_java",
+    "//content/public/test/android:content_java_test_support",
+    "//sync:sync_java_test_support",
+    "//sync:test_support_sync_proto_java",
+    "//sync/android:sync_java",
+    "//third_party/android_protobuf:protobuf_nano_javalib",
+    "//third_party/android_tools:android_support_v13_java",
+    "//third_party/android_tools:android_support_v7_appcompat_java",
+    "//ui/android:ui_java",
+  ]
+}
+
+# GYP: //chrome/android/chrome_apk.gyp:chrome_sync_shell_test_apk
+instrumentation_test_apk("chrome_sync_shell_test_apk") {
+  apk_name = "ChromeSyncShellTest"
+  apk_under_test = ":chrome_sync_shell_apk"
+  android_manifest = chrome_sync_shell_test_apk_manifest
+  deps = [
+    ":chrome_sync_shell_test_apk_java",
+    ":chrome_sync_shell_test_apk_manifest",
+  ]
+  isolate_file = "../chrome_sync_shell_test_apk.isolate"
+  proguard_enabled = !is_debug
+}