Build nacl_helper_nonsfi with GN

components/nacl/BUILD.gn

 # Copyright (c) 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/crypto.gni")
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 import("//testing/test.gni")
 
 if (enable_nacl) {
@@ skipping 216 matching lines @@
 
       if (use_glib) {
         configs += [ "//build/config/linux:glib" ]
       }
 
       if (use_seccomp_bpf) {
         defines += [ "USE_SECCOMP_BPF" ]
       }
     }
   }
+
+  if (is_nacl) {
+    executable("nacl_helper_nonsfi_nexe") {
+      output_name = "nacl_helper_nonsfi"
+      set_sources_assignment_filter([])
+      sources = [
+        "common/nacl_messages.cc",
+        "common/nacl_messages.h",
+        "common/nacl_types.cc",
+        "common/nacl_types.h",
+        "common/nacl_types_param_traits.cc",
+        "common/nacl_types_param_traits.h",
+        "loader/nacl_helper_linux.cc",
+        "loader/nacl_helper_linux.h",
+        "loader/nacl_trusted_listener.cc",
+        "loader/nacl_trusted_listener.h",
+        "loader/nonsfi/nonsfi_listener.cc",
+        "loader/nonsfi/nonsfi_listener.h",
+        "loader/nonsfi/nonsfi_main.cc",
+        "loader/nonsfi/nonsfi_main.h",
+      ]
+      ldflags = [
+        "-Wl,--noirt",

[Mark Seaborn, 2015/10/22 21:48:30]

I think these flags (and "-lc++" etc.) belong in the toolchain description in
build/ rather than on the target.

This is because use of "--target=i686-unknown-nacl" tends to require use of
"-Wl,--noirt".

Also because "-Wl,--noirt" will be required for other executables built using
that toolchain definition, such as nacl_helper_nonsfi_unittests_{main,run}.  Can
you add those targets too?  Would it be worthwhile to add them in this change? 
Running those tests might help debug why your GN-built nacl_helper_nonsfi isn't
working.

[Petr Hosek, 2015/10/23 03:01:15]

Done.

Yes, I started porting the unit tests as well (exactly for the reason you
mentioned), but they're not finished yet and Dirk asked me to land the
nacl_helper_nonsfi ASAP because it's blocking other things. I planned to add
unit tests in a follow up issue.

+        "-Wt,--noirt",
+        "-Wt,--noirtshim",
+        "-nodefaultlibs",
+      ]
+      libs = [
+        "c++",

[Mark Seaborn, 2015/10/22 21:48:30]

libc++ should be brought in automatically by linking using pnacl-clang++.  libc
should also be brought in automatically.

Oh... this is because you're using "-nodefaultlibs".

untrusted.gypi has this comment:
      # The clang driver automatically injects -lpthread when using libc++, but
      # the toolchain doesn't have it yet.  To get around this, use
      # -nodefaultlibs and explicitly link irt_browser_lib to satisfy libc++'s
      # pthread dependency.

Can you put a similar explanation in the GN build?

[Petr Hosek, 2015/10/23 03:01:15]

Done.

+        "m",
+        "c",
+        "pnaclmm",
+      ]
+      deps = [
+        ":nacl_switches",
+        ":nacl_helper_nonsfi_sandbox",
+        "//base",
+        "//components/tracing",
+        "//content",
+        "//ipc",
+        "//native_client/src/nonsfi/irt:nacl_sys_private",
+        "//native_client/src/nonsfi/loader:elf_loader",
+        "//native_client/src/untrusted/nacl:nacl",
+        "//ppapi/proxy",
+        "//sandbox/linux:sandbox_linux_nacl_nonsfi",
+      ]
+    }
+
+    source_set("nacl_helper_nonsfi_sandbox") {
+      set_sources_assignment_filter([])
+      sources = [
+        "loader/nonsfi/nonsfi_sandbox.cc",
+        "loader/nonsfi/nonsfi_sandbox.h",
+        "loader/sandbox_linux/nacl_sandbox_linux.cc",
+        "loader/sandbox_linux/nacl_sandbox_linux.h",
+      ]
+      deps = [
+        "//base",
+        "//content",
+        "//sandbox/linux:sandbox_linux_nacl_nonsfi",
+      ]
+    }
+
+    copy("nacl_helper_nonsfi_copy") {
+      sources = [
+        "${root_out_dir}/nacl_helper_nonsfi",
+      ]
+      outputs = [
+        "${root_build_dir}/{{source_file_part}}",
+      ]
+      deps = [
+        ":nacl_helper_nonsfi_nexe",
+      ]
+    }
+
+    group("nacl_helper_nonsfi") {
+      deps = [
+        ":nacl_helper_nonsfi_copy(//build/toolchain/nacl:newlib_pnacl_nonsfi)",
+      ]
+    }
+  }
 } else {
   group("nacl") {
   }
   group("nacl_helper") {
   }
+  group("nacl_helper_nonsfi") {
+  }
 }
 
 source_set("nacl_switches") {
   sources = [
     "common/nacl_switches.cc",
     "common/nacl_switches.h",
   ]
 }
 
 source_set("nacl_common") {
@@ skipping 30 matching lines @@
 
   if (is_linux) {
     sources += [
       "common/nacl_paths.cc",
       "common/nacl_paths.h",
     ]
 
     defines = [ "__STDC_LIMIT_MACROS=1" ]
   }
 }