[Mac] Implement LocationBarViewMac::UpdateLocationBarVisibility()

chrome/browser/ui/cocoa/toolbar/toolbar_controller.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/toolbar/toolbar_controller.h"
 
 #include <algorithm>
 
 #include "base/mac/bundle_locations.h"
 #include "base/mac/foundation_util.h"
@@ skipping 52 matching lines @@
 #include "ui/base/l10n/l10n_util_mac.h"
 #include "ui/gfx/geometry/rect.h"
 #include "ui/gfx/image/image.h"
 
 using content::OpenURLParams;
 using content::Referrer;
 using content::WebContents;
 
 namespace {
 
+// Duration of the toolbar animation.
+const NSTimeInterval kToolBarAnimationDuration = 0.12;
+
 // Height of the toolbar in pixels when the bookmark bar is closed.
 const CGFloat kBaseToolbarHeightNormal = 35.0;
 
+// Height of the location bar. Used for animating the toolbar in and out when
+// the location bar is displayed stand-alone for bookmark apps.
+const CGFloat kLocationBarHeight = 29.0;
+
 // The padding above the toolbar elements. This is calculated from the values
 // in Toolbar.xib: the height of the toolbar (35) minus the height of the child
 // elements (29) minus the y-origin of the elements (4).
 const CGFloat kToolbarElementTopPadding = 2.0;
 
 // The minimum width of the location bar in pixels.
 const CGFloat kMinimumLocationBarWidth = 100.0;
 
 // The amount of left padding that the wrench menu should have.
 const CGFloat kWrenchMenuLeftPadding = 3.0;
@@ skipping 35 matching lines @@
 }
 
 }  // namespace
 
 @interface ToolbarController()
 @property(assign, nonatomic) Browser* browser;
 - (void)cleanUp;
 - (void)addAccessibilityDescriptions;
 - (void)initCommandStatus:(CommandUpdater*)commands;
 - (void)prefChanged:(const std::string&)prefName;
-- (BackgroundGradientView*)backgroundGradientView;
+- (ToolbarView*)toolbarView;
 - (void)toolbarFrameChanged;
+- (void)showLocationBarOnly;
 - (void)pinLocationBarToLeftOfBrowserActionsContainerAndAnimate:(BOOL)animate;
 - (void)maintainMinimumLocationBarWidth;
 - (void)adjustBrowserActionsContainerForNewWindow:(NSNotification*)notification;
 - (void)browserActionsContainerDragged:(NSNotification*)notification;
 - (void)browserActionsVisibilityChanged:(NSNotification*)notification;
 - (void)browserActionsContainerWillAnimate:(NSNotification*)notification;
 - (void)adjustLocationSizeBy:(CGFloat)dX animate:(BOOL)animate;
 - (void)updateWrenchButtonSeverity:(WrenchIconPainter::Severity)severity
                            animate:(BOOL)animate;
 @end
@@ skipping 59 matching lines @@
 
 }  // namespace ToolbarControllerInternal
 
 @implementation ToolbarController
 
 @synthesize browser = browser_;
 
 - (id)initWithCommands:(CommandUpdater*)commands
                profile:(Profile*)profile
                browser:(Browser*)browser
-          nibFileNamed:(NSString*)nibName {
-  DCHECK(commands && profile && [nibName length]);
-  if ((self = [super initWithNibName:nibName
+        resizeDelegate:(id<ViewResizer>)resizeDelegate {
+  DCHECK(commands && profile);
+  if ((self = [super initWithNibName:@"Toolbar"
                               bundle:base::mac::FrameworkBundle()])) {
     commands_ = commands;
     profile_ = profile;
     browser_ = browser;
     hasToolbar_ = YES;
     hasLocationBar_ = YES;
 
     // Register for notifications about state changes for the toolbar buttons
     commandObserver_.reset(
         new ToolbarControllerInternal::CommandObserverBridge(self));
 
     commands->AddCommandObserver(IDC_BACK, commandObserver_.get());
     commands->AddCommandObserver(IDC_FORWARD, commandObserver_.get());
     commands->AddCommandObserver(IDC_RELOAD, commandObserver_.get());
     commands->AddCommandObserver(IDC_HOME, commandObserver_.get());
     commands->AddCommandObserver(IDC_BOOKMARK_PAGE, commandObserver_.get());
     // NOTE: Don't remove the command observers. ToolbarController is
     // autoreleased at about the same time as the CommandUpdater (owned by the
     // Browser), so |commands_| may not be valid any more.
-  }
-  return self;
-}
 
-- (id)initWithCommands:(CommandUpdater*)commands
-               profile:(Profile*)profile
-               browser:(Browser*)browser {
-  if ((self = [self initWithCommands:commands
-                             profile:profile
-                             browser:browser
-                        nibFileNamed:@"Toolbar"])) {
+    [[self toolbarView] setResizeDelegate:resizeDelegate];
+
     // Start global error services now so we badge the menu correctly.
     SyncGlobalErrorFactory::GetForProfile(profile);
   }
   return self;
 }
 
 // Called after the view is done loading and the outlets have been hooked up.
 // Now we can hook up bridges that rely on UI objects such as the location bar
 // and button state. -viewDidLoad is the recommended way to do this in 10.10
 // SDK. When running on 10.10 or above -awakeFromNib still works but for some
@@ skipping 87 matching lines @@
   // Create the controllers for the back/forward menus.
   backMenuController_.reset([[BackForwardMenuController alloc]
           initWithBrowser:browser_
                 modelType:BACK_FORWARD_MENU_TYPE_BACK
                    button:backButton_]);
   forwardMenuController_.reset([[BackForwardMenuController alloc]
           initWithBrowser:browser_
                 modelType:BACK_FORWARD_MENU_TYPE_FORWARD
                    button:forwardButton_]);
 
-  // For a popup window, the toolbar is really just a location bar
-  // (see override for [ToolbarController view], below).  When going
-  // fullscreen, we remove the toolbar controller's view from the view
-  // hierarchy.  Calling [locationBar_ removeFromSuperview] when going
-  // fullscreen causes it to get released, making us unhappy
-  // (http://crbug.com/18551).  We avoid the problem by incrementing
-  // the retain count of the location bar; use of the scoped object
-  // helps us remember to release it.
-  locationBarRetainer_.reset([locationBar_ retain]);
   trackingArea_.reset(
       [[CrTrackingArea alloc] initWithRect:NSZeroRect // Ignored
                                    options:NSTrackingMouseMoved |
                                            NSTrackingInVisibleRect |
                                            NSTrackingMouseEnteredAndExited |
                                            NSTrackingActiveAlways
                                      owner:self
                                   userInfo:nil]);
   NSView* toolbarView = [self view];
   [toolbarView addTrackingArea:trackingArea_.get()];
@@ skipping 17 matching lines @@
 
   [self addAccessibilityDescriptions];
 }
 
 - (void)dealloc {
   [self cleanUp];
   [super dealloc];
 }
 
 - (void)browserWillBeDestroyed {
+  // Clear resize delegate so it doesn't get called during stopAnimation, and
+  // stop any in-flight animation.
+  [[self toolbarView] setResizeDelegate:nil];
+  [[self toolbarView] stopAnimation];
+
   // Pass this call onto other reference counted objects.
   [backMenuController_ browserWillBeDestroyed];
   [forwardMenuController_ browserWillBeDestroyed];
   [browserActionsController_ browserWillBeDestroyed];
   [wrenchMenuController_ browserWillBeDestroyed];
 
   [self cleanUp];
 }
 
 - (void)cleanUp {
@@ skipping 172 matching lines @@
 
   hasToolbar_ = toolbar;
 
   // If there's a toolbar, there must be a location bar.
   DCHECK((toolbar && locBar) || !toolbar);
   hasLocationBar_ = toolbar ? YES : locBar;
 
   // Decide whether to hide/show based on whether there's a location bar.
   [[self view] setHidden:!hasLocationBar_];
 
-  // Make location bar not editable when in a pop-up.
+  // Make location bar not editable when in a pop-up or an app window.
   locationBarView_->SetEditable(toolbar);
+
+  // Display the toolbar with only the location bar inside it. No-ops if the

[tapted, 2015/10/26 07:55:34]

The No-ops comment is no longer needed, now we are assured that setHasToolbar:
is always called exactly once

[dominickn, 2015/10/26 23:31:32]

Done.

+  // toolbar view is already in this state.
+  if (!hasToolbar_ && hasLocationBar_)
+    [self showLocationBarOnly];
 }
 
-- (NSView*)view {
-  if (hasToolbar_)
-    return [super view];
-  return locationBar_;
-}
-
-// (Private) Returns the backdrop to the toolbar.
-- (BackgroundGradientView*)backgroundGradientView {
-  // We really do mean |[super view]|; see our override of |-view|.
-  DCHECK([[super view] isKindOfClass:[BackgroundGradientView class]]);
-  return (BackgroundGradientView*)[super view];
+// (Private) Returns the backdrop to the toolbar as a ToolbarView.
+- (ToolbarView*)toolbarView{
+  return base::mac::ObjCCastStrict<ToolbarView>([self view]);
 }
 
 - (id)customFieldEditorForObject:(id)obj {
   if (obj == locationBar_) {
     // Lazilly construct Field editor, Cocoa UI code always runs on the
     // same thread, so there shoudn't be a race condition here.
     if (autocompleteTextFieldEditor_.get() == nil) {
       autocompleteTextFieldEditor_.reset(
           [[AutocompleteTextFieldEditor alloc] init]);
     }
@@ skipping 104 matching lines @@
     [[NSNotificationCenter defaultCenter]
         addObserver:self
            selector:@selector(adjustBrowserActionsContainerForNewWindow:)
                name:NSWindowDidBecomeKeyNotification
              object:[[self view] window]];
   }
   if (![browserActionsContainerView_ isHidden])
     [self pinLocationBarToLeftOfBrowserActionsContainerAndAnimate:NO];
 }
 
+- (void)updateVisibility:(BOOL)visible withAnimation:(BOOL)animate {
+  // |visible| being YES is equivalent to [[toolbarController_ view] isHidden]
+  // being NO, and vice-versa. That is, when |visible| and |isHidden| have the
+  // same value, a state change is needed.
+  ToolbarView* view = [self toolbarView];
+
+  if ([view isHidden] == visible) {
+    CGFloat newHeight = visible ? kLocationBarHeight : 0;
+
+    // Perform the animation, which will cause the BrowserWindowController to
+    // resize this view in the browser layout as required.
+    if (animate) {
+      [view animateToNewHeight:newHeight
+                      duration:kToolBarAnimationDuration];
+    } else {
+      [view setHeight:newHeight];
+    }
+    [view setHidden:!visible];

[tapted, 2015/10/26 07:55:34]

I think this line should be removed. The problem is that setting it hidden gives
AnimatableView nothing to animate when hiding. When I try it, it first flashes
to grey, then (effectively) it's just the WebContentsView that animates up.

So, then I think the problem is that you lose the `target` visibility, and
AnimatableView doesn't offer a way to get it.

Two options:
 1) Suppress redundant calls to updateVisibility elsewhere, or find other ways
to eliminate the redundant calls themselves so we don't have to bother
suppressing them
 2) Add (back?) the `BOOL locationBarHidden_;` member (here, or a `bool` on
LocationBarViewMac) and comment about its purpose and where the redundant calls
come from

I guess AnimatableView could also be updated to provide some kind of
targetVisibility, but one of those seems more appropriate

[dominickn, 2015/10/26 23:31:32]

Done (option 2).

+  }
+}
+
 - (void)adjustBrowserActionsContainerForNewWindow:
     (NSNotification*)notification {
   [self toolbarFrameChanged];
   [[NSNotificationCenter defaultCenter]
       removeObserver:self
                 name:NSWindowDidBecomeKeyNotification
               object:[[self view] window]];
 }
 
 - (void)browserActionsContainerDragged:(NSNotification*)notification {
@@ skipping 83 matching lines @@
       containerFrame = NSOffsetRect(containerFrame,
           NSWidth(containerFrame) - savedContainerWidth, 0);
       containerFrame.size.width = savedContainerWidth;
       [browserActionsContainerView_ setGrippyPinned:NO];
     }
     [browserActionsContainerView_ setFrame:containerFrame];
     [self pinLocationBarToLeftOfBrowserActionsContainerAndAnimate:NO];
   }
 }
 
+// Hide the back, forward, reload, home, and wrench buttons of the toolbar.
+// This allows the location bar to occupy the entire width. There is no way to
+// undo this operation, and once it is called, no other programmatic changes
+// to the toolbar or location bar width should be made. This message is
+// invalid if the toolbar is shown or the location bar is hidden.
+- (void)showLocationBarOnly {
+  DCHECK(!hasToolbar_ && hasLocationBar_);
+
+  // If the toolbar buttons are already hidden, return. Assumes that the back,
+  // forward, reload, and wrench buttons are either shown or hidden together.
+  if ([backButton_ isHidden]) {

[tapted, 2015/10/26 07:55:34]

Likewise, this can be

// -showLocationBarOnly is only ever called once, shortly after initialization,
// so the regular buttons should all be visible.
DCHECK(![backButton_ isHidden]);

(probably not worth checking the rest.

And perhaps even better just to remove this entirely. (needs something though,
since I'm pretty sure the DCHECK_EQ below is now unreachable)

[dominickn, 2015/10/26 23:31:32]

Done.

+    DCHECK_EQ(YES, [backButton_ isHidden] && [forwardButton_ isHidden] &&
+                       [reloadButton_ isHidden] && [wrenchButton_ isHidden]);
+    return;
+  }
+
+  // Ensure the location bar fills the toolbar.
+  NSRect toolbarFrame = [[self view] frame];
+  toolbarFrame.size.height = kLocationBarHeight;
+  [[self view] setFrame:toolbarFrame];
+
+  [locationBar_ setFrame:NSMakeRect(0, 0, NSWidth([[self view] frame]),
+                                    kLocationBarHeight)];
+
+  [backButton_ setHidden:YES];
+  [forwardButton_ setHidden:YES];
+  [reloadButton_ setHidden:YES];
+  [wrenchButton_ setHidden:YES];
+  [homeButton_ setHidden:YES];
+}
+
 - (void)adjustLocationSizeBy:(CGFloat)dX animate:(BOOL)animate {
   // Ensure that the location bar is in its proper place.
   NSRect locationFrame = [locationBar_ frame];
   locationFrame.size.width += dX;
 
   [locationBar_ stopAnimation];
 
   if (animate)
     [locationBar_ animateToFrame:locationFrame];
   else
@@ skipping 22 matching lines @@
 
 - (CGFloat)desiredHeightForCompression:(CGFloat)compressByHeight {
   // With no toolbar, just ignore the compression.
   if (!hasToolbar_)
     return NSHeight([locationBar_ frame]);
 
   return kBaseToolbarHeightNormal - compressByHeight;
 }
 
 - (void)setDividerOpacity:(CGFloat)opacity {
-  BackgroundGradientView* view = [self backgroundGradientView];
-  [view setShowsDivider:(opacity > 0 ? YES : NO)];
-
-  // We may not have a toolbar view (e.g., popup windows only have a location
-  // bar).
-  if ([view isKindOfClass:[ToolbarView class]]) {
-    ToolbarView* toolbarView = (ToolbarView*)view;
-    [toolbarView setDividerOpacity:opacity];
-  }
-
-  [view setNeedsDisplay:YES];
+  ToolbarView* toolbarView = [self toolbarView];
+  [toolbarView setShowsDivider:(opacity > 0 ? YES : NO)];
+  [toolbarView setDividerOpacity:opacity];
+  [toolbarView setNeedsDisplay:YES];
 }
 
 - (BrowserActionsController*)browserActionsController {
   return browserActionsController_.get();
 }
 
 - (NSView*)wrenchButton {
   return wrenchButton_;
 }
 
@@ skipping 55 matching lines @@
 - (void)hideDropURLsIndicatorInView:(NSView*)view {
   // Do nothing.
 }
 
 // (URLDropTargetController protocol)
 - (BOOL)isUnsupportedDropData:(id<NSDraggingInfo>)info {
   return drag_util::IsUnsupportedDropData(profile_, info);
 }
 
 @end