Fix running gn gen for //ui/* targets on iOS.

ui/gfx/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/ui.gni")
 import("//testing/test.gni")
 
 if (is_android) {
   import("//build/config/android/config.gni")
   import("//build/config/android/rules.gni")
@@ skipping 488 matching lines @@
       "geometry/vector2d_unittest.cc",
       "geometry/vector3d_unittest.cc",
       "image/image_mac_unittest.mm",
       "image/image_util_unittest.cc",
       "mac/coordinate_conversion_unittest.mm",
       "nine_image_painter_unittest.cc",
       "platform_font_mac_unittest.mm",
       "range/range_mac_unittest.mm",
       "range/range_unittest.cc",
       "range/range_win_unittest.cc",
-      "render_text_unittest.cc",
       "sequential_id_generator_unittest.cc",
       "shadow_value_unittest.cc",
       "skbitmap_operations_unittest.cc",
       "skrect_conversion_unittest.cc",
       "transform_util_unittest.cc",
       "utf16_indexing_unittest.cc",
     ]
   }
 
+  if (!is_android && !is_ios) {

[danakj, 2015/07/22 18:26:23]

This looks the same as before? Why are you changing it?

[Dirk Pranke, 2015/07/22 18:49:36]

I think you're right that this is the same as before, logically. 

In GN code we've moved more to an additive style where 
we try to only list sources in += blocks, especially when we
can't count on sources_assignment_filter to strip them out.

However, such a change isn't required and we're not going
back through all of the code necessarily to rewrite things.

So I think this change is a win but only a minor one.

[sdefresne, 2015/07/23 07:38:03]

It is not identical, the previous code was (summarized):

if (!is_ios) {
  sources + = [ "render_text_unittest.cc" ]
}

if (is_android || is_ios) {
  sources -= [ "render_text_unittest.cc" ]
}

The second conditional was causing failures on iOS since it tried to remove a
file that was not in the sources list. My change uses the additive style.

+    sources += [ "render_text_unittest.cc" ]
+  }
+
   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 
   deps = [
     ":gfx",
     ":test_support",
     "//base",
     "//base/test:test_support",
     "//skia",
     "//third_party/icu:icuuc",
@@ skipping 13 matching lines @@
   }
 
   if (is_android) {
     sources -= [
       # Do not run display_change_notifier_unittest.cc on Android because it
       # does not compile display_observer.cc
       "display_change_notifier_unittest.cc",
     ]
   }
 
-  if (is_android || is_ios) {
-    sources -= [ "render_text_unittest.cc" ]
-  }
-
   if (use_aura) {
     sources -= [ "screen_unittest.cc" ]
-  } else {
+  } else if (!is_ios) {
     sources -= [ "nine_image_painter_unittest.cc" ]
   }
 
   if (is_chromeos) {
     sources += [ "chromeos/codec/jpeg_codec_robust_slow_unittest.cc" ]
   }
 
   if (is_win) {
     sources += [
       "color_profile_win_unittest.cc",
@@ skipping 21 matching lines @@
 if (is_android) {
   generate_jni("gfx_jni_headers") {
     sources = [
       "../android/java/src/org/chromium/ui/gfx/BitmapHelper.java",
       "../android/java/src/org/chromium/ui/gfx/DeviceDisplayInfo.java",
       "../android/java/src/org/chromium/ui/gfx/ViewConfigurationHelper.java",
     ]
     jni_package = "gfx"
   }
 }