Add a config for max optimizations in the GN build.

build/config/compiler/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/android/config.gni")
 import("//build/config/sysroot.gni")
 if (cpu_arch == "arm") {
   import("//build/config/arm.gni")
 }
 
@@ skipping 563 matching lines @@
         "-Wno-error=c++0x-compat",
         # Other things unrelated to -Wextra:
         "-Wno-non-virtual-dtor",
         "-Wno-sign-promo",
       ]
     }
   }
 }
 
 # Optimization -----------------------------------------------------------------
+#
+# Note that BUILDCONFIG.gn sets up a variable "default_optimization_config"
+# which it will assign to the config it implicitly applies to every target. If
+# you want to override the optimization level for your target, remove this
+# config (which will expand differently for debug or release builds), and then
+# add back the one you want to override it with:
+#
+#   configs -= default_optimization_config
+#   configs += [ "//build/config/compiler/optimize_max" ]
 
+# Default "optimization on" config. On Windows, this favors size over speed.
+#
+# IF YOU CHANGE THIS also consider whether optimize_max should be updated.
 config("optimize") {
   if (is_win) {
     cflags = [
       "/O2",
       "/Ob2",  # Both explicit and auto inlining.
       "/Oy-",  # Disable omitting frame pointers, must be after /O2.
+      "/Os",   # Favor size over speed.
     ]
   } else {
     if (is_ios) {
       cflags = [ "-Os" ]
     } else {
       cflags = [ "-O2" ]
     }
   }
 }
 
+# Turn off optimizations.
 config("no_optimize") {
   if (is_win) {
     cflags = [
       "/Od",  # Disable optimization.
       "/Ob0",  # Disable all inlining (on by default).
       "/RTC1",  # Runtime checks for stack frame and uninitialized variables.
     ]
   } else {
     cflags = [ "-O0" ]
   }
 }
 
+# On Windows, turns up the optimization level. This implies whole program
+# optimization and link-time code generation which is very expensive and should
+# be used sparingly. For non-Windows, this is the same as "optimize".
+config("optimize_max") {
+  if (is_win) {
+    cflags = [
+      "/O2",
+      "/Ob2",  # Both explicit and auto inlining.
+      "/Oy-",  # Disable omitting frame pointers, must be after /O2.
+      "/Ot",   # Favor speed over size.
+      "/GL",   # Whole program optimization.
+    ]
+  } else {
+    if (is_ios) {
+      cflags = [ "-Os" ]
+    } else {
+      cflags = [ "-O2" ]
+    }
+  }
+}
+
 # Symbols ----------------------------------------------------------------------
 
 # TODO(brettw) Since this sets ldflags on Windows which is inherited across
 # static library boundaries, if you want to remove the default symbol config
 # and set a different one on a target, you also have to do it for all static
 # libraries that go into that target, which is messed up. Either we need a
 # more flexible system for defining linker flags, or we need to separate this
 # out into a "symbols_linker" config that is only applied to DLLs and EXEs.
 config("symbols") {
   if (is_win) {
@@ skipping 11 matching lines @@
   } else {
     cflags = [ "-g1" ]
   }
 }
 
 config("no_symbols") {
   if (!is_win) {
     cflags = [ "-g0" ]
   }
 }