GN: Refactor PNaCl toolchain definitions to use a template

build/toolchain/nacl/BUILD.gn

 # Copyright (c) 2014 The Native Client Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/sysroot.gni")
 import("//build/config/nacl/config.gni")
 import("//build/toolchain/nacl_toolchain.gni")
 
 # Add the toolchain revision as a preprocessor define so that sources are
 # rebuilt when a toolchain is updated.
 # Idea we could use the toolchain deps feature, but currently that feature is
 # bugged and does not trigger a rebuild.
 # https://code.google.com/p/chromium/issues/detail?id=431880
 # Calls to get the toolchain revision are relatively slow, so do them all in a
 # single batch to amortize python startup, etc.
 revisions = exec_script("//native_client/build/get_toolchain_revision.py",
                         [
                           "nacl_x86_glibc",
                           "nacl_arm_glibc",
                           "pnacl_newlib",
                         ],
                         "trim list lines")
 nacl_x86_glibc_rev = revisions[0]
 nacl_arm_glibc_rev = revisions[1]
-pnacl_newlib_rev = revisions[2]
 
-nacl_toolchain("newlib_pnacl") {
-  toolchain_package = "pnacl_newlib"
-  toolchain_revision = pnacl_newlib_rev
-  toolchain_cpu = "pnacl"
-  toolprefix =
-      rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/pnacl-",
-                  root_build_dir)
+# TODO(mcgrathr): Uncomment this when
+# https://code.google.com/p/chromium/issues/detail?id=555724 is fixed.
+#pnacl_newlib_rev = revisions[2]
 
+template("pnacl_toolchain") {
+  assert(defined(invoker.strip), "Must define strip")
+  assert(defined(invoker.executable_extension),
+         "Must define executable_extension")
+
+  # TODO(mcgrathr): See above.
+  pnacl_newlib_rev = revisions[2]
+
+  nacl_toolchain(target_name) {
+    toolchain_package = "pnacl_newlib"
+    toolchain_revision = pnacl_newlib_rev
+    toolchain_cpu = "pnacl"
+    toolprefix =
+        rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/pnacl-",
+                    root_build_dir)
+
+    is_clang = true
+    cc = toolprefix + "clang"
+    cxx = toolprefix + "clang++"
+    ar = toolprefix + "ar"
+    ld = cxx
+    strip = toolprefix + invoker.strip
+    executable_extension = invoker.executable_extension
+  }
+}
+
+pnacl_toolchain("newlib_pnacl") {
   executable_extension = ".pexe"
 
-  is_clang = true
-  cc = toolprefix + "clang"
-  cxx = toolprefix + "clang++"
-  ar = toolprefix + "ar"
-  ld = cxx
-
   # The pnacl-finalize tool turns a .pexe.debug file into a .pexe file.
   # It's very similar in purpose to the traditional "strip" utility: it
   # turns what comes out of the linker into what you actually want to
   # distribute and run.  PNaCl doesn't have a "strip"-like utility that
   # you ever actually want to use other than pnacl-finalize, so just
   # make pnacl-finalize the strip tool rather than adding an additional
   # step like "postlink" to run pnacl-finalize.
-  strip = toolprefix + "finalize"
+  strip = "finalize"
 }
 
-nacl_toolchain("newlib_pnacl_nonsfi") {
-  toolchain_package = "pnacl_newlib"
-  toolchain_revision = pnacl_newlib_rev
-  toolchain_cpu = "pnacl"
-  toolprefix =
-      rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/pnacl-",
-                  root_build_dir)
+pnacl_toolchain("newlib_pnacl_nonsfi") {
+  executable_extension = ""
 
-  is_clang = true
-  cc = toolprefix + "clang"
-  cxx = toolprefix + "clang++"
-  ar = toolprefix + "ar"
-  ld = cxx
-  executable_extension = ""
+  strip = "strip"
 }
 
 template("nacl_glibc_toolchain") {
   toolchain_cpu = target_name
   assert(defined(invoker.toolchain_tuple), "Must define toolchain_tuple")
   assert(defined(invoker.toolchain_package), "Must define toolchain_package")
   assert(defined(invoker.toolchain_revision), "Must define toolchain_revision")
   forward_variables_from(invoker,
                          [
                            "toolchain_package",
@@ skipping 30 matching lines @@
 nacl_glibc_toolchain("arm") {
   toolchain_package = "nacl_arm_glibc"
   toolchain_revision = nacl_arm_glibc_rev
   toolchain_tuple = "arm-nacl"
 }
 
 template("nacl_clang_toolchain") {
   toolchain_cpu = target_name
   assert(defined(invoker.toolchain_tuple), "Must define toolchain_tuple")
 
+  # TODO(mcgrathr): See above.
+  pnacl_newlib_rev = revisions[2]
+
   toolchain_package = "pnacl_newlib"
   toolchain_revision = pnacl_newlib_rev
   toolprefix = rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/" +
                                invoker.toolchain_tuple + "-",
                            root_build_dir)
 
   nacl_toolchain("clang_newlib_" + toolchain_cpu) {
     is_clang = true
     cc = toolprefix + "clang"
     cxx = toolprefix + "clang++"
     ar = toolprefix + "ar"
     ld = cxx
   }
 }
 
 template("nacl_irt_toolchain") {
   toolchain_cpu = target_name
   assert(defined(invoker.toolchain_tuple), "Must define toolchain_tuple")
 
+  # TODO(mcgrathr): See above.
+  pnacl_newlib_rev = revisions[2]
+
   toolchain_package = "pnacl_newlib"
   toolchain_revision = pnacl_newlib_rev
   toolprefix = rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/" +
                                invoker.toolchain_tuple + "-",
                            root_build_dir)
 
   link_irt = rebase_path("//native_client/build/link_irt.py", root_build_dir)
 
   tls_edit_label =
       "//native_client/src/tools/tls_edit:tls_edit($host_toolchain)"
@@ skipping 39 matching lines @@
   toolchain_tuple = "i686-nacl"
 }
 
 nacl_clang_toolchains("x64") {
   toolchain_tuple = "x86_64-nacl"
 }
 
 nacl_clang_toolchains("arm") {
   toolchain_tuple = "arm-nacl"
 }