Move sanitizer and symbol flags out of BUILDCONFIG

build/config/BUILDCONFIG.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # =============================================================================
 # PLATFORM SELECTION
 # =============================================================================
 #
 # There are two main things to set: "os" and "cpu". The "toolchain" is the name
 # of the GN thing that encodes combinations of these things.
@@ skipping 93 matching lines @@
 # - Use a name like "use_foo" or "is_foo" (whatever is more appropriate for
 #   your feature) rather than just "foo".
 #
 # - Write good comments directly above the declaration with no blank line.
 #   These comments will appear as documentation in "gn args --list".
 #
 # - Don't call exec_script inside declare_args. This will execute the script
 #   even if the value is overridden, which is wasteful. See first bullet.
 
 declare_args() {
-  # How many symbols to include in the build. This affects the performance of
-  # the build since the symbols are large and dealing with them is slow.
-  #   2 means regular build with symbols.
-  #   1 means minimal symbols, usually enough for backtraces only.
-  #   0 means no symbols.
-  #   -1 means auto-set (off in release, regular in debug).
-  symbol_level = -1
-
   # Component build.
   is_component_build = false
 
   # Debug build.
   is_debug = true
 
   # Whether we're a traditional desktop unix.
   is_desktop_linux = current_os == "linux" && current_os != "chromeos"
 
   # Set to true when compiling with the Clang compiler. Typically this is used
   # to configure warnings.
   is_clang = current_os == "mac" || current_os == "ios" ||
              current_os == "linux" || current_os == "chromeos"
 
-  # Compile for Address Sanitizer to find memory bugs.
-  is_asan = false
-
-  # Compile for Leak Sanitizer to find leaks.
-  is_lsan = false
-
-  # Compile for Memory Sanitizer to find uninitialized reads.
-  is_msan = false
-
-  # Compile for Thread Sanitizer to find threading bugs.
-  is_tsan = false
-
   if (current_os == "chromeos") {
     # Allows the target toolchain to be injected as arguments. This is needed
     # to support the CrOS build system which supports per-build-configuration
     # toolchains.
     cros_use_custom_toolchain = false
   }
 
   # DON'T ADD MORE FLAGS HERE. Read the comment above.
 }
 
@@ skipping 191 matching lines @@
 # across many projects in the tree.
 #
 # Therefore, we only add rules to this list corresponding to platforms on the
 # Chromium waterfall.  This is not for non-officially-supported platforms
 # (FreeBSD, etc.) toolkits, (X11, GTK, etc.), or features. For these cases,
 # write a conditional in the target to remove the file(s) from the list when
 # your platform/toolkit/feature doesn't apply.
 set_sources_assignment_filter(sources_assignment_filter)
 
 # =============================================================================
-# BUILD OPTIONS
-# =============================================================================
-
-# These Sanitizers all imply using the Clang compiler. On Windows they either
-# don't work or work differently.
-if (!is_clang && (is_asan || is_lsan || is_tsan || is_msan)) {
-  is_clang = true
-}
-
-# =============================================================================
 # TARGET DEFAULTS
 # =============================================================================
 #
 # Set up the default configuration for every build target of the given type.
 # The values configured here will be automatically set on the scope of the
 # corresponding target. Target definitions can add or remove to the settings
 # here as needed.
 
 # Holds all configs used for making native executables and libraries, to avoid
 # duplication in each target below.
 _native_compiler_configs = [
   "//build/config:feature_flags",
   "//build/config/compiler:compiler",
   "//build/config/compiler:compiler_arm_fpu",
   "//build/config/compiler:chromium_code",
   "//build/config/compiler:default_include_dirs",
+  "//build/config/compiler:default_optimization",
+  "//build/config/compiler:default_symbols",
   "//build/config/compiler:no_rtti",
   "//build/config/compiler:runtime_library",
 ]
 if (is_win) {
   _native_compiler_configs += [
     "//build/config/win:lean_and_mean",
     "//build/config/win:nominmax",
     "//build/config/win:sdk",
     "//build/config/win:unicode",
     "//build/config/win:winver",
@@ skipping 20 matching lines @@
   _native_compiler_configs += [ "//build/config/android:sdk" ]
 }
 
 if (is_clang && !is_nacl) {
   _native_compiler_configs += [
     "//build/config/clang:find_bad_constructs",
     "//build/config/clang:extra_warnings",
   ]
 }
 
 # Optimizations and debug checking.

[Dirk Pranke, 2015/09/04 22:32:26]

it seems like this comment might be a bit confusing now? It's not immmediately
obvious what the difference is between //build/config:{debug,release} and one of
the //build/config/compiler:* settings.

Presumably the former control #defines and things like that, more than actual
compiler flags?

Perhaps worth adding some more text or rewording things?

[brettw, 2015/09/04 23:36:24]

Done.

 if (is_debug) {
   _native_compiler_configs += [ "//build/config:debug" ]
-  _default_optimization_config = "//build/config/compiler:no_optimize"
 } else {
   _native_compiler_configs += [ "//build/config:release" ]
-  _default_optimization_config = "//build/config/compiler:optimize"
 }
-_native_compiler_configs += [ _default_optimization_config ]
-
-# If it wasn't manually set, set to an appropriate default.
-if (symbol_level == -1) {
-  # Linux is slowed by having symbols as part of the target binary, whereas
-  # Mac and Windows have them separate, so in Release Linux, default them off.
-  if (is_debug || !is_linux) {
-    symbol_level = 2
-  } else if (is_asan || is_lsan || is_tsan || is_msan) {
-    # Sanitizers require symbols for filename suppressions to work.
-    symbol_level = 1
-  } else {
-    symbol_level = 0
-  }
-}
-
-# Symbol setup.
-if (symbol_level == 2) {
-  _default_symbols_config = "//build/config/compiler:symbols"
-} else if (symbol_level == 1) {
-  _default_symbols_config = "//build/config/compiler:minimal_symbols"
-} else if (symbol_level == 0) {
-  _default_symbols_config = "//build/config/compiler:no_symbols"
-} else {
-  assert(false, "Bad value for symbol_level.")
-}
-_native_compiler_configs += [ _default_symbols_config ]
 
 # Windows linker setup for EXEs and DLLs.
 if (is_win) {
   _windows_linker_configs = [
     "//build/config/win:default_incremental_linking",
     "//build/config/win:sdk_link",
     "//build/config/win:common_linker_setup",
 
     # Default to console-mode apps. Most of our targets are tests and such
     # that shouldn't use the windows subsystem.
@@ skipping 148 matching lines @@
     forward_variables_from(invoker, "*")
 
     # All shared libraries must have the sanitizer deps to properly link in
     # asan mode (this target will be empty in other cases).
     if (!defined(deps)) {
       deps = []
     }
     deps += [ "//build/config/sanitizers:deps" ]
   }
 }