experiment/fiddle

cmake/CMakeLists.txt

 # Boilerplate.
 cmake_minimum_required (VERSION 3.1)   # First version with CMAKE_CXX_STANDARD.
 project (skimake)
 set (CMAKE_CXX_STANDARD 11)
 
 # Default to Release mode.  We're mainly targeting Skia users, not Skia developers.
 if (NOT CMAKE_BUILD_TYPE)
     set (CMAKE_BUILD_TYPE Release)
 endif ()
 
 # To first approximation, the Skia library comprises all .cpp files under src/.
 file (GLOB_RECURSE srcs ../src/*.cpp)
 
 function (find_include_dirs out)
     file (GLOB_RECURSE headers ${ARGN})
     foreach (path ${headers})
         get_filename_component (dir ${path} PATH)
         list (APPEND include_dirs ${dir})
     endforeach()
     list (REMOVE_DUPLICATES include_dirs)
     set (${out} ${include_dirs} PARENT_SCOPE)
 endfunction()
 
 # We need src/ directories and include/private on our path when building Skia.
 # Users should be able to use Skia with only include/ directories that are not include/private.
 find_include_dirs(private_includes ../src/*.h ../include/private/*.h)

[mtklein, 2015/09/17 13:58:22]

add include/config/*.h here instead?

 find_include_dirs(public_includes ../include/*.h)
 list (REMOVE_ITEM public_includes ${private_includes})  # Easiest way to exclude private.
 
+find_include_dirs(config_include ../include/config/*.h)
+list (REMOVE_ITEM public_includes ${config_include})
+
 # These guys are third_party but provided by a Skia checkout.
 list (APPEND srcs             ../third_party/etc1/etc1.cpp ../third_party/ktx/ktx.cpp)
 list (APPEND private_includes ../third_party/etc1          ../third_party/ktx)
 
 function (remove_srcs)
     file (GLOB_RECURSE to_remove ${ARGN})
     list (REMOVE_ITEM srcs ${to_remove})
     set (srcs ${srcs} PARENT_SCOPE)
 endfunction()
 
@@ skipping 53 matching lines @@
 # Make our ports choices.
 remove_srcs(
     ../src/*moz*   # We're probably not Mozilla.
     ../src/gpu/GrContextFactory.cpp                  # For internal testing only.
     ../src/gpu/gl/GrGLCreateNativeInterface_none.cpp
     ../src/gpu/gl/GrGLDefaultInterface_none.cpp
     ../src/gpu/gl/SkCreatePlatformGLContext*.cpp     # For internal testing only.
     ../src/gpu/gl/command_buffer/*
     ../src/gpu/gl/egl/*
     ../src/gpu/gl/iOS/*
-    ../src/gpu/gl/mesa/*
     ../src/opts/SkBitmapProcState_opts_none.cpp
     ../src/opts/SkBlitMask_opts_none.cpp
     ../src/opts/SkBlitRow_opts_none.cpp
     ../src/ports/SkFontMgr_empty_factory.cpp
     ../src/ports/SkGlobalInitialization_chromium.cpp
     ../src/ports/SkImageDecoder_empty.cpp
     ../src/ports/SkImageGenerator_none.cpp
     ../src/ports/SkTLS_none.cpp)
 
 remove_srcs(../src/codec/*)  # TODO: Requires Chromium's libjpeg-turbo, and incompatible giflib.
@@ skipping 70 matching lines @@
 if (FREETYPE_FOUND)
     list (APPEND private_includes ${FREETYPE_INCLUDE_DIRS})
     list (APPEND libs             ${FREETYPE_LIBRARIES})
 endif()
 
 if (FONTCONFIG_INCLUDE_DIRS AND FONTCONFIG_LIBRARIES)
     list (APPEND private_includes ${FONTCONFIG_INCLUDE_DIRS})
     list (APPEND libs             ${FONTCONFIG_LIBRARIES})
 endif()
 
+
 if (APPLE)
     find_library(APPLICATION_SERVICES_FRAMEWORK ApplicationServices REQUIRED)
     list (APPEND libs ${APPLICATION_SERVICES_FRAMEWORK})
 endif()
 
 find_package(OpenGL REQUIRED)
 list (APPEND libs  ${OPENGL_LIBRARIES})
 
+set(SK_MESA OFF CACHE BOOL "Support for off-screen Mesa OpenGL")
+if(${CMAKE_BUILD_TYPE} STREQUAL "Debug")

[mtklein, 2015/09/17 13:58:22]

This seems unnecessary.  SK_DEBUG / SK_RELEASE are set by the presence of
NDEBUG.

+  set(SK_DEBUG 1)
+  set(SK_RELEASE 0)
+else()
+  set(SK_DEBUG 0)
+  set(SK_RELEASE 1)
+endif()
+configure_file(SkUserConfig.h.in SkUserConfig.h)

[mtklein, 2015/09/17 13:58:22]

Let's not do this.  I haven't seen any need yet for a non-default (non-empty)
SkUserConfig.h.

+
 # This is our main output, libskia.so.
 # We mostly build an .so here because it helps test we've linked everything,
 # not so much that we think Skia is a good candidate to ship as a shared library.
 add_library (skia SHARED ${srcs})
 
+if (UNIX AND NOT APPLE AND SK_MESA)

[mtklein, 2015/09/17 13:58:22]

Why is this opt-in?  Can we not just detect it like the other dependencies?

+    # TODO(halcanary):  support SK_MESA+APPLE
+    list (APPEND libs "OSMesa")
+    # SK_MESA is used by fiddle.skia.org
+else()
+     remove_srcs(../src/gpu/gl/mesa/*)
+endif()
+
 target_compile_definitions(skia
     PUBLIC
     PRIVATE -DSKIA_DLL)
 
 target_include_directories(skia
     PUBLIC  ${public_includes}
+            ${CMAKE_BINARY_DIR}
     PRIVATE ${private_includes})
 
 target_link_libraries(skia
     PUBLIC
     PRIVATE ${libs})
 
-
 set_target_properties(skia PROPERTIES
     COMPILE_FLAGS "-fno-exceptions -fno-rtti -Wno-deprecated-declarations"
     CXX_VISIBILITY_PRESET hidden
     VISIBILITY_INLINES_HIDDEN true)
 
-# Experimental C API install:
-file(GLOB cheaders "../include/c/*.h")
-install(FILES ${cheaders} DESTINATION include)
+# Experimental install:
 install(TARGETS skia DESTINATION lib)
+install(DIRECTORY ../include/c       DESTINATION include/skia)
+install(DIRECTORY ../include/core    DESTINATION include/skia)

[mtklein, 2015/09/17 13:58:22]

Yeah, again, I think it's a bad idea to even insinuate we should be installing
headers and skia places.  Particularly true with the C++ API.  If you want to do
this for fiddle, do it in a script outside here?

+install(DIRECTORY ../include/effects DESTINATION include/skia)
+install(DIRECTORY ../include/gpu     DESTINATION include/skia)
+install(DIRECTORY ../include/pathops DESTINATION include/skia)
+install(DIRECTORY ../include/ports   DESTINATION include/skia)
+install(DIRECTORY ../include/private DESTINATION include/skia)
+install(DIRECTORY ../include/utils   DESTINATION include/skia)
+install(FILES ${CMAKE_BINARY_DIR}/SkUserConfig.h DESTINATION include/skia/core)
 
 # Now build a simple example app that uses Skia via libskia.so.
 add_executable(example example.cpp)
 target_link_libraries(example skia ${OPENGL_LIBRARIES})