Adds support for POST request with bodies on WKWebView.

ios/web/web_state/js/crw_js_post_request_loader.mm

+// Copyright 2015 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/web/web_state/js/crw_js_post_request_loader.h"
+
+#import "base/json/string_escape.h"

[Eugene But (OOO till 7-30), 2015/12/03 16:51:42]

s/import/include

Sorry for missing this previously :(

[stkhapugin, 2015/12/03 17:51:02]

Done.

+#import "base/mac/objc_property_releaser.h"
+#import "base/strings/sys_string_conversions.h"
+#import "ios/web/web_state/js/page_script_util.h"
+#import "ios/web/web_state/ui/crw_wk_script_message_router.h"
+
+namespace {
+
+// Escapes characters and encloses given string in quotes for use in JavaScript.
+NSString* EscapeAndQuoteStringForJavaScript(NSString* unescapedString) {
+  std::string string = base::SysNSStringToUTF8(unescapedString);
+  return base::SysUTF8ToNSString(base::GetQuotedJSONString(string));
+}
+
+// JavaScript message handler name installed in WKWebView for request errors.
+NSString* const kErrorHandlerName = @"POSTErrorHandler";
+
+// JavaScript message handler name installed in WKWebView for successful
+// request completion.
+NSString* const kSuccessHandlerName = @"POSTSuccess";

[Eugene But (OOO till 7-30), 2015/12/03 16:51:42]

NIT: s/POSTSuccess/POSTSuccessHandler

[stkhapugin, 2015/12/03 17:51:02]

Done.

+
+}  // namespace
+
+@interface CRWJSPOSTRequestLoader ()
+
+// JavaScript used to execute POST requests. Lazily instantiated.
+@property(nonatomic, copy, readonly) NSString* requestScript;
+
+// Handler for UIApplicationDidReceiveMemoryWarningNotification.
+- (void)handleMemoryWarning;
+
+// Forms a JavaScript method call to |requestScript| that executes given
+// |request|.
+- (NSString*)scriptToExecutePOSTRequest:(NSURLRequest*)request;
+
+// Converts a dictionary of HTTP request headers to a JavaScript object.
+- (NSString*)JSONForJavaScriptFromRequestHeaders:(NSDictionary*)headers;
+
+@end
+
+@implementation CRWJSPOSTRequestLoader
+@synthesize requestScript = _requestScript;
+
+- (void)dealloc {
+  [[NSNotificationCenter defaultCenter] removeObserver:self];
+  [_requestScript release];

[Eugene But (OOO till 7-30), 2015/12/03 16:51:42]

We don't do manual memory management in Chromium. Please either use
scoped_nsobject, so you can reset this ivar in handleMemoryWarning.

[stkhapugin, 2015/12/03 17:51:02]

Done.

+  [super dealloc];
+}
+
+- (instancetype)init {
+  self = [super init];
+  if (self) {
+    [[NSNotificationCenter defaultCenter]
+        addObserver:self
+           selector:@selector(handleMemoryWarning)
+               name:UIApplicationDidReceiveMemoryWarningNotification
+             object:nil];
+  }
+  return self;
+}
+
+- (NSString*)requestScript {
+  if (!_requestScript) {
+    _requestScript = [web::GetPageScript(@"post_request") copy];
+  }
+  return _requestScript;
+}
+
+- (void)loadPOSTRequest:(NSURLRequest*)request
+              inWebView:(WKWebView*)webView
+          messageRouter:(CRWWKScriptMessageRouter*)messageRouter
+        completionBlock:(void (^)(NSError*))completionBlock {
+  DCHECK([request.HTTPMethod isEqualToString:@"POST"]);
+  DCHECK(webView);
+  DCHECK(messageRouter);
+  DCHECK(completionBlock);
+
+  // Install error handling and success routers.
+  [messageRouter setScriptMessageHandler:^(WKScriptMessage* message) {
+    // Cleaning up script handlers.
+    // This needs to be done on next runloop because this block gets deallocated
+    // during its execution otherwise.
+    dispatch_async(dispatch_get_main_queue(), ^{
+      [messageRouter removeScriptMessageHandlerForName:kErrorHandlerName
+                                               webView:webView];
+      [messageRouter removeScriptMessageHandlerForName:kSuccessHandlerName
+                                               webView:webView];
+      completionBlock(nil);
+    });
+  }
+                                    name:kSuccessHandlerName
+                                 webView:webView];
+
+  [messageRouter setScriptMessageHandler:^(WKScriptMessage* message) {
+    NSNumber* statusCode = message.body;
+    NSError* error = [NSError errorWithDomain:@"http"
+                                         code:statusCode.integerValue
+                                     userInfo:nil];
+    // Cleaning up script handlers.
+    // This needs to be done on next runloop because this block gets deallocated
+    // during its execution otherwise.
+    dispatch_async(dispatch_get_main_queue(), ^{
+      [messageRouter removeScriptMessageHandlerForName:kErrorHandlerName
+                                               webView:webView];
+      [messageRouter removeScriptMessageHandlerForName:kSuccessHandlerName
+                                               webView:webView];
+      completionBlock(error);
+    });
+  }
+                                    name:kErrorHandlerName
+                                 webView:webView];
+
+  NSString* HTML =
+      [NSString stringWithFormat:@"<html><script>%@%@</script></html>",
+                                 self.requestScript,
+                                 [self scriptToExecutePOSTRequest:request]];
+  [webView loadHTMLString:HTML baseURL:request.URL];
+}
+
+#pragma mark - Private methods.
+
+- (void)handleMemoryWarning {
+  // Request script can be recreated from file at any moment.
+  [_requestScript release];
+  _requestScript = nil;
+}
+
+- (NSString*)scriptToExecutePOSTRequest:(NSURLRequest*)request {
+  NSDictionary* headers = [request allHTTPHeaderFields];
+  NSString* headerString = [self JSONForJavaScriptFromRequestHeaders:headers];
+  NSString* URLString = [[request URL] absoluteString];
+  NSString* contentType = headers[@"Content-Type"];
+  NSString* base64Data = [[request HTTPBody] base64EncodedStringWithOptions:0];
+
+  // Here |headerString| is already properly escaped when returned from
+  // -JSONForJavaScriptFromRequestHeaders:.
+  return
+      [NSString stringWithFormat:
+                    @"__crPostRequestWorkaround.runPostRequest(%@, %@, %@, %@)",
+                    EscapeAndQuoteStringForJavaScript(URLString), headerString,
+                    EscapeAndQuoteStringForJavaScript(base64Data),
+                    EscapeAndQuoteStringForJavaScript(contentType)];
+}
+
+- (NSString*)JSONForJavaScriptFromRequestHeaders:(NSDictionary*)headers {
+  NSData* headerData = nil;

[Eugene But (OOO till 7-30), 2015/12/03 16:51:42]

NIT: Move variable declaration to line 154 and combine with initialization.

[stkhapugin, 2015/12/03 17:51:02]

Done.

+  if (headers) {
+    headerData =
+        [NSJSONSerialization dataWithJSONObject:headers options:0 error:nil];
+    if (headerData) {
+      // This string is properly escaped by NSJSONSerialization. It needs to
+      // have
+      // no quotes since JavaScripts takes this parameter as an
+      // Object<string, string>.
+      return [[[NSString alloc] initWithData:headerData
+                                    encoding:NSUTF8StringEncoding] autorelease];
+    }
+  }
+  return @"{}";
+}
+
+@end