Close all windows when app shim quits.

chrome/app/chrome_main_app_mode_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 // On Mac, one can't make shortcuts with command-line arguments. Instead, we
 // produce small app bundles which locate the Chromium framework and load it,
 // passing the appropriate data. This is the entry point into the framework for
 // those app bundles.
 
 #import <Cocoa/Cocoa.h>
 
 #include "apps/app_shim/app_shim_messages.h"
 #include "base/at_exit.h"
 #include "base/command_line.h"
 #include "base/logging.h"
 #include "base/mac/launch_services_util.h"
 #include "base/mac/mac_logging.h"
 #include "base/mac/mac_util.h"
 #include "base/mac/scoped_nsautorelease_pool.h"
+#include "base/memory/scoped_nsobject.h"
 #include "base/message_loop.h"
 #include "base/path_service.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/threading/thread.h"
 #include "chrome/common/chrome_paths.h"
 #include "chrome/common/chrome_paths_internal.h"
 #include "chrome/common/chrome_switches.h"
 #include "chrome/common/mac/app_mode_common.h"
 #include "ipc/ipc_channel_proxy.h"
 #include "ipc/ipc_listener.h"
 #include "ipc/ipc_message.h"
 
 namespace {
 
 const app_mode::ChromeAppModeInfo* g_info;
 base::Thread* g_io_thread = NULL;
 
 }  // namespace
 
+class AppShimController;
+
+@interface AppShimDelegate : NSObject<NSApplicationDelegate> {
+ @private
+  AppShimController* appShimController_;  // Weak. Owns us.
+  BOOL terminateNow_;
+  BOOL terminateRequested_;
+}
+
+- (id)initWithController:(AppShimController*)controller;
+
+- (void)terminateNow;
+
+@end
+
 // The AppShimController is responsible for communication with the main Chrome
 // process, and generally controls the lifetime of the app shim process.
 class AppShimController : public IPC::Listener {
  public:
   AppShimController();
 
   // Connects to Chrome and sends a LaunchApp message.
   void Init();
 
+  // Sends a QuitApp message to Chrome.
+  void QuitApp();
+
  private:
   // IPC::Listener implemetation.
   virtual bool OnMessageReceived(const IPC::Message& message) OVERRIDE;
   virtual void OnChannelError() OVERRIDE;
 
   // If Chrome failed to launch the app, |success| will be false and the app
   // shim process should die.
   void OnLaunchAppDone(bool success);
 
   // Called when the app is activated, either by the user clicking on it in the
   // dock or by Cmd+Tabbing to it.
   void OnDidActivateApplication();
 
-  // Quits the app shim process.
-  void Quit();
+  // Terminates the app shim process.
+  void Close();
 
   IPC::ChannelProxy* channel_;
+  scoped_nsobject<AppShimDelegate> nsapp_delegate_;
 
   DISALLOW_COPY_AND_ASSIGN(AppShimController);
 };
 
 AppShimController::AppShimController() : channel_(NULL) {
 }
 
 void AppShimController::Init() {
   DCHECK(g_io_thread);
   NSString* chrome_bundle_path =
       base::SysUTF8ToNSString(g_info->chrome_outer_bundle_path.value());
   NSBundle* chrome_bundle = [NSBundle bundleWithPath:chrome_bundle_path];
   base::FilePath user_data_dir;
   if (!chrome::GetUserDataDirectoryForBrowserBundle(chrome_bundle,
                                                     &user_data_dir)) {
-    Quit();
+    Close();
     return;
   }
 
   base::FilePath socket_path =
       user_data_dir.Append(app_mode::kAppShimSocketName);
   IPC::ChannelHandle handle(socket_path.value());
   channel_ = new IPC::ChannelProxy(handle, IPC::Channel::MODE_NAMED_CLIENT,
       this, g_io_thread->message_loop_proxy());
 
   channel_->Send(new AppShimHostMsg_LaunchApp(
       g_info->profile_dir.value(), g_info->app_mode_id));
+
+  nsapp_delegate_.reset([[AppShimDelegate alloc] initWithController:this]);
+  [NSApp setDelegate:nsapp_delegate_];

[Nico, 2013/05/29 23:01:09]

maybe DCHECK that no delegate is set yet?

[jackhou1, 2013/05/29 23:50:27]

Done.

+}
+
+void AppShimController::QuitApp() {
+  channel_->Send(new AppShimHostMsg_QuitApp);
 }
 
 bool AppShimController::OnMessageReceived(const IPC::Message& message) {
   bool handled = true;
   IPC_BEGIN_MESSAGE_MAP(AppShimController, message)
     IPC_MESSAGE_HANDLER(AppShimMsg_LaunchApp_Done, OnLaunchAppDone)
     IPC_MESSAGE_UNHANDLED(handled = false)
   IPC_END_MESSAGE_MAP()
 
   return handled;
 }
 
 void AppShimController::OnChannelError() {
   LOG(ERROR) << "App shim channel error.";
-  Quit();
+  Close();
 }
 
 void AppShimController::OnLaunchAppDone(bool success) {
   if (!success) {
-    Quit();
+    Close();
     return;
   }
   [[[NSWorkspace sharedWorkspace] notificationCenter]
       addObserverForName:NSWorkspaceDidActivateApplicationNotification
                   object:nil
                    queue:nil
               usingBlock:^(NSNotification* notification) {
       NSRunningApplication* activated_app =
           [[notification userInfo] objectForKey:NSWorkspaceApplicationKey];
       if ([activated_app isEqual:[NSRunningApplication currentApplication]])
         OnDidActivateApplication();
   }];
 }
 
-void AppShimController::Quit() {
-  [NSApp terminate:nil];
+void AppShimController::Close() {
+  [nsapp_delegate_ terminateNow];
 }
 
 void AppShimController::OnDidActivateApplication() {
   channel_->Send(new AppShimHostMsg_FocusApp);
 }
 
+@implementation AppShimDelegate
+
+- (id)initWithController:(AppShimController*)controller {
+  if ((self = [super init])) {
+    appShimController_ = controller;
+  }
+  return self;
+}
+
+- (NSApplicationTerminateReply)
+    applicationShouldTerminate:(NSApplication*)sender {
+  if (terminateNow_)
+    return NSTerminateNow;
+
+  appShimController_->QuitApp();
+  // Wait for the channel to close before terminating.
+  terminateRequested_ = YES;
+  return NSTerminateLater;
+}
+
+- (void)terminateNow {
+  if (terminateRequested_) {
+    [NSApp replyToApplicationShouldTerminate:NSTerminateNow];
+    return;
+  }
+
+  terminateNow_ = YES;
+  [NSApp terminate:nil];
+}
+
+@end
+
 //-----------------------------------------------------------------------------
 
 // A ReplyEventHandler is a helper class to send an Apple Event to a process
 // and call a callback when the reply returns.
 //
 // This is used to 'ping' the main Chrome process -- once Chrome has sent back
 // an Apple Event reply, it's guaranteed that it has opened the IPC channel
 // that the app shim will connect to.
 @interface ReplyEventHandler : NSObject {
   base::Callback<void(bool)> onReply_;
@@ skipping 154 matching lines @@
   // fully initialized don't receive a reply until its run loop starts. Once
   // the reply is received, Chrome will have opened its IPC port, guaranteed.
   [ReplyEventHandler pingProcess:psn andCall:base::Bind(&OnPingChromeReply)];
 
   base::MessageLoopForUI main_message_loop;
   main_message_loop.set_thread_name("MainThread");
   base::PlatformThread::SetName("CrAppShimMain");
   main_message_loop.Run();
   return 0;
 }