Creating a pexe content handler to translate and run pexes.

services/nacl/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//mojo/public/mojo_application.gni")
+import("//mojo/public/tools/bindings/mojom.gni")
 
 # Trusted code
 if (!is_nacl) {
   mojo_native_application("nacl_content_handler") {
     sources = [
       "content_handler_main.cc",
     ]
 
     deps = [
       "//base",
       "//mojo/application:application",
       "//mojo/application:content_handler",
       "//mojo/data_pipe_utils",
       "//mojo/message_pump",
       "//mojo/public/platform/native:system_impl_private",
       "//mojo/services/network/interfaces",
       "//mojo/nacl/sfi/nacl_bindings:monacl_sel",
       "//url",
     ]
 
     data_deps = [
       "//mojo/nacl/sfi/nacl_bindings:irt_mojo(//build/toolchain/nacl:irt_${target_cpu})",
     ]
   }
 
   if (current_cpu == "x86" || current_cpu == "arm") {
     # Non-SFI NaCl can only be executed by a 32-bit process, so our
     # content handler must be built and launched as a 32-bit process as well.
     mojo_native_application("nacl_content_handler_nonsfi_32_bit") {
+      output_name = "nacl_content_handler_nonsfi_nexe"
       sources = [
         "content_handler_main_nonsfi.cc",
       ]
 
       deps = [
         "//base",
         "//mojo/application:application",
         "//mojo/application:content_handler",
         "//mojo/data_pipe_utils",
         "//mojo/public/platform/native:mgl_thunks",
         "//mojo/public/platform/native:mgl_onscreen_thunks",
         "//mojo/message_pump",
         "//mojo/nacl/nonsfi:irt_mojo_nonsfi",
         "//mojo/public/cpp/application:application",
         "//native_client/src/nonsfi/loader:elf_loader",
       ]
     }
+    mojo_native_application("nacl_content_handler_nonsfi_pexe_32_bit") {

[Petr Hosek, 2015/10/27 15:07:52]

Nit: GN convention is to avoid duplicating the directory name in the name of the
target, so this target should be named "content_handler_nonsfi_pexe_32_bit" and
the same for all other targets in this file.

[Sean Klein, 2015/10/28 17:02:41]

Done.

+      output_name = "nacl_content_handler_nonsfi_pexe"
+      sources = [
+        "content_handler_main_nonsfi_pexe.cc",
+      ]
+
+      deps = [
+        ":pnacl_translator_bindings",
+        "//base",
+        "//mojo/application:application",
+        "//mojo/application:content_handler",
+        "//mojo/data_pipe_utils",
+        "//mojo/public/platform/native:mgl_thunks",

[Mark Seaborn, 2015/10/27 17:30:20]

These are being repeated across all of these mojo_native_applications. 
Shouldn't these be dependencies of "//mojo/nacl/nonsfi:irt_mojo_nonsfi" instead?

[Sean Klein, 2015/10/28 17:02:41]

Done.

+        "//mojo/public/platform/native:mgl_onscreen_thunks",
+        "//mojo/message_pump",
+        "//mojo/nacl/nonsfi:irt_mojo_nonsfi",
+        "//native_client/src/nonsfi/loader:elf_loader",
+      ]
+    }
+    mojo_native_application("pnacl_compile_32_bit") {
+      output_name = "pnacl_compile"
+      sources = [
+        "pnacl_compile.cc",
+      ]
+
+      deps = [
+        ":pnacl_translator_bindings",
+        "//base",
+        "//mojo/nacl/nonsfi:irt_mojo_nonsfi",
+        "//mojo/public/platform/native:mgl_thunks",
+        "//mojo/public/platform/native:mgl_onscreen_thunks",
+        "//mojo/public/cpp/application:standalone",
+        "//native_client/src/nonsfi/loader:elf_loader",
+      ]
+    }
+    mojo_native_application("pnacl_link_32_bit") {
+      output_name = "pnacl_link"
+      sources = [
+        "pnacl_link.cc",
+      ]
+
+      deps = [
+        ":pnacl_translator_bindings",
+        "//base",
+        "//mojo/nacl/nonsfi:irt_mojo_nonsfi",
+        "//mojo/public/platform/native:mgl_thunks",
+        "//mojo/public/platform/native:mgl_onscreen_thunks",
+        "//mojo/public/cpp/application:standalone",
+        "//native_client/src/nonsfi/loader:elf_loader",
+      ]
+    }
 
     # Copy to the root build directory so that the '#!' prefix line for invoking
     # our content handler can simply be "mojo:nacl_content_handler_nonsfi".
-    copy("nacl_content_handler_nonsfi_copy") {
-      sources = [
-        "${root_out_dir}/nacl_content_handler_nonsfi_32_bit.mojo",
-      ]
-      outputs = [
-        "${root_build_dir}/nacl_content_handler_nonsfi.mojo",
-      ]
-      deps = [
-        ":nacl_content_handler_nonsfi_32_bit",
-      ]
+    # Either way, build the same dependencies.
+    shared_deps = [
+      ":nacl_content_handler_nonsfi_32_bit",
+      ":nacl_content_handler_nonsfi_pexe_32_bit",
+      ":pnacl_compile_32_bit",
+      ":pnacl_link_32_bit",
+    ]
+    if (root_out_dir != root_build_dir) {
+      copy("nacl_content_handler_nonsfi_copy") {
+        sources = [
+          "${root_out_dir}/nacl_content_handler_nonsfi_nexe.mojo",
+          "${root_out_dir}/nacl_content_handler_nonsfi_pexe.mojo",
+          "${root_out_dir}/pnacl_compile.mojo",
+          "${root_out_dir}/pnacl_link.mojo",
+        ]
+        outputs = [
+          "${root_build_dir}/{{source_name_part}}.mojo",

[Petr Hosek, 2015/10/27 15:07:52]

You can use {{source_file_part}} here and omit the ".mojo" bit since you're not
changing the extension.

[Sean Klein, 2015/10/28 17:02:41]

Done.

+        ]
+        deps = shared_deps
+      }
+    } else {
+      group("nacl_content_handler_nonsfi_copy") {
+        deps = shared_deps
+      }
     }
   }
 }
 
 # This group serves as a 64 to 32 bit transformation for Linux. If we are
 # using a 64 bit toolchain, build the nonsfi nacl content handler as 32 bit.
 group("nacl_content_handler_nonsfi") {
   deps = []
   if ((target_cpu == "x64" || target_cpu == "x86") && is_linux) {
     # The toolchain is hardcoded as 32-bit clang here -- although it must
     # be 32 bit (for nonsfi), it assumes clang. Ideally, the toolchain would
     # be defined as the 32 bit variant of whatever is being used (be it clang,
     # gcc, or something else).
     deps += [ ":nacl_content_handler_nonsfi_copy(//build/toolchain/linux:clang_x86)" ]
   } else {
     deps += [ ":nacl_content_handler_nonsfi_copy" ]
   }
 }
+
+mojom("pnacl_translator_bindings") {
+  sources = [
+    "pnacl_compile.mojom",
+    "pnacl_link.mojom",
+  ]
+}