GN: Add nacl_arm_glibc toolchain

build/toolchain/nacl/BUILD.gn

 # Copyright (c) 2014 The Native Client Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/sysroot.gni")
 import("//build/config/nacl/config.gni")
 import("//build/toolchain/nacl_toolchain.gni")
 
 # Add the toolchain revision as a preprocessor define so that sources are
 # rebuilt when a toolchain is updated.
 # Idea we could use the toolchain deps feature, but currently that feature is
 # bugged and does not trigger a rebuild.
 # https://code.google.com/p/chromium/issues/detail?id=431880
 # Calls to get the toolchain revision are relatively slow, so do them all in a
 # single batch to amortize python startup, etc.
 revisions = exec_script("//native_client/build/get_toolchain_revision.py",
                         [
                           "nacl_x86_glibc",
+                          "nacl_arm_glibc",
                           "pnacl_newlib",
                         ],
                         "trim list lines")
 nacl_x86_glibc_rev = revisions[0]
-pnacl_newlib_rev = revisions[1]
+nacl_arm_glibc_rev = revisions[1]
+pnacl_newlib_rev = revisions[2]
 
 nacl_toolchain("newlib_pnacl") {
   toolchain_package = "pnacl_newlib"
   toolchain_revision = pnacl_newlib_rev
   toolchain_cpu = "pnacl"
   toolprefix =
       rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/pnacl-",
                   root_build_dir)
 
   cc = toolprefix + "clang"
   cxx = toolprefix + "clang++"
   ar = toolprefix + "ar"
   ld = cxx
   executable_extension = ".pexe.debug"
 
   finalize = toolprefix + "finalize"
   nonfinal_file =
       "{{root_out_dir}}/{{target_output_name}}${executable_extension}"
   finalized_file = "{{root_out_dir}}/{{target_output_name}}.pexe"
   postlink = "$finalize $nonfinal_file -o $finalized_file"
   link_outputs = [ finalized_file ]
 }
 
-nacl_toolchain("glibc_x86") {
+template("nacl_glibc_toolchain") {
+  toolchain_cpu = target_name
+  assert(defined(invoker.toolchain_tuple), "Must define toolchain_tuple")
+  assert(defined(invoker.toolchain_package), "Must define toolchain_package")
+  assert(defined(invoker.toolchain_revision), "Must define toolchain_revision")
+  forward_variables_from(invoker,
+                         [
+                           "toolchain_package",
+                           "toolchain_revision",
+                         ])
+
+  toolprefix = rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/" +
+                               invoker.toolchain_tuple + "-",
+                           root_build_dir)
+
+  nacl_toolchain("glibc_" + toolchain_cpu) {
+    is_clang = false
+    is_nacl_glibc = true
+
+    cc = toolprefix + "gcc"
+    cxx = toolprefix + "g++"
+    ar = toolprefix + "ar"
+    ld = cxx
+  }
+}
+
+nacl_glibc_toolchain("x86") {
   toolchain_package = "nacl_x86_glibc"
   toolchain_revision = nacl_x86_glibc_rev
-  toolchain_cpu = "x86"
-  toolprefix =
-      rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/i686-nacl-",
-                  root_build_dir)
-  is_clang = false
-  is_nacl_glibc = true
-
-  cc = toolprefix + "gcc"
-  cxx = toolprefix + "g++"
-  ar = toolprefix + "ar"
-  ld = cxx
+  toolchain_tuple = "i686-nacl"
 }
 
-nacl_toolchain("glibc_x64") {
+nacl_glibc_toolchain("x64") {
   toolchain_package = "nacl_x86_glibc"
   toolchain_revision = nacl_x86_glibc_rev
-  toolchain_cpu = "x64"
-  toolprefix =
-      rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/x86_64-nacl-",
-                  root_build_dir)
-  is_clang = false
-  is_nacl_glibc = true
+  toolchain_tuple = "x86_64-nacl"
+}
 
-  cc = toolprefix + "gcc"
-  cxx = toolprefix + "g++"
-  ar = toolprefix + "ar"
-  ld = cxx
+nacl_glibc_toolchain("arm") {
+  toolchain_package = "nacl_arm_glibc"
+  toolchain_revision = nacl_arm_glibc_rev
+  toolchain_tuple = "arm-nacl"
 }
 
 template("nacl_clang_toolchain") {
   toolchain_cpu = target_name
   assert(defined(invoker.toolchain_tuple), "Must define toolchain_tuple")
 
   toolchain_package = "pnacl_newlib"
   toolchain_revision = pnacl_newlib_rev
   toolprefix = rebase_path("${nacl_toolchain_dir}/${toolchain_package}/bin/" +
                                invoker.toolchain_tuple + "-",
@@ skipping 63 matching lines @@
   toolchain_tuple = "i686-nacl"
 }
 
 nacl_clang_toolchains("x64") {
   toolchain_tuple = "x86_64-nacl"
 }
 
 nacl_clang_toolchains("arm") {
   toolchain_tuple = "arm-nacl"
 }