Add GN template for android_assets(). Use it in content_shell_apk.

build/config/android/rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//base/android/linker/config.gni")
 import("//build/config/android/config.gni")
 import("//build/config/android/internal_rules.gni")
 import("//build/toolchain/toolchain.gni")
 import("//third_party/android_platform/config.gni")
 import("//tools/grit/grit_rule.gni")
@@ skipping 662 matching lines @@
   }
 
   group(final_target_name) {
     forward_variables_from(invoker, [ "visibility" ])
     public_deps = [
       ":${target_name}__process_resources",
     ]
   }
 }
 
+# Declare an Android assets target.
+#
+# Defines a set of files to include as assets in a dependent apk.
+#
+# To include these assets in an apk, this target should be listed in
+# the apk's deps, or in the deps of a library target used by an apk.
+#
+# Variables
+#   deps: Specifies the dependencies of this target. Any Android assets
+#     listed in deps will be included by libraries/apks that depend on this
+#     target.
+#   sources: List of files to include as assets.
+#   outputs: List of asset paths to use for the assets. If there are fewer
+#     values than exist in sources, remaining sources will use the default path.

[pkotwicz, 2015/10/29 22:57:47]

In which cases would this parameter be useful?

If the parameter is necessary, replacing the parameter with output_dir would
make the android_assets template easier to understand in my opinion

[pkotwicz, 2015/10/29 23:23:33]

I think that the purpose of outputs parameter is to allow a file to be stored in
the APK but under a different name. I understand how this can be useful.

I think that the outputs parameter is an overkill and that at least for now we
can live without it
We can use the copy() template when renaming is desired.

[agrieve, 2015/10/30 00:04:45]

I've modelled this after the copy() rule, which allows a list of outputs.

Only place I think it'll be used is by webview to store both the 32 bit and 64
bit v8 snapshots. I think it's a reasonable parameter to support anyways though.

+#   disable_compression: Whether to diesable compression for files that are
+#     known to be compressable (default: false).
+#
+# Example:
+# android_assets("content_shell_assets") {
+#   deps = [
+#     ":generates_foo",
+#     ":other_assets",
+#     ]
+#   sources = [
+#     "//path/asset1.png",
+#     "//path/asset2.png",
+#     "$target_gen_dir/foo.dat",
+#   ]
+#   outputs = [
+#     "subdir/asset1.png",
+#     "subdir/asset2.png",
+#   ]
+# }
+#
+# android_assets("overriding_content_shell_assets") {
+#   deps = [
+#     ":content_shell_assets",
+#   ]
+#   sources = [
+#     "//custom/foo.dat"  # Override foo.dat from content_shell_assets.
+#   ]
+# }
+template("android_assets") {
+  set_sources_assignment_filter([])
+  forward_variables_from(invoker, [ "testonly" ])
+
+  _build_config = "$target_gen_dir/$target_name.build_config"
+  _build_config_target_name = "${target_name}__build_config"
+
+  write_build_config(_build_config_target_name) {
+    forward_variables_from(invoker,
+                           [
+                             "deps",
+                             "disable_compression",
+                           ])
+    type = "android_assets"
+    build_config = _build_config
+    assets = invoker.sources
+    if (defined(invoker.outputs)) {
+      asset_outputs = invoker.outputs
+    }
+  }
+
+  group(target_name) {
+    forward_variables_from(invoker, [ "visibility" ])
+    if (invoker.sources != []) {
+      public_deps = [
+        ":$_build_config_target_name",
+      ]
+    }
+  }
+}
+
 # Declare a target that generates localized strings.xml from a .grd file.
 #
 # If this target is included in the deps of an android resources/library/apk,
 # the strings.xml will be included with that target.
 #
 # Variables
 #   deps: Specifies the dependencies of this target.
 #   grd_file: Path to the .grd file to generate strings.xml from.
 #   outputs: Expected grit outputs (see grit rule).
 #
@@ skipping 820 matching lines @@
     deps = []
     forward_variables_from(invoker,
                            [
                              "asset_location",
                              "deps",
                              "extensions_to_not_compress",
                              "language_splits",
                            ])
     apk_path = _final_apk_path
     android_manifest = _android_manifest
+    assets_build_config = _build_config
     resources_zip = _all_resources_zip_path
     dex_path = final_dex_path
     load_library_from_apk = _load_library_from_apk
     create_density_splits = _create_density_splits
 
     if (!defined(extensions_to_not_compress)) {
       # Allow icu data, v8 snapshots, and pak files to be loaded directly from
       # the .apk.
       # Note: These are actually suffix matches, not necessarily extensions.
       extensions_to_not_compress = ".dat,.bin,.pak"
     }
 
     version_code = _version_code
     version_name = _version_name
 
     keystore_name = _keystore_name
     keystore_path = _keystore_path
     keystore_password = _keystore_password
 
     # Incremental apk does not use native libs nor final dex.
-    incremental_deps =
-        deps + _android_manifest_deps + [ ":$process_resources_target" ]
+    incremental_deps = deps + _android_manifest_deps + [
+                         ":$build_config_target",
+                         ":$process_resources_target",
+                       ]
 
     # This target generates the input file _all_resources_zip_path.
     deps += _android_manifest_deps + [
+              ":$build_config_target",
               ":$process_resources_target",
               ":$final_dex_target_name",
             ]
 
     if (_native_libs != [] && !_create_abi_split) {
       native_libs_dir = _native_libs_dir
       deps += [ ":$_prepare_native_target_name" ]
     }
   }
 
@@ skipping 477 matching lines @@
   }
 
   android_library(target_name) {
     java_files = []
     srcjar_deps = [ ":${_template_name}__protoc_java" ]
     deps = [
       "//third_party/android_protobuf:protobuf_nano_javalib",
     ]
   }
 }