[mac] Make app shims look in the correct user data dir on Canary.

chrome/common/chrome_paths_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/common/chrome_paths_internal.h"
 
 #import <Foundation/Foundation.h>
 #include <string.h>
 
 #include <string>
@@ skipping 33 matching lines @@
   // From C.app/Contents/Versions/1.2.3.4, go up three steps to get to C.app.
   base::FilePath versioned_dir = chrome::GetVersionedDirectory();
   base::FilePath outer_app_dir = versioned_dir.DirName().DirName().DirName();
   const char* outer_app_dir_c = outer_app_dir.value().c_str();
   NSString* outer_app_dir_ns = [NSString stringWithUTF8String:outer_app_dir_c];
 
   return [[NSBundle bundleWithPath:outer_app_dir_ns] retain];
 }
 #endif  // !defined(OS_IOS)
 
-const char* ProductDirNameInternal() {
+char* ProductDirNameForBundle(NSBundle* chrome_bundle) {
   const char* product_dir_name = NULL;
 #if !defined(OS_IOS)
   base::mac::ScopedNSAutoreleasePool pool;
 
-  // Use OuterAppBundle() to get the main app's bundle. This key needs to live
-  // in the main app's bundle because it will be set differently on the canary
-  // channel, and the autoupdate system dictates that there can be no
-  // differences between channels within the versioned directory. This would
-  // normally use base::mac::FrameworkBundle(), but that references the
-  // framework bundle within the versioned directory. Ordinarily, the profile
-  // should not be accessed from non-browser processes, but those processes do
-  // attempt to get the profile directory, so direct them to look in the outer
-  // browser .app's Info.plist for the CrProductDirName key.
-  NSBundle* bundle = chrome::OuterAppBundle();
   NSString* product_dir_name_ns =
-      [bundle objectForInfoDictionaryKey:@"CrProductDirName"];
+      [chrome_bundle objectForInfoDictionaryKey:@"CrProductDirName"];
   product_dir_name = [product_dir_name_ns fileSystemRepresentation];
 #endif

[Mark Mentovai, 2013/04/03 17:52:01]

#else DCHECK(!chrome_bundle)

to ensure that nobody does anything with the argument on iOS thinking that it
has an effect?

 
   if (!product_dir_name) {
 #if defined(GOOGLE_CHROME_BUILD)
     product_dir_name = "Google/Chrome";
 #else
     product_dir_name = "Chromium";
 #endif
   }
 
   // Leaked, but the only caller initializes a static with this result, so it
   // only happens once, and that's OK.
   return strdup(product_dir_name);
 }
 
 // ProductDirName returns the name of the directory inside
 // ~/Library/Application Support that should hold the product application
 // data. This can be overridden by setting the CrProductDirName key in the
 // outer browser .app's Info.plist. The default is "Google/Chrome" for
 // officially-branded builds, and "Chromium" for unbranded builds. For the
 // official canary channel, the Info.plist will have CrProductDirName set
 // to "Google/Chrome Canary".
 std::string ProductDirName() {
-  static const char* product_dir_name = ProductDirNameInternal();
+#if defined(OS_IOS)
+  static const char* product_dir_name = ProductDirNameForBundle(nil);
+#else
+  // Use OuterAppBundle() to get the main app's bundle. This key needs to live
+  // in the main app's bundle because it will be set differently on the canary
+  // channel, and the autoupdate system dictates that there can be no
+  // differences between channels within the versioned directory. This would
+  // normally use base::mac::FrameworkBundle(), but that references the
+  // framework bundle within the versioned directory. Ordinarily, the profile
+  // should not be accessed from non-browser processes, but those processes do
+  // attempt to get the profile directory, so direct them to look in the outer
+  // browser .app's Info.plist for the CrProductDirName key.
+  static const char* product_dir_name =
+      ProductDirNameForBundle(chrome::OuterAppBundle());
+#endif
   return std::string(product_dir_name);
 }
 
+bool GetDefaultUserDataDirectoryForProduct(const std::string& product_dir,
+                                           base::FilePath* result) {
+  bool success = false;
+  if (result && PathService::Get(base::DIR_APP_DATA, result)) {
+    *result = result->Append(product_dir);
+    success = true;
+  }
+  return success;
+}
+
 }  // namespace
 
 namespace chrome {
 
 bool GetDefaultUserDataDirectory(base::FilePath* result) {
-  bool success = false;
-  if (result && PathService::Get(base::DIR_APP_DATA, result)) {
-    *result = result->Append(ProductDirName());
-    success = true;
-  }
-  return success;
+  return GetDefaultUserDataDirectoryForProduct(ProductDirName(), result);
 }
 
 bool GetUserDocumentsDirectory(base::FilePath* result) {
   return base::mac::GetUserDirectory(NSDocumentDirectory, result);
 }
 
 void GetUserCacheDirectory(const base::FilePath& profile_dir,
                            base::FilePath* result) {
   // If the profile directory is under ~/Library/Application Support,
   // use a suitable cache directory under ~/Library/Caches.  For
@@ skipping 91 matching lines @@
   return base::mac::GetLocalDirectory(NSApplicationSupportDirectory, result);
 }
 
 NSBundle* OuterAppBundle() {
   // Cache this. Foundation leaks it anyway, and this should be the only call
   // to OuterAppBundleInternal().
   static NSBundle* bundle = OuterAppBundleInternal();
   return bundle;
 }
 
+bool GetUserDataDirectoryForBrowserBundle(
+    NSBundle* bundle, base::FilePath* result) {

[Mark Mentovai, 2013/04/03 17:52:01]

Same thing with the wrapping on this line.

+  scoped_ptr_malloc<char> product_dir_name = ProductDirNameForBundle(bundle);
+  return GetDefaultUserDataDirectoryForProduct(product_dir_name.get(), result);
+}
+
 #endif  // !defined(OS_IOS)
 
 bool ProcessNeedsProfileDir(const std::string& process_type) {
   // For now we have no reason to forbid this on other MacOS as we don't
   // have the roaming profile troubles there.
   return true;
 }
 
 }  // namespace chrome