GN: Refactor android rules to use forward_variables_from()

build/config/android/rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//base/android/linker/config.gni")
 import("//build/config/android/config.gni")
 import("//build/config/android/internal_rules.gni")
 import("//build/toolchain/toolchain.gni")
 import("//third_party/android_platform/config.gni")
 import("//tools/grit/grit_rule.gni")
@@ skipping 14 matching lines @@
 # Example
 #   generate_jni("foo_jni") {
 #     sources = [
 #       "android/java/src/org/chromium/foo/Foo.java",
 #       "android/java/src/org/chromium/foo/FooUtil.java",
 #     ]
 #     jni_package = "foo"
 #   }
 template("generate_jni") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   assert(defined(invoker.sources))
   assert(defined(invoker.jni_package))
   jni_package = invoker.jni_package
   base_output_dir = "${target_gen_dir}/${target_name}"
   package_output_dir = "${base_output_dir}/${jni_package}"
   jni_output_dir = "${package_output_dir}/jni"
 
   jni_generator_include = "//base/android/jni_generator/jni_generator_helper.h"
 
@@ skipping 31 matching lines @@
     # TODO(cjhopman): #includes should probably all be relative to
     # base_output_dir. Remove that from this config once the includes are
     # updated.
     include_dirs = [
       base_output_dir,
       package_output_dir,
     ]
   }
 
   group(target_name) {
-    deps = [
-      ":$foreach_target_name",
-    ]
+    deps = []
+    forward_variables_from(invoker,
+                           [
+                             "deps",
+                             "public_deps",
+                             "visibility",
+                           ])
+    deps += [ ":$foreach_target_name" ]
     public_configs = [ ":jni_includes_${target_name}" ]
-
-    if (defined(invoker.deps)) {
-      deps += invoker.deps
-    }
-    if (defined(invoker.public_deps)) {
-      public_deps = invoker.public_deps
-    }
-
-    if (defined(invoker.visibility)) {
-      visibility = invoker.visibility
-    }
   }
 }
 
 # Declare a jni target for a prebuilt jar
 #
 # This target generates the native jni bindings for a set of classes in a .jar.
 #
 # See base/android/jni_generator/jni_generator.py for more info about the
 # format of generating JNI bindings.
 #
 # Variables
 #   classes: list of .class files in the jar to generate jni for. These should
 #     include the full path to the .class file.
 #   jni_package: subdirectory path for generated bindings
 #   jar_file: the path to the .jar. If not provided, will default to the sdk's
 #     android.jar
 #
 #   deps, public_deps: As normal
 #
 # Example
 #   generate_jar_jni("foo_jni") {
 #     classes = [
 #       "android/view/Foo.class",
 #     ]
 #     jni_package = "foo"
 #   }
 template("generate_jar_jni") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   assert(defined(invoker.classes))
   assert(defined(invoker.jni_package))
 
   if (defined(invoker.jar_file)) {
     jar_file = invoker.jar_file
   } else {
     jar_file = android_sdk_jar
   }
 
@@ skipping 41 matching lines @@
         "--native_exports_optional",
       ]
     }
   }
 
   config("jni_includes_${target_name}") {
     include_dirs = [ base_output_dir ]
   }
 
   group(target_name) {
-    deps = jni_actions
-    if (defined(invoker.deps)) {
-      deps += invoker.deps
-    }
-    if (defined(invoker.public_deps)) {
-      public_deps = invoker.public_deps
-    }
+    deps = []
+    forward_variables_from(invoker,
+                           [
+                             "deps",
+                             "public_deps",
+                             "visibility",
+                           ])
+    deps += jni_actions
     public_configs = [ ":jni_includes_${target_name}" ]
   }
 }
 
 # Declare a target for c-preprocessor-generated java files
 #
 # NOTE: For generating Java conterparts to enums prefer using the java_cpp_enum
 #       rule instead.
 #
 # This target generates java files using the host C pre-processor. Each file in
@@ skipping 21 matching lines @@
 #     ]
 #     inputs = [
 #       "android/java/templates/native_foo_header.h",
 #     ]
 #
 #     package_name = "org/chromium/base/library_loader"
 #     include_path = "android/java/templates"
 #   }
 template("java_cpp_template") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   assert(defined(invoker.sources))
   package_name = invoker.package_name + ""
 
   if (defined(invoker.include_path)) {
     include_path = invoker.include_path + ""
   } else {
     include_path = "//"
   }
 
   apply_gcc_target_name = "${target_name}__apply_gcc"
   zip_srcjar_target_name = "${target_name}__zip_srcjar"
   final_target_name = target_name
 
   action_foreach(apply_gcc_target_name) {
+    forward_variables_from(invoker,
+                           [
+                             "deps",
+                             "public_deps",
+                             "data_deps",
+                           ])
     visibility = [ ":$zip_srcjar_target_name" ]
     script = "//build/android/gyp/gcc_preprocess.py"
     if (defined(invoker.inputs)) {
       inputs = invoker.inputs + []
     }
     depfile = "${target_gen_dir}/${target_name}_{{source_name_part}}.d"
 
     sources = invoker.sources
 
-    if (defined(invoker.deps)) {
-      deps = invoker.deps
-    }
-    if (defined(invoker.public_deps)) {
-      public_deps = invoker.public_deps
-    }
-    if (defined(invoker.data_deps)) {
-      data_deps = invoker.data_deps
-    }
-
     gen_dir =
         "${target_gen_dir}/${target_name}/java_cpp_template/${package_name}"
     gcc_template_output_pattern = "${gen_dir}/{{source_name_part}}.java"
 
     outputs = [
       depfile,
       gcc_template_output_pattern,
     ]
 
     args = [
@@ skipping 24 matching lines @@
     visibility = [ ":$final_target_name" ]
     inputs = apply_gcc_outputs
     output = srcjar_path
     base_dir = base_gen_dir
     deps = [
       ":$apply_gcc_target_name",
     ]
   }
 
   group(final_target_name) {
-    if (defined(invoker.visibility)) {
-      visibility = invoker.visibility
-    }
+    forward_variables_from(invoker, [ "visibility" ])
     deps = [
       ":$zip_srcjar_target_name",
     ]
   }
 }
 
 # Declare a target for generating Java classes from C++ enums.
 #
 # This target generates Java files from C++ enums using a script.
 #
@@ skipping 15 matching lines @@
 #   java_cpp_enum("foo_generated_enum") {
 #     sources = [
 #       "src/native_foo_header.h",
 #     ]
 #     outputs = [
 #       "org/chromium/FooEnum.java",
 #     ]
 #   }
 template("java_cpp_enum") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   assert(defined(invoker.sources))
   assert(defined(invoker.outputs))
 
   generate_enum_target_name = "${target_name}__generate_enum"
   zip_srcjar_target_name = "${target_name}__zip_srcjar"
   final_target_name = target_name
 
   action(generate_enum_target_name) {
     visibility = [ ":$zip_srcjar_target_name" ]
@@ skipping 26 matching lines @@
     visibility = [ ":$final_target_name" ]
     inputs = generate_enum_outputs
     output = srcjar_path
     base_dir = base_gen_dir
     deps = [
       ":$generate_enum_target_name",
     ]
   }
 
   group(final_target_name) {
-    if (defined(invoker.visibility)) {
-      visibility = invoker.visibility
-    }
+    forward_variables_from(invoker, [ "visibility" ])
     deps = [
       ":$zip_srcjar_target_name",
     ]
   }
 }
 
 # Declare a target for processing a Jinja template.
 #
 # Variables
 #   input: The template file to be processed.
 #   output: Where to save the result.
 #   variables: (Optional) A list of variables to make available to the template
 #     processing environment, e.g. ["name=foo", "color=red"].
 #
 # Example
 #   jinja_template("chrome_shell_manifest") {
 #     input = "shell/java/AndroidManifest.xml"
 #     output = "$target_gen_dir/AndroidManifest.xml"
 #   }
 template("jinja_template") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   assert(defined(invoker.input))
   assert(defined(invoker.output))
 
   action(target_name) {
-    if (defined(invoker.visibility)) {
-      visibility = invoker.visibility
-    }
+    forward_variables_from(invoker, [ "visibility" ])
 
     sources = [
       invoker.input,
     ]
     script = "//build/android/gyp/jinja_template.py"
     depfile = "$target_gen_dir/$target_name.d"
 
     outputs = [
       depfile,
       invoker.output,
@@ skipping 30 matching lines @@
 #     processing environment, e.g. ["name=foo", "color=red"].
 #
 # Example
 #   jinja_template_resources("chrome_shell_template_resources") {
 #     res_dir = "shell/res_template"
 #     resources = ["shell/res_template/xml/syncable.xml"]
 #     variables = ["color=red"]
 #   }
 template("jinja_template_resources") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   assert(defined(invoker.resources))
   assert(defined(invoker.res_dir))
 
   _base_path = "$target_gen_dir/$target_name"
   _resources_zip = _base_path + ".resources.zip"
   _build_config = _base_path + ".build_config"
 
   write_build_config("${target_name}__build_config") {
     build_config = _build_config
@@ skipping 60 matching lines @@
   _resources_zip = _base_path + ".resources.zip"
   _build_config = _base_path + ".build_config"
 
   write_build_config("${target_name}__build_config") {
     build_config = _build_config
     resources_zip = _resources_zip
     type = "android_resources"
   }
 
   action("${target_name}__create_resources_zip") {
-    sources = invoker.sources
+    forward_variables_from(invoker,
+                           [
+                             "deps",
+                             "sources",
+                           ])
     script = "//build/android/gyp/locale_pak_resources.py"
     depfile = "$target_gen_dir/$target_name.d"
 
     outputs = [
       depfile,
       _resources_zip,
     ]
 
-    _rebased_sources = rebase_path(invoker.sources, root_build_dir)
+    _rebased_sources = rebase_path(sources, root_build_dir)
     args = [
       "--locale-paks=${_rebased_sources}",
       "--resources-zip",
       rebase_path(_resources_zip, root_build_dir),
       "--depfile",
       rebase_path(depfile, root_build_dir),
     ]
-
-    if (defined(invoker.deps)) {
-      deps = invoker.deps
-    }
   }
 
   group(target_name) {
     deps = [
       ":${target_name}__build_config",
       ":${target_name}__create_resources_zip",
     ]
   }
 }
 
@@ skipping 22 matching lines @@
 #
 
 # Example
 #   android_resources("foo_resources") {
 #     deps = [":foo_strings_grd"]
 #     resource_dirs = ["res"]
 #     custom_package = "org.chromium.foo"
 #   }
 template("android_resources") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   assert(defined(invoker.resource_dirs))
   assert(defined(invoker.android_manifest) || defined(invoker.custom_package))
 
   base_path = "$target_gen_dir/$target_name"
   zip_path = base_path + ".resources.zip"
   srcjar_path = base_path + ".srcjar"
   r_text_path = base_path + "_R.txt"
   build_config = base_path + ".build_config"
 
   build_config_target_name = "${target_name}__build_config"
   process_resources_target_name = "${target_name}__process_resources"
   final_target_name = target_name
 
   write_build_config(build_config_target_name) {
+    forward_variables_from(invoker,
+                           [
+                             "android_manifest",
+                             "custom_package",
+                             "deps",
+                           ])
     visibility = [ ":$process_resources_target_name" ]
 
     type = "android_resources"
     resources_zip = zip_path
     srcjar = srcjar_path
     r_text = r_text_path
-    if (defined(invoker.deps)) {
-      deps = invoker.deps
-    }
-    if (defined(invoker.android_manifest)) {
-      android_manifest = invoker.android_manifest
-    }
-    if (defined(invoker.custom_package)) {
-      custom_package = invoker.custom_package
-    }
-  }
-
-  android_manifest = "//build/android/AndroidManifest.xml"
-  if (defined(invoker.android_manifest)) {
-    android_manifest = invoker.android_manifest
   }
 
   process_resources(process_resources_target_name) {
     visibility = [ ":$final_target_name" ]
-
-    resource_dirs = invoker.resource_dirs
-    if (defined(invoker.custom_package)) {
-      custom_package = invoker.custom_package
-    }
-
-    if (defined(invoker.v14_skip)) {
-      v14_skip = invoker.v14_skip
-    }
-
-    if (defined(invoker.shared_resources)) {
-      shared_resources = invoker.shared_resources
-    }
-
-    deps = [
-      ":$build_config_target_name",
-    ]
-    if (defined(invoker.deps)) {
-      # Invoker may have added deps that generate the input resources.
-      deps += invoker.deps
+    deps = []
+    forward_variables_from(invoker,
+                           [
+                             "android_manifest",
+                             "custom_package",
+                             "deps",
+                             "resource_dirs",
+                             "shared_resources",
+                             "v14_skip",
+                           ])
+    deps += [ ":$build_config_target_name" ]
+    if (!defined(android_manifest)) {
+      android_manifest = "//build/android/AndroidManifest.xml"
     }
   }
 
   group(final_target_name) {
-    if (defined(invoker.visibility)) {
-      visibility = invoker.visibility
-    }
+    forward_variables_from(invoker, [ "visibility" ])
     deps = [
       ":${target_name}__process_resources",
     ]
   }
 }
 
 # Declare a target that generates localized strings.xml from a .grd file.
 #
 # If this target is included in the deps of an android resources/library/apk,
 # the strings.xml will be included with that target.
 #
 # Variables
 #   deps: Specifies the dependencies of this target.
 #   grd_file: Path to the .grd file to generate strings.xml from.
 #   outputs: Expected grit outputs (see grit rule).
 #
 # Example
 #  java_strings_grd("foo_strings_grd") {
 #    grd_file = "foo_strings.grd"
 #  }
 template("java_strings_grd") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   base_path = "$target_gen_dir/$target_name"
   resources_zip = base_path + ".resources.zip"
   build_config = base_path + ".build_config"
 
   write_build_config("${target_name}__build_config") {
+    forward_variables_from(invoker, [ "deps" ])
     type = "android_resources"
-    if (defined(invoker.deps)) {
-      deps = invoker.deps
-    }
   }
 
   # Put grit files into this subdirectory of target_gen_dir.
   extra_output_path = target_name + "_grit_output"
 
   grit_target_name = "${target_name}__grit"
   grit_output_dir = "$target_gen_dir/$extra_output_path"
   grit(grit_target_name) {
     grit_flags = [
       "-E",
@@ skipping 37 matching lines @@
 #
 # Example
 #  java_strings_grd_prebuilt("foo_strings_grd") {
 #    grit_output_dir = "$root_gen_dir/foo/grit"
 #    generated_files = [
 #      "values/strings.xml"
 #    ]
 #  }
 template("java_strings_grd_prebuilt") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   base_path = "$target_gen_dir/$target_name"
   resources_zip = base_path + ".resources.zip"
   build_config = base_path + ".build_config"
 
   build_config_target_name = "${target_name}__build_config"
   zip_target_name = "${target_name}__zip"
   final_target_name = target_name
 
   write_build_config(build_config_target_name) {
     visibility = [ ":$zip_target_name" ]
     type = "android_resources"
   }
 
   zip(zip_target_name) {
     visibility = [ ":$final_target_name" ]
 
     base_dir = invoker.grit_output_dir
     inputs = rebase_path(invoker.generated_files, ".", base_dir)
     output = resources_zip
     deps = [
       ":$build_config_target_name",
     ]
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
   }
 
   group(final_target_name) {
-    if (defined(invoker.visibility)) {
-      visibility = invoker.visibility
-    }
+    forward_variables_from(invoker, [ "visibility" ])
     deps = [
       ":$zip_target_name",
     ]
   }
 }
 
 # Declare a Java executable target
 #
 # This target creates an executable from java code and libraries. The executable
 # will be in the output folder's /bin/ directory.
@@ skipping 22 matching lines @@
 #     java_files = [ "org/chromium/foo/FooMain.java" ]
 #     deps = [ ":bar_java" ]
 #     main_class = "org.chromium.foo.FooMain"
 #   }
 template("java_binary") {
   set_sources_assignment_filter([])
 
   # TODO(cjhopman): This should not act like a java_library for dependents (i.e.
   # dependents shouldn't get the jar in their classpath, etc.).
   java_library_impl(target_name) {
-    if (defined(invoker.DEPRECATED_java_in_dir)) {
-      DEPRECATED_java_in_dir = invoker.DEPRECATED_java_in_dir
-    }
-    if (defined(invoker.chromium_code)) {
-      chromium_code = invoker.chromium_code
-    }
-    if (defined(invoker.data_deps)) {
-      deps = invoker.data_deps
-    }
-    if (defined(invoker.deps)) {
-      deps = invoker.deps
-    }
-    if (defined(invoker.enable_errorprone)) {
-      enable_errorprone = invoker.enable_errorprone
-    }
-    if (defined(invoker.java_files)) {
-      java_files = invoker.java_files
-    }
-    if (defined(invoker.srcjar_deps)) {
-      srcjar_deps = invoker.srcjar_deps
-    }
-    if (defined(invoker.srcjars)) {
-      srcjars = invoker.srcjars
-    }
-    if (defined(invoker.bypass_platform_checks)) {
-      bypass_platform_checks = invoker.bypass_platform_checks
-    }
-    if (defined(invoker.testonly)) {
-      testonly = invoker.testonly
-    }
-
+    forward_variables_from(invoker, "*")
     supports_android = false
     main_class = invoker.main_class
   }
 }
 
 # Declare a Junit executable target
 #
 # This target creates an executable from java code for running as a junit test
 # suite. The executable will be in the output folder's /bin/ directory.
 #
@@ skipping 11 matching lines @@
 #
 # Example
 #   junit_binary("foo") {
 #     java_files = [ "org/chromium/foo/FooTest.java" ]
 #     deps = [ ":bar_java" ]
 #   }
 template("junit_binary") {
   set_sources_assignment_filter([])
 
   java_binary(target_name) {
+    deps = []
+    forward_variables_from(invoker, "*")
     bypass_platform_checks = true
     main_class = "org.chromium.testing.local.JunitTestMain"
     testonly = true
 
-    if (defined(invoker.DEPRECATED_java_in_dir)) {
-      DEPRECATED_java_in_dir = invoker.DEPRECATED_java_in_dir
-    }
-    if (defined(invoker.chromium_code)) {
-      chromium_code = invoker.chromium_code
-    }
-    deps = [
+    deps += [
       "//testing/android/junit:junit_test_support",
       "//third_party/junit",
       "//third_party/mockito:mockito_java",
       "//third_party/robolectric:robolectric_java",
       "//third_party/robolectric:android-all-4.3_r2-robolectric-0",
     ]
-    if (defined(invoker.deps)) {
-      deps += invoker.deps
-    }
-    if (defined(invoker.java_files)) {
-      java_files = invoker.java_files
-    }
-    if (defined(invoker.srcjar_deps)) {
-      srcjar_deps = invoker.srcjar_deps
-    }
-    if (defined(invoker.srcjars)) {
-      srcjars = invoker.srcjars
-    }
   }
 }
 
 # Declare a java library target
 #
 # Variables
 #   deps: Specifies the dependencies of this target. Java targets in this list
 #     will be added to the javac classpath.
 #
 #   java_files: List of .java files included in this library.
@@ skipping 37 matching lines @@
 #     srcjar_deps = [
 #       ":foo_generated_enum"
 #     ]
 #     jar_excluded_patterns = [
 #       "*/FooService.class", "*/FooService##*.class"
 #     ]
 #   }
 template("java_library") {
   set_sources_assignment_filter([])
   java_library_impl(target_name) {
-    if (defined(invoker.DEPRECATED_java_in_dir)) {
-      DEPRECATED_java_in_dir = invoker.DEPRECATED_java_in_dir
-    }
-    if (defined(invoker.chromium_code)) {
-      chromium_code = invoker.chromium_code
-    }
-    if (defined(invoker.data_deps)) {
-      deps = invoker.data_deps
-    }
-    if (defined(invoker.deps)) {
-      deps = invoker.deps
-    }
-    if (defined(invoker.enable_errorprone)) {
-      enable_errorprone = invoker.enable_errorprone
-    }
-    if (defined(invoker.jar_excluded_patterns)) {
-      jar_excluded_patterns = invoker.jar_excluded_patterns
-    }
-    if (defined(invoker.java_files)) {
-      java_files = invoker.java_files
-    }
-    if (defined(invoker.proguard_config)) {
-      proguard_config = invoker.proguard_config
-    }
-    if (defined(invoker.proguard_preprocess)) {
-      proguard_preprocess = invoker.proguard_preprocess
-    }
-    if (defined(invoker.srcjar_deps)) {
-      srcjar_deps = invoker.srcjar_deps
-    }
-    if (defined(invoker.srcjars)) {
-      srcjars = invoker.srcjars
-    }
-    if (defined(invoker.bypass_platform_checks)) {
-      bypass_platform_checks = invoker.bypass_platform_checks
-    }
-    if (defined(invoker.testonly)) {
-      testonly = invoker.testonly
-    }
-    if (defined(invoker.jar_path)) {
-      jar_path = invoker.jar_path
-    }
-
-    if (defined(invoker.supports_android) && invoker.supports_android) {
-      supports_android = true
-    }
+    forward_variables_from(invoker, "*")
   }
 }
 
 # Declare a java library target for a prebuilt jar
 #
 # Variables
 #   deps: Specifies the dependencies of this target. Java targets in this list
 #     will be added to the javac classpath.
 #   jar_path: Path to the prebuilt jar.
 #   jar_dep: Target that builds jar_path (optional).
 #   proguard_preprocess: If true, proguard preprocessing will be run. This can
 #     be used to remove unwanted parts of the library.
 #   proguard_config: Path to the proguard config for preprocessing.
 #
 # Example
 #   java_prebuilt("foo_java") {
 #     jar_path = "foo.jar"
 #     deps = [
 #       ":foo_resources",
 #       ":bar_java"
 #     ]
 #   }
 template("java_prebuilt") {
   set_sources_assignment_filter([])
   java_prebuilt_impl(target_name) {
-    jar_path = invoker.jar_path
-    if (defined(invoker.jar_dep)) {
-      jar_dep = invoker.jar_dep
-    }
-    if (defined(invoker.testonly)) {
-      testonly = invoker.testonly
-    }
-    if (defined(invoker.deps)) {
-      deps = invoker.deps
-    }
-    if (defined(invoker.data_deps)) {
-      data_deps = invoker.data_deps
-    }
-    if (defined(invoker.proguard_config)) {
-      proguard_config = invoker.proguard_config
-    }
-    if (defined(invoker.proguard_preprocess)) {
-      proguard_preprocess = invoker.proguard_preprocess
-    }
+    forward_variables_from(invoker, "*")
   }
 }
 
 # Declare an Android library target
 #
 # This target creates an Android library containing java code and Android
 # resources.
 #
 # Variables
 #   deps: Specifies the dependencies of this target. Java targets in this list
@@ skipping 38 matching lines @@
 #     ]
 #     jar_excluded_patterns = [
 #       "*/FooService.class", "*/FooService##*.class"
 #     ]
 #   }
 template("android_library") {
   set_sources_assignment_filter([])
   assert(!defined(invoker.jar_path),
          "android_library does not support a custom jar path")
   java_library_impl(target_name) {
-    if (defined(invoker.DEPRECATED_java_in_dir)) {
-      DEPRECATED_java_in_dir = invoker.DEPRECATED_java_in_dir
-    }
-    if (defined(invoker.chromium_code)) {
-      chromium_code = invoker.chromium_code
-    }
-    if (defined(invoker.data_deps)) {
-      deps = invoker.data_deps
-    }
-    if (defined(invoker.deps)) {
-      deps = invoker.deps
-    }
-    if (defined(invoker.enable_errorprone)) {
-      enable_errorprone = invoker.enable_errorprone
-    }
-    if (defined(invoker.jar_excluded_patterns)) {
-      jar_excluded_patterns = invoker.jar_excluded_patterns
-    }
-    if (defined(invoker.java_files)) {
-      java_files = invoker.java_files
-    }
-    if (defined(invoker.proguard_config)) {
-      proguard_config = invoker.proguard_config
-    }
-    if (defined(invoker.proguard_preprocess)) {
-      proguard_preprocess = invoker.proguard_preprocess
-    }
-    if (defined(invoker.srcjar_deps)) {
-      srcjar_deps = invoker.srcjar_deps
-    }
-    if (defined(invoker.srcjars)) {
-      srcjars = invoker.srcjars
-    }
-    if (defined(invoker.testonly)) {
-      testonly = invoker.testonly
-    }
-    if (defined(invoker.visibility)) {
-      visibility = invoker.visibility
-    }
-    if (defined(invoker.dex_path)) {
-      dex_path = invoker.dex_path
-    }
-    if (defined(invoker.manifest_entries)) {
-      manifest_entries = invoker.manifest_entries
-    }
+    forward_variables_from(invoker, "*")
 
     supports_android = true
     requires_android = true
 
     if (!defined(jar_excluded_patterns)) {
       jar_excluded_patterns = []
     }
     jar_excluded_patterns += [
       "*/R.class",
       "*/R##*.class",
       "*/Manifest.class",
       "*/Manifest##*.class",
     ]
   }
 }
 
 # Declare a target that packages a set of Java dependencies into a standalone
 # .dex.jar.
 #
 # Variables
 #   deps: specifies the dependencies of this target. Android libraries in deps
 #     will be packaged into the resulting .dex.jar file.
 #   dex_path: location at which the output file will be put
 template("android_standalone_library") {
   set_sources_assignment_filter([])
   deps_dex(target_name) {
-    deps = invoker.deps
-    dex_path = invoker.dex_path
-    if (defined(invoker.excluded_jars)) {
-      excluded_jars = invoker.excluded_jars
-    }
+    forward_variables_from(invoker,
+                           [
+                             "deps",
+                             "dex_path",
+                             "excluded_jars",
+                           ])
   }
 }
 
 # Declare an Android library target for a prebuilt jar
 #
 # This target creates an Android library containing java code and Android
 # resources.
 #
 # Variables
 #   deps: Specifies the dependencies of this target. Java targets in this list
 #     will be added to the javac classpath. Android resources in dependencies
 #     will be used when building this library.
 #   jar_path: Path to the prebuilt jar.
 #   proguard_preprocess: If true, proguard preprocessing will be run. This can
 #     be used to remove unwanted parts of the library.
 #   proguard_config: Path to the proguard config for preprocessing.
 #
 # Example
 #   android_java_prebuilt("foo_java") {
 #     jar_path = "foo.jar"
 #     deps = [
 #       ":foo_resources",
 #       ":bar_java"
 #     ]
 #   }
 template("android_java_prebuilt") {
   set_sources_assignment_filter([])
   java_prebuilt_impl(target_name) {
-    jar_path = invoker.jar_path
+    forward_variables_from(invoker, "*")
     supports_android = true
     requires_android = true
-    if (defined(invoker.testonly)) {
-      testonly = invoker.testonly
-    }
-    if (defined(invoker.deps)) {
-      deps = invoker.deps
-    }
-    if (defined(invoker.data_deps)) {
-      data_deps = invoker.data_deps
-    }
-    if (defined(invoker.proguard_config)) {
-      proguard_config = invoker.proguard_config
-    }
-    if (defined(invoker.proguard_preprocess)) {
-      proguard_preprocess = invoker.proguard_preprocess
-    }
   }
 }
 
 # Declare an Android apk target
 #
 # This target creates an Android APK containing java code, resources, assets,
 # and (possibly) native libraries.
 #
 # Variables
 #   android_manifest: Path to AndroidManifest.xml.
@@ skipping 38 matching lines @@
 #     ]
 #     srcjar_deps = [
 #       ":foo_generated_enum"
 #     ]
 #     native_libs = [
 #       native_lib_path
 #     ]
 #   }
 template("android_apk") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   assert(defined(invoker.final_apk_path) || defined(invoker.apk_name))
   assert(defined(invoker.android_manifest))
   gen_dir = "$target_gen_dir/$target_name"
   base_path = "$gen_dir/$target_name"
   _build_config = "$target_gen_dir/$target_name.build_config"
   resources_zip_path = "$base_path.resources.zip"
   _all_resources_zip_path = "$base_path.resources.all.zip"
   jar_path = "$base_path.jar"
   _template_name = target_name
@@ skipping 490 matching lines @@
       test_name = invoker.target_name
       test_type = "instrumentation"
       test_apk = invoker.apk_name
       if (defined(invoker.isolate_file)) {
         isolate_file = invoker.isolate_file
       }
     }
   }
 
   android_apk(target_name) {
-    if (defined(invoker.android_manifest)) {
-      android_manifest = invoker.android_manifest
-    }
-    data_deps = [
+    deps = []
+    data_deps = []
+    forward_variables_from(invoker, "*")
+    data_deps += [
       "//testing/android/driver:driver_apk",
       "//tools/android/forwarder2",
       "//tools/android/md5sum",
     ]
     if (defined(test_runner_data_dep)) {
       data_deps += test_runner_data_dep
     }
-    if (defined(invoker.data_deps)) {
-      data_deps += invoker.data_deps
-    }
-    deps = [
-      "//testing/android/broker:broker_java",
-    ]
-    if (defined(invoker.deps)) {
-      deps += invoker.deps
-    }
-    if (defined(invoker.java_files)) {
-      java_files = invoker.java_files
-    }
-    if (defined(invoker.srcjar_deps)) {
-      srcjar_deps = invoker.srcjar_deps
-    }
-    if (defined(invoker.apk_name)) {
-      apk_name = invoker.apk_name
-    }
-    if (defined(invoker.final_apk_path)) {
-      final_apk_path = invoker.final_apk_path
-    }
-    if (defined(invoker.native_libs)) {
-      native_libs = invoker.native_libs
-    }
-    if (defined(invoker.apk_under_test)) {
-      apk_under_test = invoker.apk_under_test
-    }
-    if (defined(invoker.DEPRECATED_java_in_dir)) {
-      DEPRECATED_java_in_dir = invoker.DEPRECATED_java_in_dir
-    }
+    deps += [ "//testing/android/broker:broker_java" ]
   }
 }
 
 # Declare an Android gtest apk
 #
 # This target creates an Android apk for running gtest-based unittests.
 #
 # Variables
 #   deps: Specifies the dependencies of this target. These will be passed to
 #     the underlying android_apk invocation and should include the java and
@@ skipping 83 matching lines @@
 # Example
 #   android_aidl("foo_aidl") {
 #     import_include = "java/src"
 #     sources = [
 #       "java/src/com/foo/bar/FooBarService.aidl",
 #       "java/src/com/foo/bar/FooBarServiceCallback.aidl",
 #     ]
 #   }
 template("android_aidl") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   srcjar_path = "${target_gen_dir}/${target_name}.srcjar"
   aidl_path = "${android_sdk_build_tools}/aidl"
   framework_aidl = "$android_sdk/framework.aidl"
 
   action(target_name) {
     script = "//build/android/gyp/aidl.py"
     sources = invoker.sources
 
     imports = [ framework_aidl ]
@@ skipping 54 matching lines @@
 #   binary: Path to (stripped) executable.
 #
 # Example
 #   create_native_executable_dist("foo_dist") {
 #     dist_dir = "$root_build_dir/foo_dist"
 #     binary = "$root_build_dir/foo"
 #     deps = [ ":the_thing_that_makes_foo" ]
 #   }
 template("create_native_executable_dist") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
 
   dist_dir = invoker.dist_dir
   binary = invoker.binary
   template_name = target_name
 
   libraries_list =
       "${target_gen_dir}/${template_name}_library_dependencies.list"
 
   find_deps_target_name = "${template_name}__find_library_dependencies"
   copy_target_name = "${template_name}__copy_libraries_and_exe"
@@ skipping 71 matching lines @@
 #   sources: Paths to .proto files to compile.
 #   proto_path: Root directory of .proto files.
 #
 # Example:
 #  proto_java_library("foo_proto_java") {
 #    proto_path = [ "src/foo" ]
 #    sources = [ "$proto_path/foo.proto" ]
 #  }
 template("proto_java_library") {
   set_sources_assignment_filter([])
+  forward_variables_from(invoker, [ "testonly" ])
   _protoc_dep = "//third_party/android_protobuf:android_protoc($host_toolchain)"
   _protoc_out_dir = get_label_info(_protoc_dep, "root_out_dir")
   _protoc_bin = "$_protoc_out_dir/android_protoc"
   _proto_path = invoker.proto_path
 
   _template_name = target_name
 
   action("${_template_name}__protoc_java") {
     srcjar_path = "$target_gen_dir/$target_name.srcjar"
     script = "//build/protoc_java.py"
@@ skipping 23 matching lines @@
     srcjar_deps = [ ":${_template_name}__protoc_java" ]
     deps = [
       "//third_party/android_protobuf:protobuf_nano_javalib",
     ]
   }
 }
 
 # TODO(GYP): implement this.
 template("uiautomator_test") {
   set_sources_assignment_filter([])
-  if (defined(invoker.testonly)) {
-    testonly = invoker.testonly
-  }
+  forward_variables_from(invoker, [ "testonly" ])
   assert(target_name != "")
   assert(invoker.deps != [] || true)
   group(target_name) {
   }
 }