Build PPAPI NaCl Glibc tests with GN

ppapi/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 copy("copy_test_files") {
   visibility = [ ":*" ]
   sources = [
     # Keep "test_case.html.mock-http-headers" with "test_case.html".
     "tests/ppapi_nacl_tests_newlib.nmf",
     "tests/test_case.html",
@@ skipping 134 matching lines @@
 }
 
 source_set("ppapi_cpp_lib") {
   sources = ppapi_sources.cpp_source_files
   sources += [
     "cpp/module_embedder.h",
     "cpp/ppp_entrypoints.cc",
   ]
 }
 
+shared_library("ppapi_cpp_lib_shared") {
+  configs -= [ "//build/config/gcc:symbol_visibility_hidden" ]

[brettw, 2015/09/09 21:08:45]

This needs to be inside
  if (is_posix) { ... }
to match the case in BUILDCONFIG where it is added.

[Petr Hosek, 2015/09/09 22:14:50]

Done.

+  sources = ppapi_sources.cpp_source_files
+  sources += [
+    "cpp/module_embedder.h",
+    "cpp/ppp_entrypoints.cc",
+  ]
+  cflags = [ "-fPIC" ]

[Dirk Pranke, 2015/09/09 20:00:35]

Presumably this is a linux/unix- specific flag and we'll need something
different on windows?

[Petr Hosek, 2015/09/09 20:55:55]

Actually, this is NaCl specific. After checking the GYP files, it seems it's not
being used in non-NaCl code, so it might be worth moving this into the `is_nacl`
block.

[brettw, 2015/09/09 21:08:45]

This should be set already for Linux so you can just delete it.

[brettw, 2015/09/09 21:19:19]

Actually, this whole target is suspicious. ppapi_sources.cpp_source_files is
already compiled in the ppapi_cpp_lib source set. I think what you're trying to
do here is make a NaCl-specific shared library with those sources.

If that's the case, move the shared library to within the nacl block, then
depend on ":ppapi_cpp_lib".

-fPIC *isn't* automatically set for all compiles on NaCl. Maybe it should be?

[Petr Hosek, 2015/09/09 22:14:49]

Done.

+  deps = [
+    "//build/config/nacl:nacl_base",
+  ]
+}
+
 source_set("ppapi_gles2_lib") {
   include_dirs = [ "lib/gl/include" ]
   sources = [
     "lib/gl/gles2/gl2ext_ppapi.c",
     "lib/gl/gles2/gl2ext_ppapi.h",
     "lib/gl/gles2/gles2.c",
   ]
   deps = [
     "//ppapi/cpp",
   ]
@@ skipping 11 matching lines @@
                 ppapi_sources.test_nacl_source_files
 
       defines = [ "GL_GLEXT_PROTOTYPES" ]
 
       deps = [
         ":ppapi_cpp_lib",
         "//ppapi/native_client:ppapi_lib",
       ]
     }
 
+    executable("ppapi_nacl_tests_glibc") {
+      configs -= [ "//build/config/gcc:symbol_visibility_hidden" ]
+
+      include_dirs = [
+        "lib/gl/include",
+        "..",

[brettw, 2015/09/09 21:08:45]

Remove this, it's automatic in GN. Can you also remove it from the target above
(where I presume you copied it from)?

[Petr Hosek, 2015/09/09 22:14:50]

Done.

+      ]
+
+      sources = ppapi_sources.test_common_source_files +
+                ppapi_sources.test_nacl_source_files
+
+      defines = [ "GL_GLEXT_PROTOTYPES" ]
+
+      ldflags = [ "-pthread" ]

[Dirk Pranke, 2015/09/09 20:00:35]

same comment: presumably this will also need to change on windows?

[Petr Hosek, 2015/09/09 20:55:55]

ditto

+
+      deps = [
+        ":ppapi_cpp_lib_shared",
+        "//ppapi/native_client/src/untrusted/irt_stub:ppapi_stub_lib",
+        "//build/config/nacl:nacl_base",
+      ]
+    }
+
     copy("nacl_tests_copy") {
       sources = [
         "${root_out_dir}/ppapi_nacl_tests_newlib.nexe",
       ]
       outputs = [
         "${root_build_dir}/{{source_name_part}}_${target_cpu}.nexe",
       ]
       deps = [
         ":ppapi_nacl_tests_newlib",
       ]
     }
+
+    copy("nacl_glibc_tests_copy") {
+      sources = [
+        "${root_out_dir}/ppapi_nacl_tests_glibc.nexe",
+      ]
+      outputs = [
+        "${root_build_dir}/{{source_name_part}}_${target_cpu}.nexe",
+      ]
+      deps = [
+        ":ppapi_nacl_tests_glibc",
+      ]
+    }
+
+    # TODO(phosek): We should really use toolchain_package from the toolchain
+    # definition, but there is currently no way to access that variable.
+    import("//build/config/nacl/nacl.gni")
+    glibc_toolchain_dir = "${os_toolchain_dir}/nacl_x86_glibc"
+    create_nmf = rebase_path("//native_client_sdk/src/tools/create_nmf.py")
+    create_nmf_flags = [
+      "--no-default-libpath",
+      "--objdump=${glibc_toolchain_dir}/bin/x86_64-nacl-objdump",
+    ]
+
+    action("generate_glibc_nmf") {
+      glibc_nmf = "${root_build_dir}/ppapi_nacl_tests_glibc.nmf"
+      script = create_nmf

[brettw, 2015/09/09 21:08:45]

Since you only use this var once, inline it here. Also, you don't need the
rebase_path command, this takes a GN path. So delete the declaration above and
do:
  script = "//native_client_sdk/src/tools/create_nmf.py"

[Petr Hosek, 2015/09/09 22:14:49]

I'm going to be using it in the future for PNaCl action which is going to use
the same script and flags but I can move it to a variable later.

+      sources = get_target_outputs(":nacl_glibc_tests_copy")
+      outputs = [
+        glibc_nmf,
+      ]
+      glibc_nmf_flags = [ "--library-path=" + rebase_path(root_out_dir) ]
+      if (current_cpu == "x86") {
+        libdir_glibc32 = "${glibc_toolchain_dir}/x86_64-nacl/lib32"
+        glibc_nmf_flags +=
+            [ "--library-path=" + rebase_path(libdir_glibc32, root_build_dir) ]
+      }
+      if (target_cpu == "x64" || (target_cpu == "x86" && is_win)) {
+        libdir_glibc64 = "${glibc_toolchain_dir}/x86_64-nacl/lib"
+        glibc_nmf_flags +=
+            [ "--library-path=" + rebase_path(libdir_glibc64, root_build_dir) ]
+      }
+      args = [
+               "--output=" + rebase_path(glibc_nmf, root_build_dir),
+               "--stage-dependencies=" + rebase_path(root_build_dir),
+             ] + create_nmf_flags + glibc_nmf_flags +

[brettw, 2015/09/09 21:08:45]

Since this is only used once, can you delete the create_nmf_flags variable and
inline it here?

If we have another create nmf script invocation, we should make a template that
encapsulates this rather than duplicating most of this logic in a similar
variant. So inlining everything for now won't set us back.

[Petr Hosek, 2015/09/09 22:14:49]

There is going to be another invocation in the future, but I can factor this out
into a template then as you suggested.

+             rebase_path(sources, root_build_dir)
+      deps = [
+        ":nacl_glibc_tests_copy",
+      ]
+    }
   }
 
   group("ppapi_nacl_tests") {
     deps = []
     if (target_cpu == "x86" || target_cpu == "x64") {
-      deps += [ ":nacl_tests_copy(//build/toolchain/nacl:clang_newlib_${target_cpu})" ]
+      deps += [
+        ":nacl_tests_copy(//build/toolchain/nacl:clang_newlib_${target_cpu})",
+        ":generate_glibc_nmf(//build/toolchain/nacl:glibc_${target_cpu})",
+      ]
     }
   }
 }