[Android] Additional forward_variables_from conversions.

build/config/android/rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//base/android/linker/config.gni")
 import("//build/config/android/config.gni")
 import("//build/config/android/internal_rules.gni")
 import("//build/toolchain/toolchain.gni")
 import("//third_party/android_platform/config.gni")
 import("//tools/grit/grit_rule.gni")
@@ skipping 1249 matching lines @@
   _create_abi_split =
       defined(invoker.create_abi_split) && invoker.create_abi_split
   _create_density_splits =
       defined(invoker.create_density_splits) && invoker.create_density_splits
 
   # Help GN understand that _create_abi_split is not unused (bug in GN).
   assert(_create_abi_split || true)
 
   build_config_target = "${_template_name}__build_config"
   write_build_config(build_config_target) {
+    forward_variables_from(invoker, [ "apk_under_test" ])
     type = "android_apk"
     dex_path = final_dex_path
     resources_zip = resources_zip_path
     build_config = _build_config
     android_manifest = _android_manifest
 
     deps = _chromium_linker_dep + _android_manifest_deps
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
 
-    if (defined(invoker.apk_under_test)) {
-      apk_under_test = invoker.apk_under_test
-    }
-
     native_libs = _native_libs
   }
 
   final_deps = []
 
   process_resources_target = "${_template_name}__process_resources"
   final_deps += [ ":$process_resources_target" ]
   process_resources(process_resources_target) {
+    forward_variables_from(invoker, [ "include_all_resources" ])
     srcjar_path = "${target_gen_dir}/${target_name}.srcjar"
     r_text_path = "${target_gen_dir}/${target_name}_R.txt"
     android_manifest = _android_manifest
     resource_dirs = [ "//build/android/ant/empty/res" ]
     zip_path = resources_zip_path
     all_resources_zip_path = _all_resources_zip_path
     generate_constant_ids = true
 
-    if (defined(invoker.include_all_resources)) {
-      include_all_resources = invoker.include_all_resources
-    }
-
     build_config = _build_config
     deps = _android_manifest_deps + [ ":$build_config_target" ]
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
   }
   _srcjar_deps += [ ":$process_resources_target" ]
 
   if (_native_libs != []) {
     _enable_chromium_linker_tests = false
@@ skipping 30 matching lines @@
       if (_enable_chromium_linker_tests) {
         defines += [ "ENABLE_CHROMIUM_LINKER_TESTS" ]
       }
     }
     _srcjar_deps += [ ":${_template_name}__native_libraries_java" ]
   }
 
   java_target = "${_template_name}__java"
   final_deps += [ ":$java_target" ]
   java_library_impl(java_target) {
+    forward_variables_from(invoker, [ "run_findbugs" ])
     supports_android = true
     requires_android = true
     override_build_config = _build_config
     deps = _android_manifest_deps + [ ":$build_config_target" ]
 
     android_manifest = _android_manifest
     chromium_code = true
     if (defined(invoker.java_files)) {
       java_files = invoker.java_files
     } else if (defined(invoker.DEPRECATED_java_in_dir)) {
       DEPRECATED_java_in_dir = invoker.DEPRECATED_java_in_dir
     } else {
       java_files = []
     }
     srcjar_deps = _srcjar_deps
     dex_path = base_path + ".dex.jar"
 
-    if (defined(invoker.run_findbugs)) {
-      run_findbugs = invoker.run_findbugs
-    }
-
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
   }
 
   if (_dist_jar_path != "") {
     create_dist_target = "${_template_name}__create_dist_jar"
     final_deps += [ ":$create_dist_target" ]
 
     # TODO(cjhopman): This is only ever needed to calculate the list of tests to
@@ skipping 38 matching lines @@
     inputs = [
       _build_config,
     ]
     output = final_dex_path
     dex_arg_key = "${_rebased_build_config}:final_dex:dependency_dex_files"
     args = [ "--inputs=@FileArg($dex_arg_key)" ]
   }
 
   if (_native_libs != []) {
     action("${_template_name}__prepare_native") {
+      forward_variables_from(invoker,
+                             [
+                               "data_deps",
+                               "public_deps",
+                             ])
       script = "//build/android/gyp/pack_relocations.py"
       packed_libraries_dir = "$_native_libs_dir/$android_app_abi"
       depfile = "$target_gen_dir/$target_name.d"
       outputs = [
         depfile,
       ]
 
       inputs = _native_libs
       deps = _chromium_linker_dep
 
@@ skipping 22 matching lines @@
         rebase_path(root_build_dir, root_build_dir),
         "--packed-libraries-dir",
         rebase_path(packed_libraries_dir, root_build_dir),
         "--libraries=@FileArg(${_rebased_build_config}:native:libraries)",
         "--clear-dir",
       ]
 
       if (defined(invoker.deps)) {
         deps += invoker.deps
       }
-      if (defined(invoker.public_deps)) {
-        public_deps = invoker.public_deps
-      }
-      if (defined(invoker.data_deps)) {
-        data_deps = invoker.data_deps
-      }
 
       if (is_debug) {
         rebased_gdbserver = rebase_path([ android_gdbserver ], root_build_dir)
         inputs += [ android_gdbserver ]
         args += [ "--libraries=$rebased_gdbserver" ]
       }
     }
   }
 
   final_deps += [ ":${_template_name}__create" ]
   create_apk("${_template_name}__create") {
+    forward_variables_from(invoker, [ "language_splits" ])
     apk_path = _final_apk_path
     android_manifest = _android_manifest
     resources_zip = _all_resources_zip_path
     dex_path = final_dex_path
     load_library_from_apk = _load_library_from_apk
     create_density_splits = _create_density_splits
-    if (defined(invoker.language_splits)) {
-      language_splits = invoker.language_splits
-    }
     if (defined(invoker.extensions_to_not_compress)) {
       extensions_to_not_compress = invoker.extensions_to_not_compress
     } else {
       # Allow icu data, v8 snapshots, and pak files to be loaded directly from
       # the .apk.
       # Note: These are actually suffix matches, not necessarily extensions.
       extensions_to_not_compress = ".dat,.bin,.pak"
     }
 
     version_code = _version_code
@@ skipping 61 matching lines @@
 
       native_libs_dir = _native_libs_dir
       deps = [
         ":${_template_name}__prepare_native",
         ":${_manifest_rule}",
       ]
     }
   }
 
   group(target_name) {
+    forward_variables_from(invoker, [ "data_deps" ])
     deps = final_deps
-    if (defined(invoker.data_deps)) {
-      data_deps = invoker.data_deps
-    }
   }
 }
 
 # Declare an Android instrumentation test apk
 #
 # This target creates an Android instrumentation test apk.
 #
 # Variables
 #   android_manifest: Path to AndroidManifest.xml.
 #   data_deps: List of dependencies needed at runtime. These will be built but
@@ skipping 34 matching lines @@
 #     ]
 #   }
 template("instrumentation_test_apk") {
   set_sources_assignment_filter([])
   testonly = true
   _template_name = target_name
 
   if (defined(invoker.apk_name)) {
     test_runner_data_dep = [ ":${_template_name}__test_runner_script" ]
     test_runner_script("${_template_name}__test_runner_script") {
+      forward_variables_from(invoker, [ "isolate_file" ])
       test_name = invoker.target_name
       test_type = "instrumentation"
       test_apk = invoker.apk_name
-      if (defined(invoker.isolate_file)) {
-        isolate_file = invoker.isolate_file
-      }
     }
   }
 
   android_apk(target_name) {
     deps = []
     data_deps = []
     forward_variables_from(invoker, "*")
     data_deps += [
       "//testing/android/driver:driver_apk",
       "//tools/android/forwarder2",
@@ skipping 48 matching lines @@
     unittests_binary = "lib${test_suite_name}${shlib_extension}"
   }
 
   if (defined(invoker.apk_name)) {
     apk_name = invoker.apk_name
   } else {
     apk_name = test_suite_name
   }
 
   android_apk(target_name) {
+    forward_variables_from(invoker, [ "asset_location" ])
     final_apk_path = "$root_build_dir/${apk_name}_apk/${apk_name}-debug.apk"
     java_files = [
       "//testing/android/native_test/java/src/org/chromium/native_test/NativeBrowserTestActivity.java",
       "//testing/android/native_test/java/src/org/chromium/native_test/NativeTestActivity.java",
       "//testing/android/native_test/java/src/org/chromium/native_test/NativeUnitTestActivity.java",
       "//testing/android/native_test/java/src/org/chromium/native_test/NativeTestInstrumentationTestRunner.java",
     ]
     android_manifest = "//testing/android/native_test/java/AndroidManifest.xml"
     native_libs = [ unittests_binary ]
-    if (defined(invoker.asset_location)) {
-      asset_location = invoker.asset_location
-    }
     deps = [
       "//base:base_java",
       "//build/android/pylib/remote/device/dummy:remote_device_dummy_apk",
       "//testing/android/appurify_support:appurify_support_java",
       "//testing/android/reporter:reporter_java",
     ]
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
     data_deps = [ "//tools/android/md5sum" ]
@@ skipping 108 matching lines @@
   binary = invoker.binary
   template_name = target_name
 
   libraries_list =
       "${target_gen_dir}/${template_name}_library_dependencies.list"
 
   find_deps_target_name = "${template_name}__find_library_dependencies"
   copy_target_name = "${template_name}__copy_libraries_and_exe"
 
   action(find_deps_target_name) {
+    forward_variables_from(invoker, [ "deps" ])
     visibility = [ ":$copy_target_name" ]
 
     script = "//build/android/gyp/write_ordered_libraries.py"
     depfile = "$target_gen_dir/$target_name.d"
     inputs = [
       binary,
       android_readelf,
     ]
     outputs = [
       depfile,
       libraries_list,
     ]
     rebased_binaries = rebase_path([ binary ], root_build_dir)
     args = [
       "--depfile",
       rebase_path(depfile, root_build_dir),
       "--input-libraries=$rebased_binaries",
       "--libraries-dir",
       rebase_path(root_shlib_dir, root_build_dir),
       "--output",
       rebase_path(libraries_list, root_build_dir),
       "--readelf",
       rebase_path(android_readelf, root_build_dir),
     ]
-    if (defined(invoker.deps)) {
-      deps = invoker.deps
-    }
   }
 
   copy_ex(copy_target_name) {
     visibility = [ ":$template_name" ]
 
     clear_dir = true
     inputs = [
       binary,
       libraries_list,
     ]
     dest = dist_dir
     rebased_binaries_list = rebase_path([ binary ], root_build_dir)
     rebased_libraries_list = rebase_path(libraries_list, root_build_dir)
     args = [
       "--files=$rebased_binaries_list",
       "--files=@FileArg($rebased_libraries_list:lib_paths)",
     ]
 
     deps = [
       ":$find_deps_target_name",
     ]
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
   }
 
   group(template_name) {
-    if (defined(invoker.visibility)) {
-      visibility = invoker.visibility
-    }
+    forward_variables_from(invoker, [ "visibility" ])
     deps = [
       ":$copy_target_name",
     ]
   }
 }
 
 # Compile a protocol buffer to java.
 #
 # This generates java files from protocol buffers and creates an Android library
 # containing the classes.
@@ skipping 52 matching lines @@
 
 # TODO(GYP): implement this.
 template("uiautomator_test") {
   set_sources_assignment_filter([])
   forward_variables_from(invoker, [ "testonly" ])
   assert(target_name != "")
   assert(invoker.deps != [] || true)
   group(target_name) {
   }
 }