WKWebView: Implemented recoverable SSL interstitials.

ios/web/net/crw_cert_verification_controller.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/web/net/crw_cert_verification_controller.h"
 
 #include "base/logging.h"
 #include "base/mac/bind_objc_block.h"
 #import "base/memory/ref_counted.h"
 #import "base/memory/scoped_ptr.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/threading/worker_pool.h"
 #include "ios/web/net/cert_verifier_block_adapter.h"
 #include "ios/web/public/browser_state.h"
+#include "ios/web/public/certificate_policy_cache.h"
 #include "ios/web/public/web_thread.h"
 #import "ios/web/web_state/wk_web_view_security_util.h"
 #include "net/cert/cert_verify_result.h"
 #include "net/ssl/ssl_config_service.h"
 #include "net/url_request/url_request_context.h"
 #include "net/url_request/url_request_context_getter.h"
 
 namespace {
 
 // This class takes ownership of block and releases it on UI thread, even if
@@ skipping 35 matching lines @@
 
 }  // namespace
 
 @interface CRWCertVerificationController () {
   // Cert verification object which wraps |net::CertVerifier|. Must be created,
   // used and destroyed on IO Thread.
   scoped_ptr<web::CertVerifierBlockAdapter> _certVerifier;
 
   // URLRequestContextGetter for obtaining net layer objects.
   net::URLRequestContextGetter* _contextGetter;
+
+  // Used to remember user exceptions to invalid certs.
+  scoped_refptr<web::CertificatePolicyCache> _certPolicyCache;
 }
 
 // Cert verification flags. Must be used on IO Thread.
 @property(nonatomic, readonly) int certVerifyFlags;
 
 // Creates _certVerifier object on IO thread.
 - (void)createCertVerifier;
 
 // Verifies the given |cert| for the given |host| using |net::CertVerifier| and
 // calls |completionHandler| on completion. This method can be called on any
 // thread. |completionHandler| cannot be null and will be called asynchronously
-// on IO thread.
+// on IO thread or synchronously on current thread if IO task can't start (in
+// this case |dispatched| argument will be NO).

[Ryan Sleevi, 2015/10/19 23:56:22]

This is really surprising; should this be in a separate CL? COuld you explain
more here?

[Eugene But (OOO till 7-30), 2015/10/21 04:01:02]

WKWebView throws an exception (which leads to a crash) if any of it's completion
handlers is not called. To prevent that completion handlers of
CRWCertVerificationController must always be called as well.

Added comments to the header file. I think it's fine if this change is a part of
current CL, will make a separate one though if you have very strong opinion.

 - (void)verifyCert:(const scoped_refptr<net::X509Certificate>&)cert
               forHost:(NSString*)host
-    completionHandler:(void (^)(net::CertVerifyResult, int))completionHandler;
+    completionHandler:(void (^)(net::CertVerifyResult, BOOL dispatched))handler;
 
 // Verifies the given |trust| using SecTrustRef API. |completionHandler| cannot
 // be null and will be either called asynchronously on Worker thread or
 // synchronously on current thread if the worker task can't start (in this
 // case |dispatched| argument will be NO).
 - (void)verifyTrust:(base::ScopedCFTypeRef<SecTrustRef>)trust
     completionHandler:(void (^)(SecTrustResultType, BOOL dispatched))handler;
 
+// Returns cert accept policy for the given SecTrust result. |trustResult| must
+// not be for a valid cert. Must be called on IO thread.
+- (web::CertAcceptPolicy)
+    loadPolicyForBadTrustResult:(SecTrustResultType)trustResult
+             certVerifierResult:(net::CertVerifyResult)certVerifierResult
+                    serverTrust:(SecTrustRef)trust
+                           host:(NSString*)host;
+
 @end
 
 @implementation CRWCertVerificationController
 
 #pragma mark - Superclass
 
 - (void)dealloc {
   DCHECK(!_certVerifier);
   [super dealloc];
 }
 
 #pragma mark - Public
 
 - (instancetype)init {
   NOTREACHED();
   return nil;
 }
 
 - (instancetype)initWithBrowserState:(web::BrowserState*)browserState {
   DCHECK(browserState);
   DCHECK_CURRENTLY_ON_WEB_THREAD(web::WebThread::UI);
   self = [super init];
   if (self) {
     _contextGetter = browserState->GetRequestContext();
     DCHECK(_contextGetter);
+    _certPolicyCache =
+        web::BrowserState::GetCertificatePolicyCache(browserState);
+
     [self createCertVerifier];
   }
   return self;
 }
 
-- (void)decidePolicyForCert:(const scoped_refptr<net::X509Certificate>&)cert
-                       host:(NSString*)host
-          completionHandler:(web::PolicyDecisionHandler)completionHandler {
+- (void)decideLoadPolicyForTrust:(base::ScopedCFTypeRef<SecTrustRef>)trust
+                            host:(NSString*)host
+               completionHandler:(web::PolicyDecisionHandler)completionHandler {
   DCHECK_CURRENTLY_ON_WEB_THREAD(web::WebThread::UI);
   // completionHandler of |verifyCert:forHost:completionHandler:| is called on
   // IO thread and then bounces back to UI thread. As a result all objects
   // captured by completionHandler may be released on either UI or IO thread.
   // Since |completionHandler| can potentially capture multiple thread unsafe
   // objects (like Web Controller) |completionHandler| itself should never be
   // released on background thread and |BlockHolder| ensures that.
   __block scoped_refptr<BlockHolder<web::PolicyDecisionHandler>> handlerHolder(
       new BlockHolder<web::PolicyDecisionHandler>(completionHandler));
-  [self verifyCert:cert
-                forHost:host
-      completionHandler:^(net::CertVerifyResult result, int error) {
-        web::CertAcceptPolicy policy =
-            web::CERT_ACCEPT_POLICY_NON_RECOVERABLE_ERROR;
-        if (error == net::OK) {
-          policy = web::CERT_ACCEPT_POLICY_ALLOW;
-        } else if (net::IsCertStatusError(result.cert_status)) {
-          policy = net::IsCertStatusMinorError(result.cert_status)
-                       ? web::CERT_ACCEPT_POLICY_ALLOW
-                       : web::CERT_ACCEPT_POLICY_RECOVERABLE_ERROR;
+  [self verifyTrust:trust
+      completionHandler:^(SecTrustResultType trustResult, BOOL dispatched) {
+        if (!dispatched) {
+          // Cert verification task did not start.
+          dispatch_async(dispatch_get_main_queue(), ^{
+            handlerHolder->call(web::CERT_ACCEPT_POLICY_NON_RECOVERABLE_ERROR,
+                                net::CertStatus());
+          });
+          return;
         }
 
-        dispatch_async(dispatch_get_main_queue(), ^{
-          handlerHolder->call(policy, result.cert_status);
-        });
+        if (web::GetSecurityStyleFromTrustResult(trustResult) ==
+            web::SECURITY_STYLE_AUTHENTICATED) {
+          // SecTrust API considers this cert as valid.
+          dispatch_async(dispatch_get_main_queue(), ^{
+            handlerHolder->call(web::CERT_ACCEPT_POLICY_ALLOW,
+                                net::CertStatus());
+          });
+          return;
+        }
+
+        // SecTrust API considers this cert as invalid. Check the reason and
+        // whether or not user has decided to proceed with this bad cert.
+        scoped_refptr<net::X509Certificate> cert(
+            web::CreateCertFromTrust(trust));
+        [self verifyCert:cert
+                      forHost:host
+            completionHandler:^(net::CertVerifyResult certVerifierResult,
+                                BOOL dispatched) {
+              if (!dispatched) {
+                // Cert verification task did not start.
+                dispatch_async(dispatch_get_main_queue(), ^{
+                  handlerHolder->call(
+                      web::CERT_ACCEPT_POLICY_NON_RECOVERABLE_ERROR,
+                      net::CertStatus());
+                });
+                return;
+              }
+
+              web::CertAcceptPolicy policy =
+                  [self loadPolicyForBadTrustResult:trustResult
+                                 certVerifierResult:certVerifierResult
+                                        serverTrust:trust.get()
+                                               host:host];
+
+              dispatch_async(dispatch_get_main_queue(), ^{
+                handlerHolder->call(policy, certVerifierResult.cert_status);
+              });
+            }];
       }];
 }
 
 - (void)querySSLStatusForTrust:(base::ScopedCFTypeRef<SecTrustRef>)trust
                           host:(NSString*)host
              completionHandler:(web::StatusQueryHandler)completionHandler {
   DCHECK_CURRENTLY_ON_WEB_THREAD(web::WebThread::UI);
 
   // The completion handlers of |verifyCert:forHost:completionHandler:| and
   // |verifyTrust:completionHandler:| will be deallocated on background thread.
@@ skipping 23 matching lines @@
 
         // Retrieve the net::CertStatus for invalid certificates to determine
         // the rejection reason, it is possible that rejection reason could not
         // be determined and |cert_status| will be empty.
         // TODO(eugenebut): Add UMA for CertVerifier and SecTrust verification
         // mismatch (crbug.com/535699).
         scoped_refptr<net::X509Certificate> cert(
             web::CreateCertFromTrust(trust));
         [self verifyCert:cert
                       forHost:host
-            completionHandler:^(net::CertVerifyResult certVerifierResult, int) {
+            completionHandler:^(net::CertVerifyResult certVerifierResult,
+                                BOOL) {
               dispatch_async(dispatch_get_main_queue(), ^{
                 handlerHolder->call(securityStyle,
                                     certVerifierResult.cert_status);
               });
             }];
       }];
 }
 
+- (void)allowCert:(scoped_refptr<net::X509Certificate>)cert
+          forHost:(NSString*)host
+           status:(net::CertStatus)status {
+  DCHECK_CURRENTLY_ON_WEB_THREAD(web::WebThread::UI);
+  // Store user decision only for leaf server cert, and drop any intermediates.
+  // This is a workaround for WKWebView behavior, where different delegate
+  // methods receive different certificate chains for the same server cert.

[Ryan Sleevi, 2015/10/19 23:56:21]

You should explain more of the context in the code, to prevent people from
having to spleunk what you mean

// Store user decisions with the leaf cert, ignoring any intermediates.
// This is because WKWebView returns the verified certificate chain in
// [?? delegate X], but the server-supplied chain in [?? delegate Y].

[Eugene But (OOO till 7-30), 2015/10/21 04:01:02]

Done.

+  if (cert->GetIntermediateCertificates().size() > 0) {
+    cert = net::X509Certificate::CreateFromHandle(
+        cert->os_cert_handle(), net::X509Certificate::OSCertHandles());
+  }
+  DCHECK_EQ(0U, cert->GetIntermediateCertificates().size());
+  web::WebThread::PostTask(web::WebThread::IO, FROM_HERE, base::BindBlock(^{
+    _certPolicyCache->AllowCertForHost(
+        cert.get(), base::SysNSStringToUTF8(host), status);
+  }));
+}
+
 - (void)shutDown {
   DCHECK_CURRENTLY_ON_WEB_THREAD(web::WebThread::UI);
   web::WebThread::PostTask(web::WebThread::IO, FROM_HERE, base::BindBlock(^{
     // This block captures |self| delaying its deallocation and causing dealloc
     // to happen on either IO or UI thread (which is fine for this class).
     _certVerifier.reset();
   }));
 }
 
 #pragma mark - Private
@@ skipping 15 matching lines @@
 - (void)createCertVerifier {
   web::WebThread::PostTask(web::WebThread::IO, FROM_HERE, base::BindBlock(^{
     net::URLRequestContext* context = _contextGetter->GetURLRequestContext();
     _certVerifier.reset(new web::CertVerifierBlockAdapter(
         context->cert_verifier(), context->net_log()));
   }));
 }
 
 - (void)verifyCert:(const scoped_refptr<net::X509Certificate>&)cert
               forHost:(NSString*)host
-    completionHandler:(void (^)(net::CertVerifyResult, int))completionHandler {
+    completionHandler:(void (^)(net::CertVerifyResult, BOOL))completionHandler {
   DCHECK(completionHandler);
   __block scoped_refptr<net::X509Certificate> blockCert = cert;
-  web::WebThread::PostTask(
+  bool dispatched = web::WebThread::PostTask(
       web::WebThread::IO, FROM_HERE, base::BindBlock(^{
         // WeakNSObject does not work across different threads, hence this block
         // retains self.
         if (!_certVerifier) {
           completionHandler(net::CertVerifyResult(), net::ERR_FAILED);
           return;
         }
 
         web::CertVerifierBlockAdapter::Params params(
             blockCert.Pass(), base::SysNSStringToUTF8(host));
         params.flags = self.certVerifyFlags;
         params.crl_set = net::SSLConfigService::GetCRLSet();
         // OCSP response is not provided by iOS API.
-        _certVerifier->Verify(params, completionHandler);
+        _certVerifier->Verify(params, ^(net::CertVerifyResult result, int) {
+          completionHandler(result, YES);
+        });
       }));
+
+  if (!dispatched) {
+    completionHandler(net::CertVerifyResult(), NO);

[Ryan Sleevi, 2015/10/19 23:56:21]

Are you sure this is safe to recursively call into here? It seems really weird
given line 178 that this isn't an async dispatch or a return code.

[Eugene But (OOO till 7-30), 2015/10/21 04:01:02]

Yes, this is safe. Maybe weird, but still safe.

+  }
 }
 
 - (void)verifyTrust:(base::ScopedCFTypeRef<SecTrustRef>)trust
     completionHandler:(void (^)(SecTrustResultType, BOOL))completionHandler {
   DCHECK(completionHandler);
   // SecTrustEvaluate performs trust evaluation synchronously, possibly making
   // network requests. The UI thread should not be blocked by that operation.
   bool dispatched = base::WorkerPool::PostTask(FROM_HERE, base::BindBlock(^{
     SecTrustResultType trustResult = kSecTrustResultInvalid;
     if (SecTrustEvaluate(trust.get(), &trustResult) != errSecSuccess) {
       trustResult = kSecTrustResultInvalid;
     }
     completionHandler(trustResult, YES);
   }), false /* task_is_slow */);
 
   if (!dispatched) {
     completionHandler(kSecTrustResultInvalid, NO);
   }
 }
 
+- (web::CertAcceptPolicy)
+    loadPolicyForBadTrustResult:(SecTrustResultType)trustResult
+             certVerifierResult:(net::CertVerifyResult)certVerifierResult
+                    serverTrust:(SecTrustRef)trust
+                           host:(NSString*)host {
+  DCHECK_CURRENTLY_ON_WEB_THREAD(web::WebThread::IO);
+  DCHECK_NE(web::SECURITY_STYLE_AUTHENTICATED,
+            web::GetSecurityStyleFromTrustResult(trustResult));
+
+  if (trustResult != kSecTrustResultRecoverableTrustFailure ||
+      SecTrustGetCertificateCount(trust) == 0) {
+    // Trust result is not recoverable or leaf cert is missing.
+    return web::CERT_ACCEPT_POLICY_NON_RECOVERABLE_ERROR;
+  }
+
+  // Check if user has decided to proceed with this bad cert.
+  scoped_refptr<net::X509Certificate> leafCert =
+      net::X509Certificate::CreateFromHandle(
+          SecTrustGetCertificateAtIndex(trust, 0),
+          net::X509Certificate::OSCertHandles());
+
+  web::CertPolicy::Judgment judgment = _certPolicyCache->QueryPolicy(
+      leafCert.get(), base::SysNSStringToUTF8(host),
+      certVerifierResult.cert_status);
+
+  return (judgment == web::CertPolicy::ALLOWED)
+             ? web::CERT_ACCEPT_POLICY_RECOVERABLE_ERROR_ACCEPTED_BY_USER
+             : web::CERT_ACCEPT_POLICY_RECOVERABLE_ERROR_UNDECIDED_BY_USER;
+}
+
 @end