Adding third_party/openh264 build files for encoding

third_party/openh264/BUILD.gn

+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//third_party/openh264/openh264.gni")
+import("//third_party/openh264/openh264_args.gni")
+
+if (use_openh264) {
+  # Config shared by all openh264 targets.
+  config("openh264_config") {
+    cflags = []
+    defines = []
+
+    # Compiler warnings to ignore.
+    if (!is_win) {
+      # GCC flags
+      cflags += [
+        "-Wno-header-hygiene",
+        "-Wno-unused-value",
+      ]
+    }
+
+    # Platform-specific defines.
+    if (is_android) {
+      defines += [ "ANDROID_NDK" ]
+    }
+
+    # Workaround relating to the VERSION_NUMBER macro in version.h.
+    # TODO(hbos): Fix cause of the issue instead of this workaround.
+    if (!is_android) {
+      # On some builds VERSION_NUMBER is not defined when including version.h
+      # (probably another file is included named version.h, I have not been able
+      # to reproduce the problem on a local machine). Since the macro is only
+      # used for debug printing in wels[En/De]coderExt.cpp we can get around the
+      # undeclared identifier error by giving it a default value ourselves.
+      defines += [ "VERSION_NUMBER=\"openh264 v.?.?\"" ]
+
+      # For other builds we end up with a macro redefinition and have to
+      # suppress the macro redefined warning. Suppressing it does not work on
+      # android, but that's OK because we do not have the version.h problem on
+      # android, thus the if (!is_android) above.
+      if (!is_win) {
+        # GCC flags
+        cflags += [ "-Wno-macro-redefined" ]
+      } else {
+        # MSVC flags
+        cflags += [ "/wd4005" ]  # macro redefinition
+      }
+    }
+  }
+
+  static_library("openh264_common") {

[Dirk Pranke, 2015/11/19 02:46:56]

why is this (and the others) a static_library and not a source_set?

[hbos_chromium, 2015/11/19 13:00:43]

source_set makes more sense, changing.

+    deps = []
+    if (is_android) {
+      deps += [
+        # Defines "android_get/setCpu..." functions. The original OpenH264 build
+        # files replaces these using macros for "wels_..." versions of the same
+        # functions. We do not have access to these and use the <cpu-features.h>
+        # ones instead.
+        "//third_party/android_tools:cpu_features",
+      ]
+    }
+    configs -= [ "//build/config/compiler:chromium_code" ]
+    configs += [ "//build/config/compiler:no_chromium_code" ]
+    configs += [ ":openh264_config" ]
+    include_dirs = [
+      "src/codec/api/svc",
+      "src/codec/common/inc",
+      "src/codec/common/src",
+    ]
+    sources = openh264_common_sources

[Dirk Pranke, 2015/11/19 02:46:56]

Per
https://chromium.googlesource.com/chromium/src/+/master/tools/gn/docs/style_g...
, you should list sources first, deps last, etc.

[hbos_chromium, 2015/11/19 13:00:43]

Oh! Thanks for the link, updating.

+  }
+
+  static_library("openh264_processing") {
+    deps = [
+      ":openh264_common",
+    ]
+    configs -= [ "//build/config/compiler:chromium_code" ]
+    configs += [ "//build/config/compiler:no_chromium_code" ]
+    configs += [ ":openh264_config" ]
+    include_dirs = [
+      "src/codec/api/svc",
+      "src/codec/common/inc",
+      "src/codec/common/src",
+      "src/codec/processing/interface",
+      "src/codec/processing/interface/",
+      "src/codec/processing/src/adaptivequantization",
+      "src/codec/processing/src/backgrounddetection",
+      "src/codec/processing/src/common",
+      "src/codec/processing/src/complexityanalysis",
+      "src/codec/processing/src/denoise",
+      "src/codec/processing/src/downsample",
+      "src/codec/processing/src/imagerotate",
+      "src/codec/processing/src/scenechangedetection",
+      "src/codec/processing/src/scrolldetection",
+      "src/codec/processing/src/vaacalc",

[Dirk Pranke, 2015/11/19 02:46:56]

wow, you really need to list every directory individually rather than include
files relative to the top of the repo? :(

[hbos_chromium, 2015/11/19 13:00:43]

Yeah it's silly, they include by filename only. There was even a file with the
same name in two different directories so you need to have different
include_dirs per target or else you might end up including the wrong file :)

+    ]
+    sources = openh264_processing_sources
+  }
+
+  static_library("openh264_encoder") {
+    deps = [
+      ":openh264_common",
+      ":openh264_processing",
+    ]
+    configs -= [ "//build/config/compiler:chromium_code" ]
+    configs += [ "//build/config/compiler:no_chromium_code" ]
+    configs += [ ":openh264_config" ]
+    include_dirs = [
+      "src/codec/api/svc",
+      "src/codec/common/inc",
+      "src/codec/common/src",
+      "src/codec/encoder/core/inc",
+      "src/codec/encoder/core/src",
+      "src/codec/encoder/plus/inc",
+      "src/codec/encoder/plus/src",
+      "src/codec/processing/interface/",
+    ]
+    sources = openh264_encoder_sources
+  }
+
+  static_library("openh264_decoder") {
+    deps = [
+      ":openh264_common",
+      ":openh264_processing",
+    ]
+    defines = [
+      # Disables decoder_core.cpp debug prints.
+      "CODEC_FOR_TESTBED",
+    ]
+    configs -= [ "//build/config/compiler:chromium_code" ]
+    configs += [ "//build/config/compiler:no_chromium_code" ]
+    configs += [ ":openh264_config" ]
+    include_dirs = [
+      "src/codec/api/svc",
+      "src/codec/common/inc",
+      "src/codec/common/src",
+      "src/codec/decoder/core/inc",
+      "src/codec/decoder/core/src",
+      "src/codec/decoder/plus/inc",
+      "src/codec/decoder/plus/src",
+      "src/codec/processing/interface/",
+    ]
+    sources = openh264_decoder_sources
+  }
+}