Open from clipboard: Support nil clipboard

components/open_from_clipboard/clipboard_recent_content_ios.mm

 // Copyright 2015 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "components/open_from_clipboard/clipboard_recent_content_ios.h"
 
 #import <CommonCrypto/CommonDigest.h>
 #import <UIKit/UIKit.h>
 
 #import "base/ios/ios_util.h"
@@ skipping 130 matching lines @@
 
 void ClipboardRecentContentIOS::SuppressClipboardContent() {
   // User cleared the user data. The pasteboard entry must be removed from the
   // omnibox list. Force entry expiration by setting copy date to 1970.
   last_pasteboard_change_date_.reset(
       [[NSDate alloc] initWithTimeIntervalSince1970:0]);
   SaveToUserDefaults();
 }
 
 void ClipboardRecentContentIOS::PasteboardChanged() {
+  NSString* pasteboard_string = [[UIPasteboard generalPasteboard] string];
+  if (!pasteboard_string)
+    return;
   url_from_pasteboard_cache_ = URLFromPasteboard();
   if (!url_from_pasteboard_cache_.is_empty()) {
     base::RecordAction(
         base::UserMetricsAction("MobileOmniboxClipboardChanged"));
   }
   last_pasteboard_change_date_.reset([[NSDate date] retain]);
   last_pasteboard_change_count_ = [UIPasteboard generalPasteboard].changeCount;
-  NSString* pasteboard_string = [[UIPasteboard generalPasteboard] string];
-  if (!pasteboard_string) {
-    pasteboard_string = @"";
-  }
   NSData* MD5 = WeakMD5FromNSString(pasteboard_string);
   last_pasteboard_entry_md5_.reset([MD5 retain]);
   SaveToUserDefaults();
 }
 
 ClipboardRecentContentIOS::ClipboardRecentContentIOS(
     const std::string& application_scheme,
     NSUserDefaults* group_user_defaults)
     : application_scheme_(application_scheme),
       shared_user_defaults_([group_user_defaults retain]) {
   Init(base::TimeDelta::FromMilliseconds(base::SysInfo::Uptime()));
 }
 
 ClipboardRecentContentIOS::ClipboardRecentContentIOS(
     const std::string& application_scheme,
     base::TimeDelta uptime)
     : application_scheme_(application_scheme),
       shared_user_defaults_([[NSUserDefaults standardUserDefaults] retain]) {
   Init(uptime);
 }
 
 bool ClipboardRecentContentIOS::HasPasteboardChanged(base::TimeDelta uptime) {
+  // If [[UIPasteboard generalPasteboard] string] is nil, the content of the
+  // pasteboard cannot be accessed. This case should not be considered as a
+  // pasteboard change.
+  NSString* pasteboard_string = [[UIPasteboard generalPasteboard] string];
+  if (!pasteboard_string)
+    return NO;
+
   // If |MD5Changed|, we know for sure there has been at least one pasteboard
   // copy since last time it was checked.
   // If the pasteboard content is still the same but the device was not
   // rebooted, the change count can be checked to see if it changed.
   // Note: due to a mismatch between the actual behavior and documentation, and
   // lack of consistency on different reboot scenarios, the change count cannot
   // be checked after a reboot.
   // See radar://21833556 for more information.
   NSInteger change_count = [UIPasteboard generalPasteboard].changeCount;
   bool change_count_changed = change_count != last_pasteboard_change_count_;
 
   bool not_rebooted = uptime > GetClipboardContentAge();
   if (not_rebooted)
     return change_count_changed;
 
-  NSString* pasteboard_string = [[UIPasteboard generalPasteboard] string];
-  if (!pasteboard_string) {
-    pasteboard_string = @"";
-  }
   NSData* md5 = WeakMD5FromNSString(pasteboard_string);
   BOOL md5_changed = ![md5 isEqualToData:last_pasteboard_entry_md5_];
 
   return md5_changed;
 }
 
 void ClipboardRecentContentIOS::Init(base::TimeDelta uptime) {
   last_pasteboard_change_count_ = NSIntegerMax;
   url_from_pasteboard_cache_ = URLFromPasteboard();
   LoadFromUserDefaults();
 
   if (HasPasteboardChanged(uptime))
     PasteboardChanged();
 
   // Makes sure |last_pasteboard_change_count_| was properly initialized.
   DCHECK_NE(last_pasteboard_change_count_, NSIntegerMax);
   notification_bridge_.reset(
       [[PasteboardNotificationListenerBridge alloc] initWithDelegate:this]);
 }
 
 ClipboardRecentContentIOS::~ClipboardRecentContentIOS() {
   [notification_bridge_ disconnect];
 }
 
 GURL ClipboardRecentContentIOS::URLFromPasteboard() {
-  const std::string clipboard =
-      base::SysNSStringToUTF8([[UIPasteboard generalPasteboard] string]);
+  NSString* clipboard_string = [[UIPasteboard generalPasteboard] string];
+  if (!clipboard_string) {
+    return GURL::EmptyGURL();
+  }
+  const std::string clipboard = base::SysNSStringToUTF8(clipboard_string);

[droger, 2015/08/17 08:27:39]

It seems this change does not affect the behavior of the function. Is it a
mistake?

[Olivier, 2015/08/17 08:33:19]

The result is the same.
But adding the early return avoid testing the schemes and 
If [[UIPasteboard generalPasteboard] string] is nil, we should do at little as
possible, and specially not update the stored entries in NSUserDefaults.
Adding an early return will also avoid mistakes if something is added to the
function.

   GURL gurl = GURL(clipboard);
   if (gurl.is_valid()) {
     for (size_t i = 0; i < arraysize(kAuthorizedSchemes); ++i) {
       if (gurl.SchemeIs(kAuthorizedSchemes[i])) {
         return gurl;
       }
     }
     if (!application_scheme_.empty() &&
         gurl.SchemeIs(application_scheme_.c_str())) {
       return gurl;
@@ skipping 29 matching lines @@
 void ClipboardRecentContentIOS::SaveToUserDefaults() {
   [shared_user_defaults_ setInteger:last_pasteboard_change_count_
                              forKey:kPasteboardChangeCountKey];
   [shared_user_defaults_ setObject:last_pasteboard_change_date_
                             forKey:kPasteboardChangeDateKey];
   [shared_user_defaults_ setObject:last_pasteboard_entry_md5_
                             forKey:kPasteboardEntryMD5Key];
   [shared_user_defaults_ setObject:last_displayed_pasteboard_entry_
                             forKey:kLastDisplayedPasteboardEntryKey];
 }