gn/win: Run reorder-imports.py on chrome.exe

chrome/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//build/config/features.gni")
 import("//build/config/locales.gni")
+import("//build/config/sanitizers/sanitizers.gni")
 import("//build/config/ui.gni")
 import("//build/config/win/manifest.gni")
 import("//chrome/chrome_repack_locales.gni")
 import("//chrome/version.gni")
 
 if (is_android) {
   import("//build/config/android/rules.gni")
 }
 
+if (is_win) {
+  action("reorder_imports") {
+    script = "//build/win/reorder-imports.py"
+
+    # See comment in chrome_dll.gypi in the hardlink_to_output
+    # target for why this cannot be 'initial' like the DLL.
+    inputs = [
+      "$root_out_dir/initialexe/chrome.exe",
+    ]
+    outputs = [
+      "$root_out_dir/chrome.exe",
+      "$root_out_dir/chrome.exe.pdb",
+    ]
+    args = [
+      "-i",
+      rebase_path("$root_out_dir/initialexe", root_build_dir),
+      "-o",
+      rebase_path("$root_out_dir", root_build_dir),
+      "-a",
+      target_cpu,
+    ]
+    deps = [
+      ":chrome_initial",
+    ]
+  }
+}
+
 if (!is_android) {
-  # TODO(GYP) bug 512599: for Windows need to the the reorder-imports step
-  # which probably means adding another target and renaming this to
-  # chrome_initial like in GYP.
-  executable("chrome") {
+  group("chrome") {
+    deps = [
+      ":chrome_initial",
+    ]
+    if (is_win) {
+      deps += [ ":reorder_imports" ]
+    }
+  }
+
+  executable("chrome_initial") {
+    if (is_win) {
+      output_name = "initialexe/chrome"
+    } else {
+      output_name = "chrome"
+    }
+
     # Because the sources list varies so significantly per-platform, generally
     # each platform lists its own files rather than relying on filtering or
     # removing unused files.
     sources = [
       "app/chrome_exe_resource.h",
     ]
     defines = []
     public_deps = []
     deps = [
       "//build/config/sanitizers:deps",
@@ skipping 80 matching lines @@
         "//crypto",
         "//sandbox",
         "//ui/gfx",
       ]
       data_deps = [ "//chrome/app/version_assembly:version_assembly_manifest" ]
 
       libs = [
         "wintrust.lib",
         "crypt32.lib",
       ]
-      configs -= [ "//build/config/win:console" ]
-      configs += [ "//build/config/win:windowed" ]
+      if (!is_asan) {
+        # Set /SUBSYSTEM:WINDOWS for chrome.exe itself, except for the
+        # AddressSanitizer build where console output is important.
+        configs -= [ "//build/config/win:console" ]
+        configs += [ "//build/config/win:windowed" ]
+      }
     } else if (use_aura) {
       # Non-Windows aura entrypoint.
       sources += [ "app/chrome_exe_main_aura.cc" ]
     }
 
     if (is_linux) {
       sources += [
         "app/chrome_dll_resource.h",
         "app/chrome_main.cc",
         "app/chrome_main_delegate.cc",
         "app/chrome_main_delegate.h",
       ]
 
       deps += [
         # On Linux, link the dependencies (libraries) that make up actual
         # Chromium functionality directly into the executable.
         ":browser_dependencies",
         ":child_dependencies",
         ":manpage",
         "//base/allocator",
 
         # Needed to use the master_preferences functions
         "//chrome/installer/util",
         "//content/public/app:both",
       ]
+      if (enable_plugins) {
+        deps += [ "//pdf" ]
+      }
+
       public_deps = [
         ":xdg_mime",  # Needs to be public for installer to consume files.
       ]
 
       # Needed for chrome_main.cc initialization of libraries.
       configs += [ "//build/config/linux:pangocairo" ]
 
       # GYP has this in a 'profiling==0 and linux_disable_pie==0' condition.
       # but GN doesn't have either of these flags.
       ldflags = [ "-pie" ]
@@ skipping 19 matching lines @@
         "//components/startup_metric_utils",
 
         # Precompiled plugins that need to get copied to the output directory.
         # On Mac, internal plugins go inside the framework, so these
         # dependencies are on chrome.dll.
         "//third_party/adobe/flash:flapper_binaries",
         "//third_party/widevine/cdm:widevinecdmadapter",
       ]
     }
 
-    if (is_linux && enable_plugins) {
-      deps += [ "//pdf" ]
-    }
-
     if (is_multi_dll_chrome) {
       defines += [ "CHROME_MULTIPLE_DLL" ]
       data_deps += [ ":chrome_child" ]
     }
   }
 }  # !is_android
 
 shared_library("main_dll") {
   configs += [ "//build/config/compiler:wexit_time_destructors" ]
   defines = []
@@ skipping 766 matching lines @@
       "//chrome/app/theme/$branding_path_component/product_logo_48.png",
       "//chrome/tools/build/linux/chrome-wrapper",
       "//third_party/xdg-utils/scripts/xdg-mime",
       "//third_party/xdg-utils/scripts/xdg-settings",
     ]
     outputs = [
       "$root_out_dir/{{source_file_part}}",
     ]
   }
 }