CMake: Compile in OSMesa on Linux, if found.

cmake/CMakeLists.txt

 # Boilerplate.
 cmake_minimum_required (VERSION 3.1)   # First version with CMAKE_CXX_STANDARD.
 project (skimake)
 set (CMAKE_CXX_STANDARD 11)
 
 # Default to Release mode.  We're mainly targeting Skia users, not Skia developers.
 if (NOT CMAKE_BUILD_TYPE)
     set (CMAKE_BUILD_TYPE Release)
 endif ()
 
@@ skipping 82 matching lines @@
 # Make our ports choices.
 remove_srcs(
     ../src/*moz*   # We're probably not Mozilla.
     ../src/gpu/GrContextFactory.cpp                  # For internal testing only.
     ../src/gpu/gl/GrGLCreateNativeInterface_none.cpp
     ../src/gpu/gl/GrGLDefaultInterface_none.cpp
     ../src/gpu/gl/SkCreatePlatformGLContext*.cpp     # For internal testing only.
     ../src/gpu/gl/command_buffer/*
     ../src/gpu/gl/egl/*
     ../src/gpu/gl/iOS/*
-    ../src/gpu/gl/mesa/*
     ../src/opts/SkBitmapProcState_opts_none.cpp
     ../src/opts/SkBlitMask_opts_none.cpp
     ../src/opts/SkBlitRow_opts_none.cpp
     ../src/ports/SkFontMgr_empty_factory.cpp
     ../src/ports/SkGlobalInitialization_chromium.cpp
     ../src/ports/SkImageDecoder_empty.cpp
     ../src/ports/SkImageGenerator_none.cpp
     ../src/ports/SkTLS_none.cpp)
 
 remove_srcs(../src/codec/*)  # TODO: Requires Chromium's libjpeg-turbo, and incompatible giflib.
@@ skipping 78 matching lines @@
 endif()
 
 if (APPLE)
     find_library(APPLICATION_SERVICES_FRAMEWORK ApplicationServices REQUIRED)
     list (APPEND libs ${APPLICATION_SERVICES_FRAMEWORK})
 endif()
 
 find_package(OpenGL REQUIRED)
 list (APPEND libs  ${OPENGL_LIBRARIES})
 
+list (APPEND private_defines "-DSKIA_DLL")

[mtklein_C, 2015/09/21 16:14:39]

As a nit, let's move this out of where all the deps are found.  Maybe, line ~217
just above the target_compile_definitions call?

[hal.canary, 2015/09/21 16:35:57]

Done.

+
+find_library(OSMESA_LIBRARIES "OSMesa")

[mtklein_C, 2015/09/21 16:14:39]

Let's put the find_* together with the others above for consistency?

[hal.canary, 2015/09/21 16:35:57]

Done.

+find_path (OSMESA_INCLUDE_DIRS "GL/osmesa.h")
+if (OSMESA_LIBRARIES AND OSMESA_INCLUDE_DIRS)
+    list (APPEND libs  ${OSMESA_LIBRARIES})

[mtklein_C, 2015/09/21 16:14:39]

Add OSMESA_INCLUDE_DIRS to private_includes?

[hal.canary, 2015/09/21 16:35:57]

It was just /usr/include;  but no harm.  done.

+    list (APPEND public_defines "-DSK_MESA=1")
+    message("-- Found OSMesa: " ${OSMESA_LIBRARIES})

[mtklein_C, 2015/09/21 16:14:39]

Remove this.  It'll print anyway

+else()
+    remove_srcs(../src/gpu/gl/mesa/*)
+endif()
+
 # This is our main output, libskia.so.
 # We mostly build an .so here because it helps test we've linked everything,
 # not so much that we think Skia is a good candidate to ship as a shared library.
 add_library (skia SHARED ${srcs})
 
 target_compile_definitions(skia
-    PUBLIC
-    PRIVATE -DSKIA_DLL)
+    PUBLIC  ${public_defines}
+    PRIVATE ${private_defines})
 
 target_include_directories(skia
     PUBLIC  ${public_includes}
     PRIVATE ${private_includes})
 
 target_link_libraries(skia
     PUBLIC
     PRIVATE ${libs})
 
 
 set_target_properties(skia PROPERTIES
     COMPILE_FLAGS "-fno-exceptions -fno-rtti -Wno-deprecated-declarations"
     CXX_VISIBILITY_PRESET hidden
     VISIBILITY_INLINES_HIDDEN true)
 
 # Experimental C API install:
 file(GLOB cheaders "../include/c/*.h")
 install(FILES ${cheaders} DESTINATION include)
 install(TARGETS skia DESTINATION lib)
 
 # Now build a simple example app that uses Skia via libskia.so.
 add_executable(example example.cpp)
 target_link_libraries(example skia ${OPENGL_LIBRARIES})