Create *_managed targets for android_apk()s

build/config/android/internal_rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/android/config.gni")
 
 assert(is_android)
 
 rebased_android_sdk = rebase_path(android_sdk, root_build_dir)
 rebased_android_sdk_root = rebase_path(android_sdk_root, root_build_dir)
 rebased_android_sdk_build_tools =
     rebase_path(android_sdk_build_tools, root_build_dir)
 
 android_sdk_jar = "$android_sdk/android.jar"
 rebased_android_sdk_jar = rebase_path(android_sdk_jar, root_build_dir)
 android_aapt_path = "$rebased_android_sdk_build_tools/aapt"
 
+android_configuration_name = "Release"
+if (is_debug) {
+  android_configuration_name = "Debug"
+}
+
 template("android_lint") {
   set_sources_assignment_filter([])
   if (defined(invoker.testonly)) {
     testonly = invoker.testonly
   }
 
   jar_path = invoker.jar_path
   android_manifest = invoker.android_manifest
   java_files = invoker.java_files
   base_path = "$target_gen_dir/$target_name"
@@ skipping 469 matching lines @@
     if (defined(invoker.visibility)) {
       visibility = invoker.visibility
     }
     public_deps = [
       ":${target_name}__jar_toc",
       ":$_output_jar_target",
     ]
   }
 }
 
+# Creates an unsigned .apk
+#
+# Variables
+#   deps: Specifies the dependencies of this target.
+#   dex_path: Path to classes.dex file to include (optional).
+#   resource_packaged_apk_path: Path to .ap_ to use.

[Dirk Pranke, 2015/08/17 21:14:13]

is `.ap_` a typo? 

[agrieve, 2015/08/18 14:48:47]

Awesomely, no. That's the actual extension chosen for android resource-only
apks.

+#   output_apk_path: Output path for the generated .apk.
+#   native_libs_dir: Directory containing native libraries.
+template("package_apk") {
+  action(target_name) {
+    if (defined(invoker.testonly)) {
+      testonly = invoker.testonly
+    }
+    script = "//build/android/gyp/ant.py"
+    _ant_script = "//build/android/ant/apk-package.xml"
+
+    deps = invoker.deps
+    depfile = "$target_gen_dir/$target_name.d"
+
+    inputs = [
+      invoker.resource_packaged_apk_path,
+      _ant_script,
+    ]
+    if (defined(invoker.dex_path)) {
+      inputs += [ invoker.dex_path ]
+    }

[Dirk Pranke, 2015/08/17 21:14:13]

you can (and should) use 

    forward_variables_from(invoker, ["dex_path", "testonly"])

now, instead.

[agrieve, 2015/08/18 14:48:47]

Done.

+
+    outputs = [
+      depfile,
+      invoker.output_apk_path,
+    ]
+
+    _rebased_emma_jar = ""
+    _rebased_resource_packaged_apk_path =
+        rebase_path(invoker.resource_packaged_apk_path, root_build_dir)
+    _rebased_packaged_apk_path =
+        rebase_path(invoker.output_apk_path, root_build_dir)
+    _rebased_native_libs_dir =
+        rebase_path(invoker.native_libs_dir, root_build_dir)
+    args = [
+      "--depfile",
+      rebase_path(depfile, root_build_dir),
+      "--",
+      "-quiet",
+      "-DANDROID_SDK_ROOT=$rebased_android_sdk_root",
+      "-DANDROID_SDK_TOOLS=$rebased_android_sdk_build_tools",
+      "-DRESOURCE_PACKAGED_APK_NAME=$_rebased_resource_packaged_apk_path",
+      "-DCONFIGURATION_NAME=$android_configuration_name",
+      "-DNATIVE_LIBS_DIR=$_rebased_native_libs_dir",
+      "-DOUT_DIR=",
+      "-DUNSIGNED_APK_PATH=$_rebased_packaged_apk_path",
+      "-DEMMA_INSTRUMENT=0",
+      "-DEMMA_DEVICE_JAR=$_rebased_emma_jar",
+      "-Dbasedir=.",
+      "-buildfile",
+      rebase_path(_ant_script, root_build_dir),
+    ]
+    if (defined(invoker.dex_path)) {
+      _rebased_dex_path = rebase_path(invoker.dex_path, root_build_dir)
+      args += [
+        "-DDEX_FILE_PATH=$_rebased_dex_path",
+        "-DHAS_CODE=true",
+      ]
+    } else {
+      args += [ "-DHAS_CODE=false" ]
+    }
+  }
+}
+
 template("finalize_apk") {
   action(target_name) {
     script = "//build/android/gyp/finalize_apk.py"
     depfile = "$target_gen_dir/$target_name.d"
 
     if (defined(invoker.testonly)) {
       testonly = invoker.testonly
     }
 
     sources = [
@@ skipping 49 matching lines @@
 # zipaligns the apk.
 template("create_apk") {
   set_sources_assignment_filter([])
   if (defined(invoker.testonly)) {
     testonly = invoker.testonly
   }
 
   _android_manifest = invoker.android_manifest
   _base_path = invoker.base_path
   _final_apk_path = invoker.apk_path
+  _managed_final_apk_path_helper =
+      process_file_template([ _final_apk_path ],
+                            "{{source_dir}}/{{source_name_part}}_managed.apk")
+  _managed_final_apk_path = _managed_final_apk_path_helper[0]
 
   if (defined(invoker.resources_zip)) {
     _resources_zip = invoker.resources_zip
   }
   if (defined(invoker.dex_path)) {
     _dex_path = invoker.dex_path
   }
   _load_library_from_apk = invoker.load_library_from_apk
 
   _package_deps = []
@@ skipping 10 matching lines @@
     _asset_location = invoker.asset_location
   }
 
   _version_code = invoker.version_code
   _version_name = invoker.version_name
 
   _base_apk_path = _base_path + ".apk_intermediates"
 
   _resource_packaged_apk_path = _base_apk_path + ".ap_"
   _packaged_apk_path = _base_apk_path + ".unfinished.apk"
+  _managed_packaged_apk_path = _base_apk_path + "_managed.unfinished.apk"
   _shared_resources =
       defined(invoker.shared_resources) && invoker.shared_resources
 
-  _configuration_name = "Release"
-  if (is_debug) {
-    _configuration_name = "Debug"
-  }
-
   _keystore_path = invoker.keystore_path
   _keystore_name = invoker.keystore_name
   _keystore_password = invoker.keystore_password
 
   _split_densities = []
   if (defined(invoker.create_density_splits) && invoker.create_density_splits) {
     _split_densities = [
       "hdpi",
       "xhdpi",
       "xxhdpi",
@@ skipping 24 matching lines @@
       _resource_packaged_apk_path,
     ]
 
     args = [
       "--depfile",
       rebase_path(depfile, root_build_dir),
       "--android-sdk",
       rebased_android_sdk,
       "--aapt-path",
       android_aapt_path,
-      "--configuration-name=$_configuration_name",
+      "--configuration-name=$android_configuration_name",
       "--android-manifest",
       rebase_path(_android_manifest, root_build_dir),
       "--version-code",
       _version_code,
       "--version-name",
       _version_name,
       "--apk-path",
       rebase_path(_resource_packaged_apk_path, root_build_dir),
     ]
 
@@ skipping 26 matching lines @@
     }
     if (defined(invoker.extensions_to_not_compress)) {
       args += [
         "--no-compress",
         invoker.extensions_to_not_compress,
       ]
     }
   }
 
   package_target = "${target_name}__package"
-  action(package_target) {
-    script = "//build/android/gyp/ant.py"
-    _ant_script = "//build/android/ant/apk-package.xml"
-
+  package_apk(package_target) {
     deps = [
       ":${_package_resources_target_name}",
     ]
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
-    depfile = "$target_gen_dir/$target_name.d"
+    if (defined(_dex_path)) {
+      dex_path = _dex_path
+    }
+    native_libs_dir = _native_libs_dir
+    output_apk_path = _packaged_apk_path
+    resource_packaged_apk_path = _resource_packaged_apk_path
+  }
 
-    inputs = [
-      _resource_packaged_apk_path,
-      _ant_script,
+  _managed_package_target = "${target_name}_managed__package"
+  package_apk(_managed_package_target) {
+    deps = [
+      ":${_package_resources_target_name}",
     ]
-    if (defined(_dex_path)) {
-      inputs += [ _dex_path ]
+    if (defined(invoker.deps)) {
+      deps += invoker.deps

[Dirk Pranke, 2015/08/17 21:14:13]

same comment

[agrieve, 2015/08/18 14:48:47]

Done.

     }
 
-    outputs = [
-      depfile,
-      _packaged_apk_path,
-    ]
+    # TODO(agrieve): Multidex
+    if (defined(_dex_path)) {
+      dex_path = _dex_path
+    }
 
-    _rebased_emma_jar = ""
-    _rebased_resource_packaged_apk_path =
-        rebase_path(_resource_packaged_apk_path, root_build_dir)
-    _rebased_packaged_apk_path = rebase_path(_packaged_apk_path, root_build_dir)
-    _rebased_native_libs_dir = rebase_path(_native_libs_dir, root_build_dir)
-    args = [
-      "--depfile",
-      rebase_path(depfile, root_build_dir),
-      "--",
-      "-quiet",
-      "-DANDROID_SDK_ROOT=$rebased_android_sdk_root",
-      "-DANDROID_SDK_TOOLS=$rebased_android_sdk_build_tools",
-      "-DRESOURCE_PACKAGED_APK_NAME=$_rebased_resource_packaged_apk_path",
-      "-DCONFIGURATION_NAME=$_configuration_name",
-      "-DNATIVE_LIBS_DIR=$_rebased_native_libs_dir",
-      "-DOUT_DIR=",
-      "-DUNSIGNED_APK_PATH=$_rebased_packaged_apk_path",
-      "-DEMMA_INSTRUMENT=0",
-      "-DEMMA_DEVICE_JAR=$_rebased_emma_jar",
-      "-Dbasedir=.",
-      "-buildfile",
-      rebase_path(_ant_script, root_build_dir),
-    ]
-    if (defined(_dex_path)) {
-      _rebased_dex_path = rebase_path(_dex_path, root_build_dir)
-      args += [
-        "-DDEX_FILE_PATH=$_rebased_dex_path",
-        "-DHAS_CODE=true",
-      ]
-    } else {
-      args += [ "-DHAS_CODE=false" ]
-    }
+    # TODO(agrieve): Add a placeholder .so for http://crbug.com/384638
+    native_libs_dir = "//build/android/empty/res"
+    output_apk_path = _managed_packaged_apk_path
+    resource_packaged_apk_path = _resource_packaged_apk_path
   }
 
   _finalize_apk_rule_name = "${target_name}__finalize"
   finalize_apk(_finalize_apk_rule_name) {
     input_apk_path = _packaged_apk_path
     output_apk_path = _final_apk_path
     keystore_path = _keystore_path
     keystore_name = _keystore_name
     keystore_password = _keystore_password
     rezip_apk = _load_library_from_apk
 
     public_deps = [
       # Generator of the _packaged_apk_path this target takes as input.
       ":$package_target",
     ]
   }
 
-  _final_deps = [ ":${_finalize_apk_rule_name}" ]
+  _managed_finalize_apk_rule_name = "${target_name}_managed__finalize"
+  finalize_apk(_managed_finalize_apk_rule_name) {
+    input_apk_path = _managed_packaged_apk_path
+    output_apk_path = _managed_final_apk_path
+    keystore_path = _keystore_path
+    keystore_name = _keystore_name
+    keystore_password = _keystore_password
+
+    public_deps = [
+      ":$_managed_package_target",
+    ]
+  }
+
+  _split_deps = []
 
   template("finalize_split") {
     finalize_apk(target_name) {
       _config = invoker.split_config
       _type = invoker.split_type
       input_apk_path = "${_resource_packaged_apk_path}_${_config}"
       _output_paths = process_file_template(
               [ _final_apk_path ],
               "{{source_dir}}/{{source_name_part}}-${_type}-${_config}.apk")
       output_apk_path = _output_paths[0]
       keystore_path = _keystore_path
       keystore_name = _keystore_name
       keystore_password = _keystore_password
       deps = [
         ":${_package_resources_target_name}",
       ]
     }
   }
 
   foreach(_split, _split_densities) {
     _split_rule = "${target_name}__finalize_${_split}_split"
     finalize_split(_split_rule) {
       split_type = "density"
       split_config = _split
     }
-    _final_deps += [ ":$_split_rule" ]
+    _split_deps += [ ":$_split_rule" ]
   }
   foreach(_split, _split_languages) {
     _split_rule = "${target_name}__finalize_${_split}_split"
     finalize_split(_split_rule) {
       split_type = "lang"
       split_config = _split
     }
-    _final_deps += [ ":$_split_rule" ]
+    _split_deps += [ ":$_split_rule" ]
   }
 
   group(target_name) {
-    public_deps = _final_deps
+    public_deps = [ ":${_finalize_apk_rule_name}" ] + _split_deps
+  }
+  group("${target_name}_managed") {
+    public_deps = [ ":${_managed_finalize_apk_rule_name}" ] + _split_deps
   }
 }
 
 template("java_prebuilt_impl") {
   set_sources_assignment_filter([])
   if (defined(invoker.testonly)) {
     testonly = invoker.testonly
   }
   _supports_android =
       defined(invoker.supports_android) && invoker.supports_android
@@ skipping 753 matching lines @@
     ]
     args = [
       "--depfile",
       rebase_path(depfile, root_build_dir),
       "--script-output-path",
       rebase_path(generated_script, root_build_dir),
     ]
     args += test_runner_args
   }
 }