Refactor NaCl IRT toolchains, use arm-nacl-clang

build/toolchain/nacl/BUILD.gn

 # Copyright (c) 2014 The Native Client Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/sysroot.gni")
 import("//build/toolchain/nacl_toolchain.gni")
 
 nacl_toolchain_dir = rebase_path("//native_client/toolchain", root_build_dir)
 os_toolchain_dir = "${nacl_toolchain_dir}/${current_os}_x86"
 
@@ skipping 121 matching lines @@
   toolchain_cpu = "x64"
   toolprefix = "${os_toolchain_dir}/${toolchain_package}/bin/x86_64-nacl-"
   is_clang = true
 
   cc = toolprefix + "clang"
   cxx = toolprefix + "clang++"
   ar = toolprefix + "ar"
   ld = cxx
 }
 
-link_irt = rebase_path("//native_client/build/link_irt.py", root_build_dir)
+template("nacl_irt_toolchain") {
+  toolchain_cpu = target_name
+  assert(defined(invoker.toolchain_tuple), "Must define toolchain_tuple")
 
-nacl_toolchain("irt_x86") {
   toolchain_package = "pnacl_newlib"
   toolchain_revision = pnacl_newlib_rev
-  toolchain_cpu = "x86"
-  toolprefix = "${os_toolchain_dir}/${toolchain_package}/bin/i686-nacl-"
-  is_clang = true
+  toolprefix = "${os_toolchain_dir}/${toolchain_package}/bin/" +
+               invoker.toolchain_tuple + "-"
 
-  cc = toolprefix + "clang"
-  cxx = toolprefix + "clang++"
-  ar = toolprefix + "ar"
-  readelf = toolprefix + "readelf"
+  link_irt = rebase_path("//native_client/build/link_irt.py", root_build_dir)
 
   tls_edit_label =
       "//native_client/src/tools/tls_edit:tls_edit($host_toolchain)"
   host_toolchain_out_dir =
       rebase_path(get_label_info(tls_edit_label, "root_out_dir"),
                   root_build_dir)
+  tls_edit = "${host_toolchain_out_dir}/tls_edit"
 
-  # Some IRT implementations (notably, Chromium's) contain C++ code,
-  # so we need to link w/ the C++ linker.
-  ld = "${python_path} ${link_irt} --tls-edit=${host_toolchain_out_dir}/tls_edit --link-cmd=${cxx} --readelf-cmd=${readelf}"
+  nacl_toolchain("irt_" + toolchain_cpu) {
+    is_clang = true
+    cc = toolprefix + "clang"
+    cxx = toolprefix + "clang++"
+    ar = toolprefix + "ar"
+    readelf = toolprefix + "readelf"
 
-  # TODO(ncbray): depend on link script
-  deps = [
-    tls_edit_label,
-  ]
+    # Some IRT implementations (notably, Chromium's) contain C++ code,
+    # so we need to link w/ the C++ linker.
+    ld = "${python_path} ${link_irt} --tls-edit=${tls_edit} --link-cmd=${cxx} --readelf-cmd=${readelf}"
+
+    # TODO(ncbray): depend on link script
+    deps = [
+      tls_edit_label,
+    ]
+  }
 }
 
-nacl_toolchain("irt_x64") {
-  toolchain_package = "pnacl_newlib"
-  toolchain_revision = pnacl_newlib_rev
-  toolchain_cpu = "x64"
-  toolprefix = "${os_toolchain_dir}/${toolchain_package}/bin/x86_64-nacl-"
-  is_clang = true
-
-  cc = toolprefix + "clang"
-  cxx = toolprefix + "clang++"
-  ar = toolprefix + "ar"
-  readelf = toolprefix + "readelf"
-
-  # Some IRT implementations (notably, Chromium's) contain C++ code,
-  # so we need to link w/ the C++ linker.
-  ld = "${python_path} ${link_irt} --tls-edit=tls_edit --link-cmd=${cxx} --readelf-cmd=${readelf}"
-
-  # TODO(ncbray): depend on link script
-  deps = [
-    "//native_client/src/tools/tls_edit:tls_edit($host_toolchain)",
-  ]
+nacl_irt_toolchain("x86") {
+  toolchain_tuple = "i686-nacl"
 }
 
-# Uses newlib to match the Chrome build.
-nacl_toolchain("irt_arm") {
-  toolchain_package = "nacl_arm_newlib"
-  toolchain_revision = nacl_arm_newlib_rev
-  toolchain_cpu = "arm"
-  toolprefix = "${os_toolchain_dir}/${toolchain_package}/bin/arm-nacl-"
-  is_clang = false
+nacl_irt_toolchain("x64") {
+  toolchain_tuple = "x86_64-nacl"
+}
 
-  cc = toolprefix + "gcc"
-  cxx = toolprefix + "g++"
-  ar = toolprefix + "ar"
-  readelf = toolprefix + "readelf"
-
-  # Some IRT implementations (notably, Chromium's) contain C++ code,
-  # so we need to link w/ the C++ linker.
-  ld = "${python_path} ${link_irt} --tls-edit=tls_edit --link-cmd=${cxx} --readelf-cmd=${readelf}"
-
-  # TODO(ncbray): depend on link script
-  deps = [
-    "//native_client/src/tools/tls_edit:tls_edit($host_toolchain)",
-  ]
+nacl_irt_toolchain("arm") {
+  toolchain_tuple = "arm-nacl"
 }