GN: Side-load dex files as well as native code in incremental installs

build/config/android/internal_rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/android/config.gni")
 import("//third_party/ijar/ijar.gni")
 
 assert(is_android)
 
 rebased_android_sdk = rebase_path(android_sdk, root_build_dir)
@@ skipping 501 matching lines @@
 #   deps: Specifies the dependencies of this target.
 #   dex_path: Path to classes.dex file to include (optional).
 #   resource_packaged_apk_path: Path to .ap_ to use.
 #   output_apk_path: Output path for the generated .apk.
 #   native_libs_dir: Directory containing native libraries.
 template("package_apk") {
   action(target_name) {
     forward_variables_from(invoker,
                            [
                              "deps",
-                             "data_deps",
                              "public_deps",
                              "testonly",
                            ])
     script = "//build/android/gyp/ant.py"
     _ant_script = "//build/android/ant/apk-package.xml"
 
     depfile = "$target_gen_dir/$target_name.d"
+    data_deps = [ "//tools/android/md5sum" ]  # Used when deploying APKs
 
     inputs = [
       invoker.resource_packaged_apk_path,
       _ant_script,
     ]
     if (defined(invoker.dex_path)) {
       inputs += [ invoker.dex_path ]
     }
 
     outputs = [
@@ skipping 108 matching lines @@
   _base_path = invoker.base_path
   _final_apk_path = invoker.apk_path
   _incremental_final_apk_path_helper =
       process_file_template(
           [ _final_apk_path ],
           "{{source_dir}}/{{source_name_part}}_incremental.apk")
   _incremental_final_apk_path = _incremental_final_apk_path_helper[0]
 
   if (defined(invoker.resources_zip)) {
     _resources_zip = invoker.resources_zip
+    assert(_resources_zip != "")  # Mark as used.
   }
   if (defined(invoker.dex_path)) {
     _dex_path = invoker.dex_path
   }
   _load_library_from_apk = invoker.load_library_from_apk
 
-  _package_deps = []
+  _deps = []
   if (defined(invoker.deps)) {
-    _package_deps = invoker.deps
+    _deps = invoker.deps
   }
 
   _native_libs_dir = "//build/android/empty/res"
   if (defined(invoker.native_libs_dir)) {
     _native_libs_dir = invoker.native_libs_dir
   }
 
   if (defined(invoker.asset_location)) {
     _asset_location = invoker.asset_location
+    assert(_asset_location != "")  # Mark as used.
   }
 
   _version_code = invoker.version_code
   _version_name = invoker.version_name
+  assert(_version_code != -1)  # Mark as used.
+  assert(_version_name != "")  # Mark as used.
 
   _base_apk_path = _base_path + ".apk_intermediates"
 
   _resource_packaged_apk_path = _base_apk_path + ".ap_"
+  _incremental_resource_packaged_apk_path = _base_apk_path + "_incremental.ap_"
   _packaged_apk_path = _base_apk_path + ".unfinished.apk"
   _incremental_packaged_apk_path =
       _base_apk_path + "_incremental.unfinished.apk"
   _shared_resources =
       defined(invoker.shared_resources) && invoker.shared_resources
+  assert(_shared_resources || true)  # Mark as used.
 
   _keystore_path = invoker.keystore_path
   _keystore_name = invoker.keystore_name
   _keystore_password = invoker.keystore_password
 
   _split_densities = []
   if (defined(invoker.create_density_splits) && invoker.create_density_splits) {
     _split_densities = [
       "hdpi",
       "xhdpi",
       "xxhdpi",
       "xxxhdpi",
       "tvdpi",
     ]
   }
 
   _split_languages = []
   if (defined(invoker.language_splits)) {
     _split_languages = invoker.language_splits
   }
 
+  template("package_resources_helper") {
+    action(target_name) {
+      deps = invoker.deps
+
+      script = "//build/android/gyp/package_resources.py"
+      depfile = "${target_gen_dir}/${target_name}.d"
+      inputs = [
+        invoker.android_manifest,
+      ]
+      if (defined(_resources_zip)) {
+        inputs += [ _resources_zip ]
+      }
+      outputs = [
+        depfile,
+        invoker.resource_packaged_apk_path,
+      ]
+
+      args = [
+        "--depfile",
+        rebase_path(depfile, root_build_dir),
+        "--android-sdk",
+        rebased_android_sdk,
+        "--aapt-path",
+        android_aapt_path,
+        "--configuration-name=$android_configuration_name",
+        "--android-manifest",
+        rebase_path(invoker.android_manifest, root_build_dir),
+        "--version-code",
+        _version_code,
+        "--version-name",
+        _version_name,
+        "--apk-path",
+        rebase_path(invoker.resource_packaged_apk_path, root_build_dir),
+      ]
+
+      if (defined(_asset_location)) {
+        args += [
+          "--asset-dir",
+          rebase_path(_asset_location, root_build_dir),
+        ]
+      }
+      if (defined(_resources_zip)) {
+        args += [
+          "--resource-zips",
+          rebase_path(_resources_zip, root_build_dir),
+        ]
+      }
+      if (_shared_resources) {
+        args += [ "--shared-resources" ]
+      }
+      if (_split_densities != []) {
+        args += [ "--create-density-splits" ]
+        foreach(_density, _split_densities) {
+          outputs += [ "${invoker.resource_packaged_apk_path}_${_density}" ]
+        }
+      }
+      if (_split_languages != []) {
+        args += [ "--language-splits=$_split_languages" ]
+        foreach(_language, _split_languages) {
+          outputs += [ "${invoker.resource_packaged_apk_path}_${_language}" ]
+        }
+      }
+      if (defined(invoker.extensions_to_not_compress)) {
+        args += [
+          "--no-compress",
+          invoker.extensions_to_not_compress,
+        ]
+      }
+    }
+  }
+
   _package_resources_target_name = "${target_name}__package_resources"
-  action(_package_resources_target_name) {
-    deps = _package_deps
+  package_resources_helper(_package_resources_target_name) {
+    forward_variables_from(invoker, [ "extensions_to_not_compress" ])
+    deps = _deps
+    android_manifest = _android_manifest
+    resource_packaged_apk_path = _resource_packaged_apk_path
+  }
 
-    script = "//build/android/gyp/package_resources.py"
+  _generate_incremental_manifest_target_name =
+      "${target_name}_incremental_generate_manifest"
+  _incremental_android_manifest =
+      get_label_info(_generate_incremental_manifest_target_name,
+                     "target_gen_dir") + "/AndroidManifest.xml"
+  action(_generate_incremental_manifest_target_name) {
+    deps = _deps
+    script = "//build/android/incremental_install/generate_android_manifest.py"
     depfile = "${target_gen_dir}/${target_name}.d"
     inputs = [
       _android_manifest,
     ]
-    if (defined(_resources_zip)) {
-      inputs += [ _resources_zip ]
-    }
     outputs = [
       depfile,
-      _resource_packaged_apk_path,
+      _incremental_android_manifest,
     ]
 
+    _rebased_src_manifest = rebase_path(_android_manifest, root_build_dir)
+    _rebased_incremental_manifest =
+        rebase_path(_incremental_android_manifest, root_build_dir)
     args = [
-      "--depfile",
-      rebase_path(depfile, root_build_dir),
-      "--android-sdk",
-      rebased_android_sdk,
-      "--aapt-path",
-      android_aapt_path,
-      "--configuration-name=$android_configuration_name",
-      "--android-manifest",
-      rebase_path(_android_manifest, root_build_dir),
-      "--version-code",
-      _version_code,
-      "--version-name",
-      _version_name,
-      "--apk-path",
-      rebase_path(_resource_packaged_apk_path, root_build_dir),
+      "--src-manifest=$_rebased_src_manifest",
+      "--out-manifest=$_rebased_incremental_manifest",
     ]
+    if (disable_incremental_isolated_processes) {
+      args += [ "--disable-isolated-processes" ]
+    }
+  }
 
-    if (defined(_asset_location)) {
-      args += [
-        "--asset-dir",
-        rebase_path(_asset_location, root_build_dir),
-      ]
-    }
-    if (defined(_resources_zip)) {
-      args += [
-        "--resource-zips",
-        rebase_path(_resources_zip, root_build_dir),
-      ]
-    }
-    if (_shared_resources) {
-      args += [ "--shared-resources" ]
-    }
-    if (_split_densities != []) {
-      args += [ "--create-density-splits" ]
-      foreach(_density, _split_densities) {
-        outputs += [ "${_resource_packaged_apk_path}_${_density}" ]
-      }
-    }
-    if (_split_languages != []) {
-      args += [ "--language-splits=$_split_languages" ]
-      foreach(_language, _split_languages) {
-        outputs += [ "${_resource_packaged_apk_path}_${_language}" ]
-      }
-    }
-    if (defined(invoker.extensions_to_not_compress)) {
-      args += [
-        "--no-compress",
-        invoker.extensions_to_not_compress,
-      ]
-    }
+  _incremental_package_resources_target_name =
+      "${target_name}_incremental__package_resources"
+
+  # TODO(agrieve): See if we can speed up this step by swapping the manifest
+  # from the result of the main package_resources step.
+  package_resources_helper(_incremental_package_resources_target_name) {
+    forward_variables_from(invoker, [ "extensions_to_not_compress" ])
+    deps = _deps + [ ":$_generate_incremental_manifest_target_name" ]
+    android_manifest = _incremental_android_manifest
+    resource_packaged_apk_path = _incremental_resource_packaged_apk_path
   }
 
   package_target = "${target_name}__package"
   package_apk(package_target) {
-    deps = []
-    forward_variables_from(invoker, [ "deps" ])
-    deps += [ ":${_package_resources_target_name}" ]
-
-    data_deps = [ "//tools/android/md5sum" ]  # Used when deploying APKs
+    deps = _deps + [ ":${_package_resources_target_name}" ]
 
     if (defined(_dex_path)) {
       dex_path = _dex_path
     }
     native_libs_dir = _native_libs_dir
     output_apk_path = _packaged_apk_path
     resource_packaged_apk_path = _resource_packaged_apk_path
   }
 
   _incremental_package_target = "${target_name}_incremental__package"
   package_apk(_incremental_package_target) {
-    deps = []
-    forward_variables_from(invoker, [ "deps" ])
-    deps += [ ":${_package_resources_target_name}" ]
+    _dex_target = "//build/android/incremental_install:bootstrap_java__dex"
+    deps = _deps + [
+             ":${_incremental_package_resources_target_name}",
+             _dex_target,
+           ]
 
-    # TODO(agrieve): Multidex
     if (defined(_dex_path)) {
-      dex_path = _dex_path
+      dex_path =
+          get_label_info(_dex_target, "target_gen_dir") + "/bootstrap.dex"
     }
 
     # TODO(agrieve): Add a placeholder .so for http://crbug.com/384638
     native_libs_dir = "//build/android/empty/res"
     output_apk_path = _incremental_packaged_apk_path
-    resource_packaged_apk_path = _resource_packaged_apk_path
+    resource_packaged_apk_path = _incremental_resource_packaged_apk_path
   }
 
   _finalize_apk_rule_name = "${target_name}__finalize"
   finalize_apk(_finalize_apk_rule_name) {
     input_apk_path = _packaged_apk_path
     output_apk_path = _final_apk_path
     keystore_path = _keystore_path
     keystore_name = _keystore_name
     keystore_password = _keystore_password
     rezip_apk = _load_library_from_apk
@@ skipping 807 matching lines @@
     ]
     args = [
       "--depfile",
       rebase_path(depfile, root_build_dir),
       "--script-output-path",
       rebase_path(generated_script, root_build_dir),
     ]
     args += test_runner_args
   }
 }