Aura on Android: Stub implementation of SelectFileDialog.

ui/shell_dialogs/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/ui.gni")
 import("//testing/test.gni")
 if (is_android) {
   import("//build/config/android/config.gni")
 }
 
 component("shell_dialogs") {
   sources = [
     "android/shell_dialogs_jni_registrar.cc",
     "android/shell_dialogs_jni_registrar.h",
     "base_shell_dialog.cc",
     "base_shell_dialog.h",
     "base_shell_dialog_win.cc",
     "base_shell_dialog_win.h",
     "linux_shell_dialog.cc",
     "linux_shell_dialog.h",
     "select_file_dialog.cc",
     "select_file_dialog.h",
     "select_file_dialog_android.cc",
     "select_file_dialog_android.h",
+    "select_file_dialog_auraandroid.cc",

[sky, 2015/10/15 21:51:47]

Can you conditionally include below rather than listing for all?

[mfomitchev, 2015/10/15 22:12:40]

Are there some guidelines which explain when it's better to exclude vs. include
files conditionally? The only thing I was able to find was the GYP
documentation, which says excluding is generally the preferred style
(https://gyp.gsrc.io/docs/UserDocumentation.md#Add-new-source-files).
It doesn't matter much to me either way, but it would be nice to have something
concrete we can use in the future in similar cases.

Actually, perhaps it would be worth adding a rule for _auraandroid in
BUILDCONFIG.gn
(https://code.google.com/p/chromium/codesearch#chromium/src/build/config/BUILD...
We do have several other cases where we add _auraandroid files (which we haven't
upstreamed yet). Incidentally, that would also rationalize the fact that we use
_auraandroid vs. _aura_android suffix.

[brettw, 2015/10/20 02:49:26]

You should conditionally include now unless for some reason the reverse is
better.

GYP recommended this because it allowed all files to be included in generated VC
solution files, even if they applied to other platforms. But this facility isn't
really used any more so we stopped recommending this.

This is documented in the GN style guide:
https://chromium.googlesource.com/chromium/src/+/master/tools/gn/docs/style_g...

The GN rule for filename exclusion rules is for platforms (like _android) only
and not for features and things like Aura. This is because the GYP rules were
spiraling out of control and there are relatively few of these cases anyway.

[mfomitchev, 2015/10/20 17:55:44]

Thanks Brett! Done. 

+    "select_file_dialog_auraandroid.h",
     "select_file_dialog_factory.cc",
     "select_file_dialog_factory.h",
     "select_file_dialog_mac.h",
     "select_file_dialog_mac.mm",
     "select_file_dialog_win.cc",
     "select_file_dialog_win.h",
     "select_file_policy.cc",
     "select_file_policy.h",
     "selected_file_info.cc",
     "selected_file_info.h",
@@ skipping 10 matching lines @@
   ]
 
   if (use_aura) {
     if (is_mac) {
       # Will be automatically filtered out on non-Mac.
       sources -= [ "select_file_dialog_mac.mm" ]
     }
     deps += [ "//ui/aura" ]
   }
 
-  if (is_android) {
+  if (is_android && !use_aura) {
     deps += [
       "//ui/android",
       "//ui/android:ui_java",
       "//ui/base:ui_base_jni_headers",
     ]
     include_dirs = [ "$root_gen_dir/ui" ]
     libs = [ "jnigraphics" ]
   }
 
+  if (is_android && use_aura) {
+    sources -= [
+      "android/shell_dialogs_jni_registrar.cc",
+      "android/shell_dialogs_jni_registrar.h",
+      "select_file_dialog_android.cc",
+      "select_file_dialog_android.h",
+    ]
+  } else {
+    sources -= [
+      "select_file_dialog_auraandroid.cc",
+      "select_file_dialog_auraandroid.h",
+    ]
+  }
+
   if (is_win) {
     deps += [ "//win8:metro_viewer" ]
   }
 }
 
 test("shell_dialogs_unittests") {
   sources = [
     "select_file_dialog_win_unittest.cc",
   ]
 
   deps = [
     ":shell_dialogs",
     "//base",
     "//base/test:test_support",
     "//base/test:run_all_unittests",
     "//testing/gtest",
   ]
 }