Add support for decoding to 565 to libjpeg_turbo

simd/jsimd_arm_neon.S

 /*
  * ARMv7 NEON optimizations for libjpeg-turbo
  *
  * Copyright (C) 2009-2011 Nokia Corporation and/or its subsidiary(-ies).
  * All rights reserved.
  * Author: Siarhei Siamashka <siarhei.siamashka@nokia.com>
+ * Copyright (C) 2014 Linaro Limited.  All Rights Reserved.
  *
  * This software is provided 'as-is', without any express or implied
  * warranty.  In no event will the authors be held liable for any damages
  * arising from the use of this software.
  *
  * Permission is granted to anyone to use this software for any purpose,
  * including commercial applications, and to alter it and redistribute it
  * freely, subject to the following restrictions:
  *
  * 1. The origin of this software must not be misrepresented; you must not
@@ skipping 1322 matching lines @@
             vst4.8  {d10[2], d11[2], d12[2], d13[2]}, [RGB]!
             vst4.8  {d10[3], d11[3], d12[3], d13[3]}, [RGB]!
         .elseif \size == 2
             vst4.8  {d10[4], d11[4], d12[4], d13[4]}, [RGB]!
             vst4.8  {d10[5], d11[5], d12[5], d13[5]}, [RGB]!
         .elseif \size == 1
             vst4.8  {d10[6], d11[6], d12[6], d13[6]}, [RGB]!
         .else
             .error unsupported macroblock size
         .endif
+    .elseif \bpp == 16
+        .if \size == 8
+            vst1.16  {q15}, [RGB]!
+        .elseif \size == 4
+            vst1.16  {d30}, [RGB]!
+        .elseif \size == 2
+            vst1.16  {d31[0]}, [RGB]!
+            vst1.16  {d31[1]}, [RGB]!
+        .elseif \size == 1
+            vst1.16  {d31[2]}, [RGB]!
+        .else
+            .error unsupported macroblock size
+        .endif
     .else
         .error unsupported bpp
     .endif
 .endm
 
 .macro generate_jsimd_ycc_rgb_convert_neon colorid, bpp, r_offs, g_offs, b_offs
 
 /*
  * 2 stage pipelined YCbCr->RGB conversion
  */
@@ skipping 11 matching lines @@
     vmull.s16       q15, d7, d1[3] /* multiply by 29033 */
 .endm
 
 .macro do_yuv_to_rgb_stage2
     vrshrn.s32      d20, q10, #15
     vrshrn.s32      d21, q11, #15
     vrshrn.s32      d24, q12, #14
     vrshrn.s32      d25, q13, #14
     vrshrn.s32      d28, q14, #14
     vrshrn.s32      d29, q15, #14
-    vaddw.u8        q10, q10, d0
+    vaddw.u8        q11, q10, d0
     vaddw.u8        q12, q12, d0
     vaddw.u8        q14, q14, d0
-    vqmovun.s16     d1\g_offs, q10
+.if \bpp != 16
+    vqmovun.s16     d1\g_offs, q11
     vqmovun.s16     d1\r_offs, q12
     vqmovun.s16     d1\b_offs, q14
+.else /* rgb565 */
+    vqshlu.s16      q13, q11, #8
+    vqshlu.s16      q15, q12, #8
+    vqshlu.s16      q14, q14, #8
+    vsri.u16        q15, q13, #5
+    vsri.u16        q15, q14, #11
+.endif
 .endm
 
 .macro do_yuv_to_rgb_stage2_store_load_stage1
-    vld1.8          {d4}, [U, :64]!
+      /* "do_yuv_to_rgb_stage2" and "store" */
       vrshrn.s32      d20, q10, #15
+    /* "load" and "do_yuv_to_rgb_stage1" */
+    pld             [U, #64]
       vrshrn.s32      d21, q11, #15
+    pld             [V, #64]
       vrshrn.s32      d24, q12, #14
       vrshrn.s32      d25, q13, #14
+    vld1.8          {d4}, [U, :64]!
       vrshrn.s32      d28, q14, #14
     vld1.8          {d5}, [V, :64]!
       vrshrn.s32      d29, q15, #14
-      vaddw.u8        q10, q10, d0
+    vaddw.u8        q3, q1, d4     /* q3 = u - 128 */
+    vaddw.u8        q4, q1, d5     /* q2 = v - 128 */
+      vaddw.u8        q11, q10, d0
+    vmull.s16       q10, d6, d1[1] /* multiply by -11277 */
+    vmlal.s16       q10, d8, d1[2] /* multiply by -23401 */
       vaddw.u8        q12, q12, d0
       vaddw.u8        q14, q14, d0
-      vqmovun.s16     d1\g_offs, q10
+.if \bpp != 16 /**************** rgb24/rgb32 *********************************/
+      vqmovun.s16     d1\g_offs, q11
+    pld             [Y, #64]
+      vqmovun.s16     d1\r_offs, q12
     vld1.8          {d0}, [Y, :64]!
-      vqmovun.s16     d1\r_offs, q12
-    pld             [U, #64]
-    pld             [V, #64]
-    pld             [Y, #64]
       vqmovun.s16     d1\b_offs, q14
-    vaddw.u8        q3, q1, d4     /* q3 = u - 128 */
-    vaddw.u8        q4, q1, d5     /* q2 = v - 128 */
-      do_store        \bpp, 8
-    vmull.s16       q10, d6, d1[1] /* multiply by -11277 */
-    vmlal.s16       q10, d8, d1[2] /* multiply by -23401 */
     vmull.s16       q11, d7, d1[1] /* multiply by -11277 */
     vmlal.s16       q11, d9, d1[2] /* multiply by -23401 */
+      do_store        \bpp, 8
     vmull.s16       q12, d8, d1[0] /* multiply by 22971 */
     vmull.s16       q13, d9, d1[0] /* multiply by 22971 */
     vmull.s16       q14, d6, d1[3] /* multiply by 29033 */
     vmull.s16       q15, d7, d1[3] /* multiply by 29033 */
+.else /**************************** rgb565 ***********************************/
+      vqshlu.s16      q13, q11, #8
+    pld             [Y, #64]
+      vqshlu.s16      q15, q12, #8
+      vqshlu.s16      q14, q14, #8
+    vld1.8          {d0}, [Y, :64]!
+    vmull.s16       q11, d7, d1[1]
+    vmlal.s16       q11, d9, d1[2]
+      vsri.u16        q15, q13, #5
+    vmull.s16       q12, d8, d1[0]
+      vsri.u16        q15, q14, #11
+    vmull.s16       q13, d9, d1[0]
+    vmull.s16       q14, d6, d1[3]
+      do_store        \bpp, 8
+    vmull.s16       q15, d7, d1[3]
+.endif
 .endm
 
 .macro do_yuv_to_rgb
     do_yuv_to_rgb_stage1
     do_yuv_to_rgb_stage2
 .endm
 
 /* Apple gas crashes on adrl, work around that by using adr.
  * But this requires a copy of these constants for each function.
  */
@@ skipping 121 matching lines @@
 
 .endm
 
 /*--------------------------------- id ----- bpp R  G  B */
 generate_jsimd_ycc_rgb_convert_neon extrgb,  24, 0, 1, 2
 generate_jsimd_ycc_rgb_convert_neon extbgr,  24, 2, 1, 0
 generate_jsimd_ycc_rgb_convert_neon extrgbx, 32, 0, 1, 2
 generate_jsimd_ycc_rgb_convert_neon extbgrx, 32, 2, 1, 0
 generate_jsimd_ycc_rgb_convert_neon extxbgr, 32, 3, 2, 1
 generate_jsimd_ycc_rgb_convert_neon extxrgb, 32, 1, 2, 3
+generate_jsimd_ycc_rgb_convert_neon rgb565,  16, 0, 0, 0
 
 .purgem do_load
 .purgem do_store
 
 
 /*****************************************************************************/
 
 /*
  * jsimd_extrgb_ycc_convert_neon
  * jsimd_extbgr_ycc_convert_neon
@@ skipping 818 matching lines @@
 
     .unreq          OUTPTR
     .unreq          INPTR
     .unreq          WIDTH
     .unreq          TMP
 
 
 .purgem upsample16
 .purgem upsample32
 .purgem upsample_row