Allow mojo_runner to connect to arbitrary executables.

mojo/runner/child/BUILD.gn

Index: mojo/runner/child/BUILD.gn
diff --git a/mojo/runner/child/BUILD.gn b/mojo/runner/child/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..40546cf58d2c43995e315787f5a302a25908cb3b
--- /dev/null
+++ b/mojo/runner/child/BUILD.gn
@@ -0,0 +1,97 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//mojo/public/mojo_application.gni")
+import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")
+
+group("child") {
+  testonly = true
+  deps = [
+    ":lib",
+    ":apptests",
+  ]
+}
+
+source_set("lib") {
+  sources = [
+    "runner_connection.cc",
+    "runner_connection.h",
+  ]
+
+  deps = [
+    ":interfaces",
+    "//base",
+    "//mojo/application/public/interfaces",
+    "//mojo/message_pump",
+    "//third_party/mojo/src/mojo/edk/system",
+  ]
+}
+
+mojom("interfaces") {
+  sources = [
+    "child_controller.mojom",
+  ]
+
+  deps = [
+    "//mojo/application/public/interfaces",
+  ]
+
+  import_dirs = [ "//mojo/services" ]
+}
+
+mojom("apptest_interfaces") {
+  sources = [
+    "native_service.mojom",
+  ]
+
+  deps = [
+    "//mojo/application/public/interfaces",
+  ]
+
+  import_dirs = [ "//mojo/services" ]
+}
+
+mojo_native_application("apptests") {
+  output_name = "mojo_runner_child_apptest"
+  testonly = true
+
+  sources = [
+    "native_apptest.cc",
+  ]
+
+  deps = [
+    ":apptest_interfaces",
+    "//base",
+    "//base/test:test_config",
+    "//mojo/application/public/cpp:sources",
+    "//mojo/application/public/cpp:test_support",
+    "//mojo/common:common_base",
+    "//mojo/converters/network:network",
+  ]
+
+  data_deps = [
+    ":native_target",
+  ]
+}
+
+executable("native_target") {
+  output_name = "mojo_runner_child_apptest_native_target"
+  testonly = true
+
+  sources = [
+    "native_apptest_target.cc",
+  ]
+
+  deps = [
+    ":apptest_interfaces",
+    ":lib",
+    "//base",
+    "//mojo/application/public/cpp",
+    "//mojo/application/public/interfaces",
+    "//mojo/common:common_base",
+    "//mojo/message_pump",
+    "//mojo/runner:init",
+    "//third_party/mojo/src/mojo/edk/embedder:embedder",
+  ]
+}