Modify the gcc_toolchain definitions in GN for NaCl compatibility

build/toolchain/gcc_toolchain.gni

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/toolchain/toolchain.gni")
 
 # This value will be inherited in the toolchain below.
 concurrent_links = exec_script("get_concurrent_links.py", [], "value")
 
 # This template defines a toolchain for something that works like gcc
@@ skipping 12 matching lines @@
 #
 # Optional parameters:
 #  - libs_section_prefix
 #  - libs_section_postfix
 #      The contents of these strings, if specified, will be placed around
 #      the libs section of the linker line. It allows one to inject libraries
 #      at the beginning and end for all targets in a toolchain.
 #  - solink_libs_section_prefix
 #  - solink_libs_section_postfix
 #      Same as libs_section_{pre,post}fix except used for solink instead of link.
+#  - link_outputs
+#      The content of this array, if specified, will be added to the list of
+#      outputs from the link command. This can be useful in conjunction with
+#      the post_link parameter.
+#  - post_link
+#      The content of this string, if specified, will be appended to the link
+#      command.

[Roland McGrath, 2015/08/28 19:59:37]

This sounds like it's for arguments to be added to the end of the existing link
command.  In fact, it's a second shell command that will be run after the shell
command for linking, with &&.  Make it clear.

[Dirk Pranke, 2015/08/28 20:05:33]

That makes sense. I will fix it.

 #  - post_solink
 #      The content of this string, if specified, will be appended to the solink
 #      command.

[Dirk Pranke, 2015/08/28 20:45:30]

turns out post_solink isn't actually implemented or referenced anywhere, so I
will delete the comment.

 #  - deps
 #      Just forwarded to the toolchain definition.
+#  - executable_extension
+#      If this string is specified it will be used for the file extension
+#      for an executable, rather than using no extension; targets will
+#      still be able to override the extension using the output_extension
+#      variable.
 #  - is_clang
 #      Whether to use clang instead of gcc.
+#  - is_component_build
+#      Whether to forceably enable or disable component builds for this

[Roland McGrath, 2015/08/28 19:59:37]

"forcibly"

[Dirk Pranke, 2015/08/28 20:05:33]

Acknowledged.

+#      toolchain; if not specified, the toolchain will inherit the
+#      default setting.
+#  - rebuild_define
+#      The contents of this string, if specified, will be passed as a #define
+#      to the toolchain. It can be used to force recompiles whenever a
+#      toolchain is updated.
+#  - shlib_extension
+#      If this string is specified it will be used for the file extension
+#      for a shared library, rather than default value specified in
+#      toolchain.gni
 #  - strip
 #      Location of the strip executable. When specified, strip will be run on
 #      all shared libraries and executables as they are built. The pre-stripped
 #      artifacts will be put in lib.stripped/ and exe.stripped/.
 template("gcc_toolchain") {
   toolchain(target_name) {
     assert(defined(invoker.cc), "gcc_toolchain() must specify a \"cc\" value")
     assert(defined(invoker.cxx), "gcc_toolchain() must specify a \"cxx\" value")
     assert(defined(invoker.ar), "gcc_toolchain() must specify a \"ar\" value")
     assert(defined(invoker.ld), "gcc_toolchain() must specify a \"ld\" value")
     assert(defined(invoker.toolchain_cpu),
            "gcc_toolchain() must specify a \"toolchain_cpu\"")
     assert(defined(invoker.toolchain_os),
            "gcc_toolchain() must specify a \"toolchain_os\"")
 
+    # This define changes when the toolchain changes, forcing a rebuild.
+    # Nothing should ever use this define.
+    if (defined(invoker.rebuild_define)) {
+      rebuild_string = "-D" + invoker.rebuild_define + " "
+    } else {
+      rebuild_string = ""
+    }
+
     # We can't do string interpolation ($ in strings) on things with dots in
     # them. To allow us to use $cc below, for example, we create copies of
     # these values in our scope.
     cc = invoker.cc
     cxx = invoker.cxx
     ar = invoker.ar
     ld = invoker.ld
     if (defined(invoker.readelf)) {
       readelf = invoker.readelf
     } else {
       readelf = "readelf"
     }
     if (defined(invoker.nm)) {
       nm = invoker.nm
     } else {
       nm = "nm"
     }
 
+    if (defined(invoker.shlib_extension)) {
+      default_shlib_extension = invoker.shlib_extension
+    } else {
+      default_shlib_extension = shlib_extension
+    }
+
+    if (defined(invoker.executable_extension)) {
+      default_executable_extension = invoker.executable_extension
+    } else {
+      default_executable_extension = ""
+    }
+
     # Bring these into our scope for string interpolation with default values.
     if (defined(invoker.libs_section_prefix)) {
       libs_section_prefix = invoker.libs_section_prefix
     } else {
       libs_section_prefix = ""
     }
 
     if (defined(invoker.libs_section_postfix)) {
       libs_section_postfix = invoker.libs_section_postfix
     } else {
@@ skipping 11 matching lines @@
     } else {
       solink_libs_section_postfix = ""
     }
 
     # These library switches can apply to all tools below.
     lib_switch = "-l"
     lib_dir_switch = "-L"
 
     tool("cc") {
       depfile = "{{output}}.d"
-      command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
+      command = "$cc -MMD -MF $depfile ${rebuild_string}{{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
       depsformat = "gcc"
       description = "CC {{output}}"
       outputs = [
         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
       ]
     }
 
     tool("cxx") {
       depfile = "{{output}}.d"
-      command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}} -c {{source}} -o {{output}}"
+      command = "$cxx -MMD -MF $depfile ${rebuild_string}{{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}} -c {{source}} -o {{output}}"
       depsformat = "gcc"
       description = "CXX {{output}}"
       outputs = [
         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
       ]
     }
 
     tool("asm") {
       # For GCC we can just use the C compiler to compile assembly.
       depfile = "{{output}}.d"
-      command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
+      command = "$cc -MMD -MF $depfile ${rebuild_string}{{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
       depsformat = "gcc"
       description = "ASM {{output}}"
       outputs = [
         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
       ]
     }
 
     tool("alink") {
       rspfile = "{{output}}.rsp"
       command = "rm -f {{output}} && $ar rcs {{output}} @$rspfile"
@@ skipping 38 matching lines @@
             "${invoker.strip} --strip-unneeded -o $sofile $unstripped_sofile"
         command += " && " + strip_command
       }
       rspfile_content = "-Wl,--whole-archive {{inputs}} {{solibs}} -Wl,--no-whole-archive $solink_libs_section_prefix {{libs}} $solink_libs_section_postfix"
 
       description = "SOLINK $sofile"
 
       # Use this for {{output_extension}} expansions unless a target manually
       # overrides it (in which case {{output_extension}} will be what the target
       # specifies).
-      default_output_extension = shlib_extension
-      if (defined(invoker.default_output_extension)) {
-        default_output_extension = invoker.default_output_extension
-      }
+      default_output_extension = default_shlib_extension
 
       output_prefix = "lib"
 
       # Since the above commands only updates the .TOC file when it changes, ask
       # Ninja to check if the timestamp actually changed to know if downstream
       # dependencies should be recompiled.
       restat = true
 
       # Tell GN about the output files. It will link to the sofile but use the
       # tocfile for dependency management.
       outputs = [
         sofile,
         tocfile,
       ]
       if (sofile != unstripped_sofile) {
         outputs += [ unstripped_sofile ]
       }
       link_output = sofile
       depend_output = tocfile
     }
 
     tool("link") {
       exename = "{{target_output_name}}{{output_extension}}"
       outfile = "{{root_out_dir}}/$exename"
       rspfile = "$outfile.rsp"
       unstripped_outfile = outfile
+
+      # Use this for {{output_extension}} expansions unless a target manually
+      # overrides it (in which case {{output_extension}} will be what the target
+      # specifies).
+      default_output_extension = default_executable_extension
+
       if (defined(invoker.strip)) {
         unstripped_outfile = "{{root_out_dir}}/exe.unstripped/$exename"
       }
 
       command = "$ld {{ldflags}} -o $unstripped_outfile -Wl,--start-group @$rspfile {{solibs}} -Wl,--end-group $libs_section_prefix {{libs}} $libs_section_postfix"
       if (defined(invoker.strip)) {
         strip_command =
             "${invoker.strip} --strip-unneeded -o $outfile $unstripped_outfile"
         command += " && " + strip_command
       }
+      if (defined(invoker.postlink)) {
+        command += " && " + invoker.postlink
+      }
       description = "LINK $outfile"
       rspfile_content = "{{inputs}}"
       outputs = [
         outfile,
       ]
       if (outfile != unstripped_outfile) {
         outputs += [ unstripped_outfile ]
       }
+      if (defined(invoker.link_outputs)) {
+        outputs += invoker.link_outputs
+      }
     }
 
     tool("stamp") {
       command = "touch {{output}}"
       description = "STAMP {{output}}"
     }
 
     tool("copy") {
       command = "ln -f {{source}} {{output}} 2>/dev/null || (rm -rf {{output}} && cp -af {{source}} {{output}})"
       description = "COPY {{source}} {{output}}"
     }
 
     # When invoking this toolchain not as the default one, these args will be
     # passed to the build. They are ignored when this is the default toolchain.
     toolchain_args() {
       current_cpu = invoker.toolchain_cpu
       current_os = invoker.toolchain_os
 
       # These values need to be passed through unchanged.
       target_os = target_os
       target_cpu = target_cpu
 
       if (defined(invoker.is_clang)) {
         is_clang = invoker.is_clang
       }
+      if (defined(invoker.is_component_build)) {
+        is_component_build = invoker.is_component_build
+      }
     }
 
     if (defined(invoker.deps)) {
       deps = invoker.deps
     }
   }
 }