Un-nest configs in GN files.

third_party/zlib/BUILD.gn

 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 config("zlib_config") {
   include_dirs = [ "." ]
 }
 
 static_library("zlib_x86_simd") {
   if (!is_ios && (current_cpu == "x86" || current_cpu == "x64")) {
@@ skipping 10 matching lines @@
   } else {
     sources = [
       "simd_stub.c",
     ]
   }
 
   configs -= [ "//build/config/compiler:chromium_code" ]
   configs += [ "//build/config/compiler:no_chromium_code" ]
 }
 
+config("zlib_warnings") {
+  if (is_clang && !is_ios &&
+      (current_cpu == "x86" || current_cpu == "x64")) {
+    cflags = [ "-Wno-incompatible-pointer-types" ]
+  }
+}
+
 static_library("zlib") {
   if (!is_win) {
     # Don't stomp on "libzlib" on other platforms.
     output_name = "chrome_zlib"
   }
 
   sources = [
     "adler32.c",
     "compress.c",
     "crc32.c",
@@ skipping 19 matching lines @@
     "uncompr.c",
     "x86.h",
     "zconf.h",
     "zlib.h",
     "zutil.c",
     "zutil.h",
   ]
 
   if (!is_ios && (current_cpu == "x86" || current_cpu == "x64")) {
     sources += [ "x86.c" ]
-
-    config("zlib_warnings") {
-      if (is_clang) {
-        cflags = [ "-Wno-incompatible-pointer-types" ]
-      }
-    }
-    configs += [ ":zlib_warnings" ]
   }
 
   configs -= [ "//build/config/compiler:chromium_code" ]
-  configs += [ "//build/config/compiler:no_chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+
+    # Must be after no_chromium_code for warning flags to be ordered correctly.
+    ":zlib_warnings",
+  ]
 
   public_configs = [ ":zlib_config" ]
   deps = [
     ":zlib_x86_simd",
   ]
 }
 
+config("minizip_warnings") {
+  visibility = [ ":*" ]
+  if (is_clang) {
+    # zlib uses `if ((a == b))` for some reason.
+    cflags = [ "-Wno-parentheses-equality" ]
+  }
+}
+
 static_library("minizip") {
   sources = [
     "contrib/minizip/ioapi.c",
     "contrib/minizip/ioapi.h",
     "contrib/minizip/iowin32.c",
     "contrib/minizip/iowin32.h",
     "contrib/minizip/unzip.c",
     "contrib/minizip/unzip.h",
     "contrib/minizip/zip.c",
     "contrib/minizip/zip.h",
   ]
 
   if (!is_win) {
     sources -= [
       "contrib/minizip/iowin32.c",
       "contrib/minizip/iowin32.h",
     ]
   }
   if (is_mac || is_ios || is_android) {
     # Mac, Android and the BSDs don't have fopen64, ftello64, or fseeko64. We
     # use fopen, ftell, and fseek instead on these systems.
     defines = [ "USE_FILE32API" ]
   }
 
   deps = [
     ":zlib",
   ]
 
-  config("minizip_warnings") {
-    if (is_clang) {
-      # zlib uses `if ((a == b))` for some reason.
-      cflags = [ "-Wno-parentheses-equality" ]
-    }
-  }
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
 
-  configs -= [ "//build/config/compiler:chromium_code" ]
-  configs += [ "//build/config/compiler:no_chromium_code" ]
-  configs += [ ":minizip_warnings" ]
+    # Must be after no_chromium_code for warning flags to be ordered correctly.
+    ":minizip_warnings",
+  ]
   public_configs = [ ":zlib_config" ]
 }
 
 static_library("zip") {
   sources = [
     "google/zip.cc",
     "google/zip.h",
     "google/zip_internal.cc",
     "google/zip_internal.h",
     "google/zip_reader.cc",
     "google/zip_reader.h",
   ]
   deps = [
     ":minizip",
     "//base",
   ]
 }