Allow a custom toolchain to be injected into BUILDCONFIG.gn

build/config/BUILDCONFIG.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # =============================================================================
 # PLATFORM SELECTION
 # =============================================================================
 #
 # There are two main things to set: "os" and "cpu". The "toolchain" is the name
 # of the GN thing that encodes combinations of these things.
@@ skipping 107 matching lines @@
   is_debug = true
 
   # Whether we're a traditional desktop unix.
   is_desktop_linux = current_os == "linux" && current_os != "chromeos"
 
   # Set to true when compiling with the Clang compiler. Typically this is used
   # to configure warnings.
   is_clang = current_os == "mac" || current_os == "ios" ||
              current_os == "linux" || current_os == "chromeos"
 
-  if (current_os == "chromeos") {
-    # Allows the target toolchain to be injected as arguments. This is needed
-    # to support the CrOS build system which supports per-build-configuration
-    # toolchains.
-    cros_use_custom_toolchain = false
-  }
+  # Allows the path to a custom target toolchain to be injected as a single
+  # argument, and set as the default toolchain.
+  custom_toolchain = ""
 
   # DON'T ADD MORE FLAGS HERE. Read the comment above.
 }
 
 # =============================================================================
 # OS DEFINITIONS
 # =============================================================================
 #
 # We set these various is_FOO booleans for convenience in writing OS-based
 # conditions.
@@ skipping 338 matching lines @@
 
 # ==============================================================================
 # TOOLCHAIN SETUP
 # ==============================================================================
 #
 # Here we set the default toolchain, as well as the variable host_toolchain
 # which will identify the toolchain corresponding to the local system when
 # doing cross-compiles. When not cross-compiling, this will be the same as the
 # default toolchain.
 
+_default_toolchain = ""
 if (is_win) {
   # On windows we use the same toolchain for host and target by default.
   if (is_clang) {
     host_toolchain = "//build/toolchain/win:clang_$current_cpu"
   } else {
     host_toolchain = "//build/toolchain/win:$current_cpu"
   }
 
   if (current_os == "win") {
-    set_default_toolchain("$host_toolchain")
+    _default_toolchain = host_toolchain
   } else if (current_cpu == "x64") {  # WinRT x64
-    set_default_toolchain("//build/toolchain/win:winrt_x64")
+    _default_toolchain = "//build/toolchain/win:winrt_x64"
   } else if (current_cpu == "x86") {  # WinRT x86
-    set_default_toolchain("//build/toolchain/win:winrt_x86")
+    _default_toolchain = "//build/toolchain/win:winrt_x86"
   }
 } else if (is_android) {
   if (host_os == "linux") {
     # Use clang for the x86/64 Linux host builds.
     if (host_cpu == "x86" || host_cpu == "x64") {
       host_toolchain = "//build/toolchain/linux:clang_$host_cpu"
     } else {
       host_toolchain = "//build/toolchain/linux:$host_cpu"
     }
   } else if (host_os == "mac") {
     host_toolchain = "//build/toolchain/mac:clang_$host_cpu"
   } else {
     assert(false, "Unknown host for android cross compile")
   }
   if (is_clang) {
-    set_default_toolchain("//build/toolchain/android:clang_$current_cpu")
+    _default_toolchain = "//build/toolchain/android:clang_$current_cpu"
   } else {
-    set_default_toolchain("//build/toolchain/android:$current_cpu")
+    _default_toolchain = "//build/toolchain/android:$current_cpu"
   }
 } else if (is_linux) {
   if (is_clang) {
     host_toolchain = "//build/toolchain/linux:clang_$host_cpu"
-    set_default_toolchain("//build/toolchain/linux:clang_$current_cpu")
+    _default_toolchain = "//build/toolchain/linux:clang_$current_cpu"
   } else {
     host_toolchain = "//build/toolchain/linux:$host_cpu"
-    set_default_toolchain("//build/toolchain/linux:$current_cpu")
-  }
-  if (is_chromeos && cros_use_custom_toolchain) {
-    set_default_toolchain("//build/toolchain/cros:target")
+    _default_toolchain = "//build/toolchain/linux:$current_cpu"
   }
 } else if (is_mac) {
   host_toolchain = "//build/toolchain/mac:clang_x64"
-  set_default_toolchain(host_toolchain)
+  _default_toolchain = host_toolchain
 } else if (is_ios) {
   host_toolchain = "//build/toolchain/mac:clang_x64"
-  set_default_toolchain("//build/toolchain/mac:ios_clang_arm")
+  _default_toolchain = "//build/toolchain/mac:ios_clang_arm"
 } else if (is_nacl) {
   # TODO(GYP): This will need to change when we get NaCl working
   # on multiple platforms, but this whole block of code (how we define
   # host_toolchain) needs to be reworked regardless to key off of host_os
   # and host_cpu rather than the is_* variables.
   host_toolchain = "//build/toolchain/linux:clang_x64"
 }
 
+# If a custom toolchain has been set in the args, set it as default. Otherwise,
+# set the default toolchain for the platform (if any).
+if (custom_toolchain != "") {
+  set_default_toolchain(custom_toolchain)
+} else if (_default_toolchain != "") {
+  set_default_toolchain(_default_toolchain)
+}
+
 # ==============================================================================
 # COMPONENT SETUP
 # ==============================================================================
 
 if (is_component_build) {
   _component_mode = "shared_library"
 } else {
   _component_mode = "source_set"
 }
 template("component") {
   target(_component_mode, target_name) {
     forward_variables_from(invoker, "*")
 
     # All shared libraries must have the sanitizer deps to properly link in
     # asan mode (this target will be empty in other cases).
     if (!defined(deps)) {
       deps = []
     }
     deps += [ "//build/config/sanitizers:deps" ]
   }
 }