Make chrome/common pass "gn check"

chrome/common/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//tools/grit/grit_rule.gni")
 import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")
 import("//chrome/version.gni")
 
 gypi_values = exec_script("//build/gypi_to_gn.py",
                           [ rebase_path("../chrome_common.gypi") ],
@@ skipping 29 matching lines @@
 static_library("common") {
   sources = rebase_path(gypi_values.chrome_common_sources, ".", "//chrome")
   defines = []
 
   configs += [
     "//build/config:precompiled_headers",
     "//build/config/compiler:wexit_time_destructors",
   ]
 
   public_deps = [
-    "//chrome/common:constants",
-    "//chrome/common/safe_browsing:proto",
-  ]
-  deps = [
     "//base:base",
     "//base:i18n",
     "//base:prefs",
     "//base:base_static",
     "//chrome:resources",
     "//chrome:strings",
     "//chrome/app/theme:theme_resources",
+    "//chrome/common:constants",
+    "//chrome/common/safe_browsing:proto",
     "//chrome/common/variations:fieldtrial_testing_config",
     "//chrome/installer/util",
     "//components/cloud_devices/common",
     "//components/component_updater",
     "//components/content_settings/core/common",
     "//components/crash/core/common",
+    "//components/data_reduction_proxy/content/common",
+    "//components/dom_distiller/core",
+    "//components/error_page/common",
     "//components/favicon_base",
     "//components/gcm_driver/common",
     "//components/json_schema",
     "//components/metrics",
     "//components/metrics:net",
     "//components/omnibox/common",
     "//components/policy:policy_component_common",
     "//components/strings",
     "//components/translate/core/common",
     "//components/url_formatter",
     "//components/variations",
     "//components/version_info",
     "//content/public/common",
     "//crypto",
     "//extensions/common:common_constants",
+    "//gin",
+    "//google_apis",
+    "//gpu/command_buffer/service",
+    "//gpu/config",
     "//net",
+    "//ppapi/shared_impl",
     "//skia",
     "//third_party/icu",
     "//third_party/zlib:zip",
+    "//ui/accessibility",
+    "//ui/base",
+    "//ui/gfx/ipc",
+    "//ui/gl",
+    "//ui/message_center",
     "//ui/resources:resources",
     "//url",
   ]
 
   if (is_ios) {
     sources += [
       # Use this Mac file that was filtered out.
       "channel_info_mac.mm",
     ]
     sources -= [
       "resource_usage_reporter_type_converters.cc",
       "resource_usage_reporter_type_converters.h",
     ]
   } else {
     # Non-iOS.
-    deps += [
+    public_deps += [
       ":mojo_bindings",
+      "//chrome/common/net",
       "//components/visitedlink/common",
       "//components/autofill/content/common",
       "//components/autofill/core/common",
       "//components/password_manager/content/common",
       "//components/password_manager/core/common",
       "//components/signin/core/common",
       "//components/translate/content/common",
       "//media",
       "//ipc",
       "//third_party/re2",
+      "//third_party/mojo/src/mojo/public/cpp/bindings",
       "//third_party/widevine/cdm:version_h",
     ]
-    public_deps += [
-      "//chrome/common/net",
-      "//third_party/mojo/src/mojo/public/cpp/bindings",
-    ]
   }
 
   if (enable_extensions) {
     sources += rebase_path(gypi_values.chrome_common_extensions_sources,
                            ".",
                            "//chrome")
-    deps += [
+    public_deps += [
       "//device/usb",
       "//chrome/common/extensions/api",
       "//extensions/common",
       "//extensions/common/api",
       "//extensions:extensions_resources",
       "//extensions/strings",
       "//media/cast:net",
+
+      # This dependency is for a header used only by extensions code.
+      "//ui/keyboard:keyboard_with_content",
     ]
     if (is_chromeos) {
       sources +=
           rebase_path(gypi_values.chrome_common_extensions_chromeos_sources,
                       ".",
                       "//chrome")
     }
   }
 
   if (is_win || is_mac) {
     sources +=
         rebase_path(gypi_values.chrome_common_win_mac_sources, ".", "//chrome")
-    deps += [ "//breakpad:client" ]
+    public_deps += [ "//breakpad:client" ]
   }
   if (is_win || is_mac || is_chromeos) {
     sources += rebase_path(gypi_values.chrome_common_networking_private_sources,
                            ".",
                            "//chrome")
 
     # networking_private_crypto.cc depends on boringssl.
-    deps += [ "//third_party/boringssl" ]
+    public_deps += [ "//third_party/boringssl" ]
   }
   if (is_mac) {
     sources +=
         rebase_path(gypi_values.chrome_common_mac_sources, ".", "//chrome")
-    deps += [ ":app_mode_app_support" ]
+    public_deps += [ ":app_mode_app_support" ]
+  }
+  if (is_chromeos) {
+    public_deps += [ "//chromeos" ]
   }
 
   if (enable_nacl) {
-    deps += [ "//components/nacl:nacl_common" ]
+    public_deps += [ "//components/nacl:nacl_common" ]
   }
 
   # Printing.
   if (enable_basic_printing || enable_print_preview) {
-    deps += [
+    public_deps += [
       "//components/printing/common",
       "//printing",
     ]
     if (enable_print_preview) {
       # Full printing support.
       sources += rebase_path(gypi_values.chrome_common_service_process_sources,
                              ".",
                              "//chrome")
     }
   }
@@ skipping 22 matching lines @@
     # Non-Android.
     sources +=
         rebase_path(gypi_values.chrome_common_importer_sources, ".", "//chrome")
   }
 
   if (is_chromeos) {
     sources -= [ "channel_info_posix.cc" ]
   }
 
   if (is_win) {
-    deps += [
+    public_deps += [
       "//components/dom_distiller/core",  # Needed by chrome_content_client.cc.
       "//third_party/wtl",
     ]
   }
 
   if (enable_mdns) {
     sources += [ "local_discovery/local_discovery_messages.h" ]
   }
 
   if (is_mac) {
     sources -= [ "channel_info_posix.cc" ]
-    deps += [
+    public_deps += [
       "//third_party/mach_override",
       "//third_party/google_toolbox_for_mac",
     ]
   }
 
   if (enable_plugins) {
     sources += [
       "pepper_flash.cc",
       "pepper_flash.h",
       "ppapi_utils.cc",
       "ppapi_utils.h",
     ]
-    deps += [ "//third_party/adobe/flash:flapper_version_h" ]
+    public_deps += [ "//third_party/adobe/flash:flapper_version_h" ]
   }
   if (enable_plugins && enable_extensions) {
     sources += [
       "pepper_permission_util.cc",
       "pepper_permission_util.h",
     ]
   }
   if (!enable_webrtc) {
     sources -= [ "media/webrtc_logging_messages.h" ]
   }
   if (enable_configuration_policy) {
-    deps += [ "//components/policy" ]
+    public_deps += [ "//components/policy" ]
   }
 
   if (safe_browsing_mode == 1) {
     sources += rebase_path(gypi_values.chrome_common_full_safe_browsing_sources,
                            ".",
                            "//chrome")
   }
 }
 
 process_version("make_chrome_version") {
@@ skipping 100 matching lines @@
     ":constants",
     "//base",
   ]
 }
 
 mojom("mojo_bindings") {
   sources = [
     "resource_usage_reporter.mojom",
   ]
 }