Avoid sync IPCs for firstRectForCharacterRange/attributedSubstringForProposedRange.

content/browser/renderer_host/render_widget_host_view_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "content/browser/renderer_host/render_widget_host_view_mac.h"
 
 #import <objc/runtime.h>
 #include <OpenGL/gl.h>
 #include <QuartzCore/QuartzCore.h>
 
@@ skipping 1207 matching lines @@
     [cocoa_view_ setMarkedRange:range.ToNSRange()];
   }
 
   RenderWidgetHostViewBase::SelectionChanged(text, offset, range);
 }
 
 void RenderWidgetHostViewMac::SelectionBoundsChanged(
     const ViewHostMsg_SelectionBounds_Params& params) {
   if (params.anchor_rect == params.focus_rect)
     caret_rect_ = params.anchor_rect;
+  first_selection_rect_ = params.anchor_rect;
 }
 
 void RenderWidgetHostViewMac::SetShowingContextMenu(bool showing) {
   RenderWidgetHostViewBase::SetShowingContextMenu(showing);
 
   // Create a fake mouse event to inform the render widget that the mouse
   // left or entered.
   NSWindow* window = [cocoa_view_ window];
   // TODO(asvitkine): If the location outside of the event stream doesn't
   // correspond to the current event (due to delayed event processing), then
@@ skipping 208 matching lines @@
                "RenderWidgetHostViewMac::GetFirstRectForCharacterRange");
 
   // If requested range is same as caret location, we can just return it.
   if (selection_range_.is_empty() && gfx::Range(range) == selection_range_) {
     if (actual_range)
       *actual_range = range;
     *rect = NSRectFromCGRect(caret_rect_.ToCGRect());
     return true;
   }
 
+  if (composition_range_.is_empty()) {
+    *actual_range = selection_range_.ToNSRange();
+    *rect = NSRectFromCGRect(first_selection_rect_.ToCGRect());
+    return true;
+  }
+
   const gfx::Range request_range_in_composition =
       ConvertCharacterRangeToCompositionRange(gfx::Range(range));
   if (request_range_in_composition == gfx::Range::InvalidRange())
     return false;
 
   // If firstRectForCharacterRange in WebFrame is failed in renderer,
   // ImeCompositionRangeChanged will be sent with empty vector.
   if (composition_bounds_.empty())
     return false;
   DCHECK_EQ(composition_bounds_.size(), composition_range_.length());
@@ skipping 1414 matching lines @@
   // there. (When this method returns an empty range, the input method doesn't
   // call the setMarkedText method.)
   return hasMarkedText_ ? markedRange_ : NSMakeRange(NSNotFound, 0);
 }
 
 - (NSAttributedString*)attributedSubstringForProposedRange:(NSRange)range
     actualRange:(NSRangePointer)actualRange {
   // TODO(thakis): Pipe |actualRange| through TextInputClientMac machinery.
   if (actualRange)
     *actualRange = range;
-  NSAttributedString* str =
-      TextInputClientMac::GetInstance()->GetAttributedSubstringFromRange(
-          renderWidgetHostView_->render_widget_host_, range);
-  return str;
+
+  const gfx::Range requested_range(range);
+  if (requested_range.is_reversed())
+    return nil;
+
+  gfx::Range expected_range;
+  base::string16 expected_text;
+
+  if (!renderWidgetHostView_->composition_range().is_empty()) {
+    expected_text = markedText_;
+    expected_range = renderWidgetHostView_->composition_range();
+  } else {
+    expected_text = renderWidgetHostView_->selection_text();
+    size_t offset = renderWidgetHostView_->selection_text_offset();
+    expected_range = gfx::Range(offset, offset + expected_text.size());
+  }
+
+  if (!expected_range.Contains(requested_range))
+    return nil;
+
+  expected_text = expected_text.substr(
+      requested_range.start() - expected_range.start(),
+      requested_range.length());
+
+  return [[[NSAttributedString alloc] initWithString:
+      base::SysUTF16ToNSString(expected_text)] autorelease];

[Alexei Svitkine (slow), 2015/08/25 14:55:39]

I think you can avoid a couple of temp string copies via:

const base::string16* expected_text;
if (!renderWidgetHostView_->composition_range().is_empty()) {
  ...
  expected_text = &markedText_;
} else {
  ...
  expected_text = &renderWidgetHostView_->selection_text();
}

...

const char16* bytes =
    &expected_text[requested_range.start() - expected_range.start()];
base::scoped_nsobject<NSObject> ns_string(
    [[NSString alloc] initWithBytes:bytes
                             length:requested_range.length()
                           encoding:NSUTF16StringEncoding]);
return [[[NSAttributedString alloc] initWithString:ns_string] autorelease];

Since the selection can be a whole document (e.g. select all), I think the
optimization would be worth it (with a comment).

 }
 
 - (NSInteger)conversationIdentifier {
   return reinterpret_cast<NSInteger>(self);
 }
 
 // Each RenderWidgetHostViewCocoa has its own input context, but we return
 // nil when the caret is in non-editable content or password box to avoid
 // making input methods do their work.
 - (NSTextInputContext *)inputContext {
@@ skipping 411 matching lines @@
 
 // "-webkit-app-region: drag | no-drag" is implemented on Mac by excluding
 // regions that are not draggable. (See ControlRegionView in
 // native_app_window_cocoa.mm). This requires the render host view to be
 // draggable by default.
 - (BOOL)mouseDownCanMoveWindow {
   return YES;
 }
 
 @end