Move sanitizer and symbol flags out of BUILDCONFIG

build/config/compiler/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/android/config.gni")
 import("//build/config/chrome_build.gni")
+import("//build/config/compiler/compiler.gni")
+import("//build/toolchain/ccache.gni")
+
 if (current_cpu == "arm") {
   import("//build/config/arm.gni")
 }
 if (current_cpu == "mipsel" || current_cpu == "mips64el") {
   import("//build/config/mips.gni")
 }
 if (is_posix) {
   import("//build/config/gcc/gcc_version.gni")
 }
 if (is_win) {
   import("//build/config/win/visual_studio_version.gni")
 }
 
-import("//build/toolchain/ccache.gni")
-import("//build/config/sanitizers/sanitizers.gni")
-
 declare_args() {
   # Normally, Android builds are lightly optimized, even for debug builds, to
   # keep binary size down. Setting this flag to true disables such optimization
   android_full_debug = false
 
   # Whether to use the binary binutils checked into third_party/binutils.
   # These are not multi-arch so cannot be used except on x86 and x86-64 (the
   # only two architectures that are currently checked in). Turn this off when
   # you are using a custom toolchain and need to control -B in cflags.
   linux_use_bundled_binutils = is_linux && current_cpu == "x64"
@@ skipping 44 matching lines @@
 # This is a separate config so that third_party code (which would not use the
 # source root and might have conflicting versions of some headers) can remove
 # this and specify their own include paths.
 config("default_include_dirs") {
   include_dirs = [
     "//",
     root_gen_dir,
   ]
 }
 
-# TODO(GYP) bug 527515: is_ubsan, is_ubsan_vptr
-if (!is_win) {
-  using_sanitizer = is_asan || is_lsan || is_tsan || is_msan
-}
-
 # compiler ---------------------------------------------------------------------
 #
 # Base compiler configuration.
 #
 # See also "runtime_library" below for related stuff and a discussion about
 # where stuff should go. Put warning related stuff in the "warnings" config.
 
 config("compiler") {
   cflags = []
   cflags_c = []
@@ skipping 1048 matching lines @@
     cflags += [ "-Wno-incompatible-pointer-types" ]
   } else if (current_cpu == "mipsel") {
     cflags += [ "-w" ]
   } else if (is_chromeos && current_cpu == "arm") {
     cflags += [ "-w" ]
   }
 }
 
 # Optimization -----------------------------------------------------------------
 #
-# Note that BUILDCONFIG.gn sets up a variable "default_optimization_config"
-# which it will assign to the config it implicitly applies to every target. If
-# you want to override the optimization level for your target, remove this
-# config (which will expand differently for debug or release builds), and then
-# add back the one you want to override it with:
+# The BUILDCONFIG file sets the "default_optimization" config on targets by
+# default. It will be equivalent to either "optimize" (release) or
+# "no_optimize" (debug) optimization configs.
 #
-#   configs -= default_optimization_config
-#   configs += [ "//build/config/compiler/optimize_max" ]
+# You can override the optimization level on a per-target basis by removing the
+# default config and then adding the named one you want:
+#
+#   configs -= [ "//build/config/compiler:default_optimization" ]
+#   configs += [ "//build/config/compiler:optimize_max" ]
 
 # Shared settings for both "optimize" and "optimize_max" configs.
 # IMPORTANT: On Windows "/O1" and "/O2" must go before the common flags.
 if (is_win) {
   common_optimize_on_cflags = [
     "/Ob2",  # Both explicit and auto inlining.
     "/Oy-",  # Disable omitting frame pointers, must be after /O2.
     "/d2Zi+",  # Improve debugging of optimized code.
     "/Zc:inline",  # Remove unreferenced COMDAT (faster links).
   ]
@@ skipping 62 matching lines @@
 
     if (!using_sanitizer) {
       # Functions interposed by the sanitizers can make ld think
       # that some libraries aren't needed when they actually are,
       # http://crbug.com/234010. As workaround, disable --as-needed.
       common_optimize_on_ldflags += [ "-Wl,--as-needed" ]
     }
   }
 }
 
-# Default "optimization on" config. On Windows, this favors size over speed.
+# Default "optimization on" config. Set up variables so the
+# "default_optimization" config can re-use these settings.
+if (is_win) {
+  # Favor size over speed, /O1 must be before the common flags. The GYP
+  # build also specifies /Os and /GF but these are implied by /O1.
+  optimize_cflags = [ "/O1" ] + common_optimize_on_cflags + [ "/Oi" ]
+} else if (is_android || is_ios) {
+  # Favor size over speed.
+  optimize_cflags = [ "-Os" ] + common_optimize_on_cflags
+} else {
+  # Linux & Mac favor speed over size.
+  # TODO(brettw) it's weird that Mac and desktop Linux are different. We should
+  # explore favoring size over speed in this case as well.
+  optimize_cflags = [ "-O2" ] + common_optimize_on_cflags
+}
+optimize_ldflags = common_optimize_on_ldflags
+
 config("optimize") {
-  if (is_win) {
-    # Favor size over speed, /O1 must be before the common flags. The GYP
-    # build also specifies /Os and /GF but these are implied by /O1.
-    cflags = [ "/O1" ] + common_optimize_on_cflags + [ "/Oi" ]
-  } else if (is_android || is_ios) {
-    cflags = [ "-Os" ] + common_optimize_on_cflags  # Favor size over speed.
-  } else {
-    cflags = [ "-O2" ] + common_optimize_on_cflags
-  }
-  ldflags = common_optimize_on_ldflags
+  cflags = optimize_cflags
+  ldflags = optimize_ldflags
 }
 
-# Turn off optimizations.
+# Turn off optimizations. Set up variables so the
+# "default_optimization" config can re-use these settings.
+if (is_win) {
+  no_optimize_cflags = [
+    "/Od",  # Disable optimization.
+    "/Ob0",  # Disable all inlining (on by default).
+    "/RTC1",  # Runtime checks for stack frame and uninitialized variables.
+  ]
+  no_optimize_ldflags = []
+} else if (is_android && !android_full_debug) {
+  # On Android we kind of optimize some things that don't affect debugging
+  # much even when optimization is disabled to get the binary size down.
+  no_optimize_cflags = [
+    "-Os",
+    "-fdata-sections",
+    "-ffunction-sections",
+  ]
+  if (!using_sanitizer) {
+    no_optimize_cflags += [ "-fomit-frame-pointer" ]
+  }
+  no_optimize_ldflags = common_optimize_on_ldflags
+} else {
+  no_optimize_cflags = [ "-O0" ]
+  no_optimize_ldflags = []
+}
+
 config("no_optimize") {
-  if (is_win) {
-    cflags = [
-      "/Od",  # Disable optimization.
-      "/Ob0",  # Disable all inlining (on by default).
-      "/RTC1",  # Runtime checks for stack frame and uninitialized variables.
-    ]
-  } else if (is_android && !android_full_debug) {
-    # On Android we kind of optimize some things that don't affect debugging
-    # much even when optimization is disabled to get the binary size down.
-    cflags = [
-      "-Os",
-      "-fdata-sections",
-      "-ffunction-sections",
-    ]
-    if (!using_sanitizer) {
-      cflags += [ "-fomit-frame-pointer" ]
-    }
-    ldflags = common_optimize_on_ldflags
-  } else {
-    cflags = [ "-O0" ]
-  }
+  cflags = no_optimize_cflags
+  ldflags = no_optimize_ldflags
 }
 
 # Turns up the optimization level. On Windows, this implies whole program
 # optimization and link-time code generation which is very expensive and should
 # be used sparingly.
 config("optimize_max") {
   ldflags = common_optimize_on_ldflags
   if (is_win) {
     # Favor speed over size, /O2 must be before the common flags. The GYP
     # build also specifies /Ot, /Oi, and /GF, but these are implied by /O2.
@@ skipping 10 matching lines @@
         # normal build isn't going to actually be a bug, so the incremental
         # value of C4702 for PGO builds is likely very small.
         "/wd4702",
       ]
     }
   } else {
     cflags = [ "-O2" ] + common_optimize_on_cflags
   }
 }
 
+# The default optimization applied to all targets. This will be equivalent to
+# either "optimize" or "no_optimize", depending on the build flags.
+config("default_optimization") {
+  if (is_debug) {
+    cflags = no_optimize_cflags
+    ldflags = no_optimize_ldflags
+  } else {
+    cflags = optimize_cflags
+    ldflags = optimize_ldflags
+  }
+}
+
 # Symbols ----------------------------------------------------------------------
 
+# The BUILDCONFIG file sets the "default_symbols" config on targets by
+# default. It will be equivalent to one the three specific symbol levels.
+#
+# You can override the symbol level on a per-target basis by removing the
+# default config and then adding the named one you want:
+#
+#   configs -= [ "//build/config/compiler:default_symbols" ]
+#   configs += [ "//build/config/compiler:symbols" ]
+
+# Full symbols.
+if (is_win) {
+  import("//build/toolchain/goma.gni")
+  if (use_goma) {
+    symbols_cflags = [ "/Z7" ]  # No PDB file
+  } else {
+    symbols_cflags = [ "/Zi" ]  # Produce PDB file, no edit and continue.
+  }
+  if (is_win_fastlink) {
+    # Tell VS 2015+ to create a PDB that references debug
+    # information in .obj and .lib files instead of copying
+    # it all. This flag is incompatible with /PROFILE
+    symbols_ldflags = [ "/DEBUG:FASTLINK" ]
+  } else {
+    symbols_ldflags = [ "/DEBUG" ]
+  }
+} else {
+  symbols_cflags = [ "-g2" ]
+  if (use_debug_fission) {
+    symbols_cflags += [ "-gsplit-dwarf" ]
+  }
+  symbols_ldflags = []
+}
+
 config("symbols") {
-  if (is_win) {
-    import("//build/toolchain/goma.gni")
-    if (use_goma) {
-      cflags = [ "/Z7" ]  # No PDB file
-    } else {
-      cflags = [ "/Zi" ]  # Produce PDB file, no edit and continue.
-    }
-    if (is_win_fastlink) {
-      # Tell VS 2015+ to create a PDB that references debug
-      # information in .obj and .lib files instead of copying
-      # it all. This flag is incompatible with /PROFILE
-      ldflags = [ "/DEBUG:FASTLINK" ]
-    } else {
-      ldflags = [ "/DEBUG" ]
-    }
+  cflags = symbols_cflags
+  ldflags = symbols_ldflags
+}
+
+# Minimal symbols.
+if (is_win) {
+  # Linker symbols for backtraces only.
+  minimal_symbols_cflags = []
+  if (is_win_fastlink) {
+    # Tell VS 2015+ to create a PDB that references debug
+    # information in .obj and .lib files instead of copying
+    # it all. This flag is incompatible with /PROFILE
+    minimal_symbols_ldflags = [ "/DEBUG:FASTLINK" ]
   } else {
-    cflags = [ "-g2" ]
-    if (use_debug_fission) {
-      cflags += [ "-gsplit-dwarf" ]
-    }
+    minimal_symbols_ldflags = [ "/DEBUG" ]
   }
+} else {
+  minimal_symbols_cflags = [ "-g1" ]
+  if (use_debug_fission) {
+    minimal_symbols_cflags += [ "-gsplit-dwarf" ]
+  }
+  minimal_symbols_ldflags = []
 }
 
 config("minimal_symbols") {
-  if (is_win) {
-    # Linker symbols for backtraces only.
-    if (is_win_fastlink) {
-      # Tell VS 2015+ to create a PDB that references debug
-      # information in .obj and .lib files instead of copying
-      # it all. This flag is incompatible with /PROFILE
-      ldflags = [ "/DEBUG:FASTLINK" ]
-    } else {
-      ldflags = [ "/DEBUG" ]
-    }
-  } else {
-    cflags = [ "-g1" ]
-    if (use_debug_fission) {
-      cflags += [ "-gsplit-dwarf" ]
-    }
-  }
+  cflags = minimal_symbols_cflags
+  ldflags = minimal_symbols_ldflags
+}
+
+# No symbols.
+if (is_win) {
+  no_symbols_cflags = []
+} else {
+  no_symbols_cflags = [ "-g0" ]
 }
 
 config("no_symbols") {
-  if (!is_win) {
-    cflags = [ "-g0" ]
+  cflags = no_symbols_cflags
+}
+
+# Default symbols.
+config("default_symbols") {
+  if (symbol_level == 0) {
+    cflags = no_symbols_cflags
+  } else if (symbol_level == 1) {
+    cflags = minimal_symbols_cflags
+    ldflags = minimal_symbols_ldflags
+  } else if (symbol_level == 2) {
+    cflags = symbols_cflags
+    ldflags = symbols_ldflags
+  } else {
+    assert(false)
   }
 }