[KeyEvent Mac] Move WebInputEventFactory into chromium.

content/browser/renderer_host/input/web_input_event_builders_mac_unittest.mm

+// Copyright (c) 2015 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import <Cocoa/Cocoa.h>
+#include <gtest/gtest.h>
+
+#include "content/browser/renderer_host/input/web_input_event_builders_mac.h"
+#include "ui/events/keycodes/keyboard_codes.h"
+
+using blink::WebKeyboardEvent;
+using blink::WebInputEvent;
+using content::WebKeyboardEventBuilder;
+
+namespace {
+
+struct KeyMappingEntry {
+  int macKeyCode;
+  unichar character;
+  int windowsKeyCode;
+};
+
+struct ModifierKey {
+  int macKeyCode;
+  int leftOrRightMask;
+  int nonSpecificMask;
+};
+
+// Modifier keys, grouped into left/right pairs.
+ModifierKey modifierKeys[] = {
+    {56, 1 << 1, NSShiftKeyMask},      // Left Shift
+    {60, 1 << 2, NSShiftKeyMask},      // Right Shift
+    {55, 1 << 3, NSCommandKeyMask},    // Left Command
+    {54, 1 << 4, NSCommandKeyMask},    // Right Command
+    {58, 1 << 5, NSAlternateKeyMask},  // Left Alt
+    {61, 1 << 6, NSAlternateKeyMask},  // Right Alt
+    {59, 1 << 0, NSControlKeyMask},    // Left Control
+    {62, 1 << 13, NSControlKeyMask},   // Right Control
+};
+
+NSEvent* BuildFakeKeyEvent(NSUInteger keyCode,
+                           unichar character,
+                           NSUInteger modifierFlags,
+                           NSEventType eventType) {
+  NSString* string = [NSString stringWithCharacters:&character length:1];
+  return [NSEvent keyEventWithType:eventType
+                          location:NSZeroPoint
+                     modifierFlags:modifierFlags
+                         timestamp:0.0
+                      windowNumber:0
+                           context:nil
+                        characters:string
+       charactersIgnoringModifiers:string
+                         isARepeat:NO
+                           keyCode:keyCode];
+}
+
+}  // namespace
+
+// Test that arrow keys don't have numpad modifier set.
+TEST(WebInputEventBuilderMacTest, ArrowKeyNumPad) {
+  // Left
+  NSEvent* macEvent = BuildFakeKeyEvent(0x7B, NSLeftArrowFunctionKey,
+                                        NSNumericPadKeyMask, NSKeyDown);
+  WebKeyboardEvent webEvent = WebKeyboardEventBuilder::Build(macEvent);
+  EXPECT_EQ(0, webEvent.modifiers);
+
+  // Right
+  macEvent = BuildFakeKeyEvent(0x7C, NSRightArrowFunctionKey,
+                               NSNumericPadKeyMask, NSKeyDown);
+  webEvent = WebKeyboardEventBuilder::Build(macEvent);
+  EXPECT_EQ(0, webEvent.modifiers);
+
+  // Down
+  macEvent = BuildFakeKeyEvent(0x7D, NSDownArrowFunctionKey,
+                               NSNumericPadKeyMask, NSKeyDown);
+  webEvent = WebKeyboardEventBuilder::Build(macEvent);
+  EXPECT_EQ(0, webEvent.modifiers);
+
+  // Up
+  macEvent = BuildFakeKeyEvent(0x7E, NSUpArrowFunctionKey, NSNumericPadKeyMask,
+                               NSKeyDown);
+  webEvent = WebKeyboardEventBuilder::Build(macEvent);
+  EXPECT_EQ(0, webEvent.modifiers);
+}
+
+// Test that numpad keys get mapped correctly.
+TEST(WebInputEventBuilderMacTest, NumPadMapping) {
+  KeyMappingEntry table[] = {
+      {65, '.', ui::VKEY_DECIMAL},
+      {67, '*', ui::VKEY_MULTIPLY},
+      {69, '+', ui::VKEY_ADD},
+      {71, NSClearLineFunctionKey, ui::VKEY_CLEAR},
+      {75, '/', ui::VKEY_DIVIDE},
+      {76, 3, ui::VKEY_RETURN},
+      {78, '-', ui::VKEY_SUBTRACT},
+      {81, '=', ui::VKEY_OEM_PLUS},
+      {82, '0', ui::VKEY_0},
+      {83, '1', ui::VKEY_1},
+      {84, '2', ui::VKEY_2},
+      {85, '3', ui::VKEY_3},
+      {86, '4', ui::VKEY_4},
+      {87, '5', ui::VKEY_5},
+      {88, '6', ui::VKEY_6},
+      {89, '7', ui::VKEY_7},
+      {91, '8', ui::VKEY_8},
+      {92, '9', ui::VKEY_9},
+  };
+
+  for (size_t i = 0; i < arraysize(table); ++i) {
+    NSEvent* macEvent = BuildFakeKeyEvent(table[i].macKeyCode,
+                                          table[i].character, 0, NSKeyDown);
+    WebKeyboardEvent webEvent = WebKeyboardEventBuilder::Build(macEvent);
+    EXPECT_EQ(table[i].windowsKeyCode, webEvent.windowsKeyCode);
+  }
+}
+
+// Test that left- and right-hand modifier keys are interpreted correctly when
+// pressed simultaneously.
+TEST(WebInputEventFactoryTestMac, SimultaneousModifierKeys) {
+  for (size_t i = 0; i < arraysize(modifierKeys) / 2; ++i) {
+    const ModifierKey& left = modifierKeys[2 * i];
+    const ModifierKey& right = modifierKeys[2 * i + 1];
+    // Press the left key.
+    NSEvent* macEvent = BuildFakeKeyEvent(
+        left.macKeyCode, 0, left.leftOrRightMask | left.nonSpecificMask,
+        NSFlagsChanged);
+    WebKeyboardEvent webEvent = WebKeyboardEventBuilder::Build(macEvent);
+    EXPECT_EQ(WebInputEvent::RawKeyDown, webEvent.type);
+    // Press the right key
+    macEvent = BuildFakeKeyEvent(
+        right.macKeyCode, 0,
+        left.leftOrRightMask | right.leftOrRightMask | left.nonSpecificMask,
+        NSFlagsChanged);
+    webEvent = WebKeyboardEventBuilder::Build(macEvent);
+    EXPECT_EQ(WebInputEvent::RawKeyDown, webEvent.type);
+    // Release the right key
+    macEvent = BuildFakeKeyEvent(right.macKeyCode, 0,
+                                 left.leftOrRightMask | left.nonSpecificMask,
+                                 NSFlagsChanged);
+    // Release the left key
+    macEvent = BuildFakeKeyEvent(left.macKeyCode, 0, 0, NSFlagsChanged);
+    webEvent = WebKeyboardEventBuilder::Build(macEvent);
+    EXPECT_EQ(WebInputEvent::KeyUp, webEvent.type);
+  }
+}
+
+// Test that individual modifier keys are still reported correctly, even if the
+// undocumented left- or right-hand flags are not set.
+TEST(WebInputEventBuilderMacTest, MissingUndocumentedModifierFlags) {
+  for (size_t i = 0; i < arraysize(modifierKeys); ++i) {
+    const ModifierKey& key = modifierKeys[i];
+    NSEvent* macEvent = BuildFakeKeyEvent(key.macKeyCode, 0,
+                                          key.nonSpecificMask, NSFlagsChanged);
+    WebKeyboardEvent webEvent = WebKeyboardEventBuilder::Build(macEvent);
+    EXPECT_EQ(WebInputEvent::RawKeyDown, webEvent.type);
+    macEvent = BuildFakeKeyEvent(key.macKeyCode, 0, 0, NSFlagsChanged);
+    webEvent = WebKeyboardEventBuilder::Build(macEvent);
+    EXPECT_EQ(WebInputEvent::KeyUp, webEvent.type);
+  }
+}