patch from chinmaygarde@ to make progress on mac, ios.

build/config/ios/rules.gni

Index: build/config/ios/rules.gni
diff --git a/build/config/ios/rules.gni b/build/config/ios/rules.gni
new file mode 100644
index 0000000000000000000000000000000000000000..f062233bcb16c1af35c68395a81364d0f0d1c193
--- /dev/null
+++ b/build/config/ios/rules.gni
@@ -0,0 +1,181 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+ios_app_script = "//build/config/ios/ios_app.py"
+
+template("code_sign_ios") {
+  assert(defined(invoker.entitlements_path),
+         "The path to the entitlements .xcent file")
+  assert(defined(invoker.identity), "The code signing identity")
+  assert(defined(invoker.application_path), "The application to code sign")
+  assert(defined(invoker.deps))
+
+  action(target_name) {
+    sources = [
+      invoker.entitlements_path,
+    ]
+
+    _application_path = invoker.application_path
+
+    script = ios_app_script
+
+    outputs = [
+      "$_application_path/_CodeSignature/CodeResources",
+    ]
+
+    args = [
+      "codesign",
+      "-p",
+      rebase_path(invoker.application_path, root_build_dir),
+      "-i",
+      invoker.identity,
+      "-e",
+      rebase_path(invoker.entitlements_path, root_build_dir),
+    ]
+
+    deps = invoker.deps

[brettw, 2015/08/04 18:07:28]

If you sync you can do:
  forward_variables_from(invoker, ["deps", "public_deps", "testonly",
"visibility"])
instead, which is a little simpler (also not public_deps addition which is good
practice).

[Dirk Pranke, 2015/08/04 18:27:15]

ack.

+    if (defined(invoker.testonly)) {
+      testonly = invoker.testonly
+    }
+  }
+}
+
+# TODO(GYP), TODO(dpranke): Should this be part of ios_app?
+template("resource_copy_ios") {
+  assert(defined(invoker.resources),
+         "The source list of resources to copy over")
+  assert(defined(invoker.bundle_directory),
+         "The directory within the bundle to place the sources in")
+  assert(defined(invoker.app_name), "The name of the application")
+
+  _bundle_directory = invoker.bundle_directory
+  _app_name = invoker.app_name
+  _resources = invoker.resources
+
+  copy(target_name) {
+    set_sources_assignment_filter([])
+    sources = _resources
+    outputs = [
+      "$root_build_dir/$_app_name.app/$_bundle_directory/{{source_file_part}}",
+    ]
+  }
+}
+
+template("ios_app") {
+  assert(defined(invoker.deps),
+         "Dependencies must be specified for $target_name")
+  assert(defined(invoker.info_plist),
+         "The application plist file must be specified for $target_name")
+  assert(defined(invoker.app_name),
+         "The iOS application name must be specified for $target_name")
+  assert(defined(invoker.entitlements_path),
+         "The entitlements path must be specified for $target_name")
+  assert(defined(invoker.code_signing_identity),
+         "The code_signing_identity must be specified for $target_name")
+
+  # We just create a variable so we can use the same in interpolation
+  app_name = invoker.app_name
+
+  if (defined(invoker.testonly)) {
+    testonly = invoker.testonly
+  }
+
+  struct_gen_target_name = target_name + "_struct"
+  plist_gen_target_name = target_name + "_plist"
+  bin_gen_target_name = target_name + "_bin"
+
+  # Generate the project structure
+  action(struct_gen_target_name) {

[sdefresne, 2015/08/04 07:42:01]

nit: this targets only creates directories as output, however, gn gen already
creates directories for all files listed in outputs, so I'm wondering whether it
is needed at all.

[brettw, 2015/08/04 18:07:28]

No idea, maybe try with it removed? Whatever you think is best is fine.

[Dirk Pranke, 2015/08/04 18:27:15]

I also think it is unnecessary but hadn't tested to confirm yet.

+    script = ios_app_script
+
+    sources = []

[brettw, 2015/08/04 18:07:28]

You can just delete this.

[Dirk Pranke, 2015/08/04 18:27:15]

ack.

+    outputs = [
+      "$root_build_dir/$app_name.app",
+    ]
+
+    args = [
+      "structure",
+      "-d",
+      rebase_path(root_build_dir),
+      "-n",
+      app_name,
+    ]
+  }

[brettw, 2015/08/04 18:07:28]

Can you set visibility on these intermediate targets so only the final group can
depend on them? You'll want to make a
  group_target_name = target_name
above since target_name will be changed inside these sub-targets.

[Dirk Pranke, 2015/08/04 18:27:15]

will do.

+
+  # Generate the executable
+  executable(bin_gen_target_name) {
+    output_name = "${app_name}.app/${app_name}"
+    if (defined(invoker.testonly)) {
+      testonly = invoker.testonly
+    }
+
+    if (defined(invoker.libs)) {
+      libs = invoker.libs
+    } else {
+      libs = []
+    }
+    libs += [
+      "UIKit.framework",
+      "QuartzCore.framework",
+      "OpenGLES.framework",
+    ]
+
+    deps = invoker.deps + [
+             ":$struct_gen_target_name",
+             ":$plist_gen_target_name",
+           ]
+  }
+
+  # Process the Info.plist
+  action(plist_gen_target_name) {
+    script = ios_app_script
+
+    sources = [
+      invoker.info_plist,
+    ]
+    outputs = [
+      "$root_build_dir/${app_name}.app/Info.plist",
+    ]
+
+    args = [
+      "plist",
+      "-i",
+      rebase_path(invoker.info_plist, root_build_dir),
+      "-o",
+      rebase_path("$root_build_dir/${app_name}.app"),
+    ]
+
+    deps = [
+      ":$struct_gen_target_name",
+    ]
+  }
+
+  # Perform Code Signing
+  code_sign_gen_target_name = target_name + "_codesign"
+  code_sign_ios(code_sign_gen_target_name) {
+    entitlements_path = invoker.entitlements_path
+    identity = invoker.code_signing_identity
+    application_path = "$root_build_dir/$app_name.app"
+    deps = [
+      ":$struct_gen_target_name",
+      ":$plist_gen_target_name",
+      ":$bin_gen_target_name",
+    ]
+    if (defined(invoker.testonly)) {

[brettw, 2015/08/04 18:07:28]

forward_variables_from(invoker, ["testonly"])

[Dirk Pranke, 2015/08/04 18:27:15]

ack.

+      testonly = invoker.testonly
+    }
+  }
+
+  # Top level group
+  group(target_name) {
+    deps = [

[brettw, 2015/08/04 18:07:28]

I'd do public_deps instead since you may want to take the outputs from here as
inputs to other stuff.

[Dirk Pranke, 2015/08/04 18:27:15]

Hm. I don't think so; this is declaring the ios_app(target_name) executables,
and I don't think anything will depend on the sub-targets of those. I'd prefer
to leave this as regular deps for now and change later if need be.

Unless I misunderstand something?

+      ":$struct_gen_target_name",
+      ":$plist_gen_target_name",
+      ":$bin_gen_target_name",
+    ]
+    if (invoker.code_signing_identity != "") {
+      deps += [ ":$code_sign_gen_target_name" ]
+    }
+  }
+}