third_party: Add wayland library.

third_party/wayland/BUILD.gn

+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+config("wayland_config") {
+  include_dirs = [
+    "include/src",
+    "include/protocol",
+    "src/src",
+  ]
+}
+
+source_set("wayland_util") {
+  sources = [
+    "src/src/wayland-util.c",
+    "src/src/wayland-util.h",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+
+  public_configs = [ ":wayland_config" ]
+}
+
+source_set("wayland_private") {
+  sources = [
+    "src/src/connection.c",
+    "src/src/wayland-os.c",
+    "src/src/wayland-os.h",
+    "src/src/wayland-private.h",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    "//build/config/linux:libffi",
+    ":wayland_config",
+  ]
+}
+
+static_library("wayland_server") {

[Dirk Pranke, 2015/11/10 01:58:55]

is there a reason this target is a static library and not a source_set?

[reveman, 2015/11/10 02:43:50]

mainly because it mirrors upstream better. protocol/wayland-protocol.c can't be
part of both wayland_client and wayland_server target when using source_set and
still allow us to depend on both in the same binary (e.g. unit tests in follow
up patches). we could easily solve this by moving wayland-protocol.c to the
wayland_private target but it seemed like a good idea to instead follow the same
pattern as upstream.

let me know if you prefer that I change this. either way is fine with me.

[Dirk Pranke, 2015/11/10 03:02:22]

If you want to be able to include both wayland_client and wayland_server in the
same binary, then I would recommend that move move wayland-protocol to
wayland_private.

Compiling the same file twice as part of two different targets and then linking
them into the same binary seems like something you should avoid if at all
possible (and I would give this same feedback to the upstream maintainers).

[reveman, 2015/11/10 06:09:27]

added a wayland_protocol target to latest patch. this allows us to share
wayland_protocol.c between _server and _client targets and use source_set
instead of static_library while still keeping wayland_private the same as
upstream.

+  sources = [
+    "include/protocol/wayland-server-protocol.h",
+    "protocol/wayland-protocol.c",
+    "src/src/event-loop.c",
+    "src/src/wayland-server.c",
+    "src/src/wayland-shm.c",
+  ]
+
+  deps = [
+    ":wayland_private",
+    ":wayland_util",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    "//build/config/linux:libffi",
+  ]
+
+  public_configs = [ ":wayland_config" ]
+}
+
+static_library("wayland_client") {

[Dirk Pranke, 2015/11/10 01:58:55]

same question.

+  sources = [
+    "include/protocol/wayland-client-protocol.h",
+    "protocol/wayland-protocol.c",
+    "src/src/wayland-client.c",
+  ]
+
+  deps = [
+    ":wayland_private",
+    ":wayland_util",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    "//build/config/linux:libffi",
+  ]
+
+  public_configs = [ ":wayland_config" ]
+}