Add country combobox to change country and rebuild address inputs.

chrome/browser/ui/cocoa/autofill/autofill_section_container.mm

 // Copyright (c) 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/autofill/autofill_section_container.h"
 
 #include <algorithm>
 
 #include "base/mac/foundation_util.h"
 #include "base/strings/sys_string_conversions.h"
@@ skipping 54 matching lines @@
     return true;
   }
 
   return section == autofill::SECTION_CC_BILLING;
 }
 
 }  // namespace
 
 @interface AutofillSectionContainer ()
 
-// A text field has been edited or activated - inform the delegate that it's
-// time to show a suggestion popup & possibly reset the validity of the input.
-- (void)textfieldEditedOrActivated:(NSControl<AutofillInputField>*)field
-                            edited:(BOOL)edited;
+// An input field has been edited or activated - inform the delegate and
+// possibly reset the validity of the input (if it's a textfield).
+- (void)fieldEditedOrActivated:(NSControl<AutofillInputField>*)field
+                        edited:(BOOL)edited;
 
 // Convenience method to retrieve a field type via the control's tag.
 - (autofill::ServerFieldType)fieldTypeForControl:(NSControl*)control;
 
 // Find the DetailInput* associated with a field type.
 - (const autofill::DetailInput*)detailInputForType:
     (autofill::ServerFieldType)type;
 
 // Takes an NSArray of controls and builds a FieldValueMap from them.
 // Translates between Cocoa code and delegate, essentially.
 // All controls must inherit from NSControl and conform to AutofillInputView.
 - (void)fillDetailOutputs:(autofill::FieldValueMap*)outputs
              fromControls:(NSArray*)controls;
 
 // Updates input fields based on delegate status. If |shouldClobber| is YES,
 // will clobber existing data and reset fields to the initial values.
 - (void)updateAndClobber:(BOOL)shouldClobber;
 
 // Return YES if this is a section that contains CC info. (And, more
 // importantly, a potential CVV field)
 - (BOOL)isCreditCardSection;
 
 // Create properly styled label for section. Autoreleased.
 - (NSTextField*)makeDetailSectionLabel:(NSString*)labelText;
 
 // Create a button offering input suggestions.
 - (MenuButton*)makeSuggestionButton;
 
-// Create a view with all inputs requested by |delegate_|. Autoreleased.
-- (LayoutView*)makeInputControls;
+// Create a view with all inputs requested by |delegate_| and resets |input_|.
+- (void)makeInputControls;
 
 // Refresh all field icons based on |delegate_| status.
 - (void)updateFieldIcons;
 
 // Refresh the enabled/disabled state of all input fields.
 - (void)updateEditability;
 
 @end
 
 @implementation AutofillSectionContainer
@@ skipping 33 matching lines @@
   if (![[self view] isHidden])
     [self validateFor:autofill::VALIDATE_EDIT];
 
   // Always request re-layout on state change.
   id delegate = [[view_ window] windowController];
   if ([delegate respondsToSelector:@selector(requestRelayout)])
     [delegate performSelector:@selector(requestRelayout)];
 }
 
 - (void)loadView {
-  // Keep a list of weak pointers to DetailInputs.
-  const autofill::DetailInputs& inputs =
-      delegate_->RequestedFieldsForSection(section_);
+  [self makeInputControls];
 
-  // Reverse the order of all the inputs.
-  for (int i = inputs.size() - 1; i >= 0; --i) {
-    detailInputs_.push_back(&(inputs[i]));
-  }
-
-  // Then right the reversal in each row.
-  std::vector<const autofill::DetailInput*>::iterator it;
-  for (it = detailInputs_.begin(); it < detailInputs_.end(); ++it) {
-    std::vector<const autofill::DetailInput*>::iterator start = it;
-    while (it != detailInputs_.end() &&
-           (*it)->length != autofill::DetailInput::LONG) {
-      ++it;
-    }
-    std::reverse(start, it);
-  }
-
-  inputs_.reset([[self makeInputControls] retain]);
   base::string16 labelText = delegate_->LabelForSection(section_);
   label_.reset(
       [[self makeDetailSectionLabel:base::SysUTF16ToNSString(labelText)]
           retain]);
 
   suggestButton_.reset([[self makeSuggestionButton] retain]);
   suggestContainer_.reset([[AutofillSuggestionContainer alloc] init]);
 
   view_.reset([[AutofillSectionView alloc] initWithFrame:NSZeroRect]);
   [self setView:view_];
@@ skipping 88 matching lines @@
   if (webEvent.type != content::NativeWebKeyboardEvent::RawKeyDown)
     return kKeyEventNotHandled;
 
   // Allow the delegate to intercept key messages.
   if (delegate_->HandleKeyPressEventInInput(webEvent))
     return kKeyEventHandled;
   return kKeyEventNotHandled;
 }
 
 - (void)onMouseDown:(NSControl<AutofillInputField>*)field {
-  [self textfieldEditedOrActivated:field edited:NO];
+  [self fieldEditedOrActivated:field edited:NO];
   [validationDelegate_ updateMessageForField:field];
 }
 
 - (void)fieldBecameFirstResponder:(NSControl<AutofillInputField>*)field {
   [validationDelegate_ updateMessageForField:field];
 }
 
 - (void)didChange:(id)sender {
-  [self textfieldEditedOrActivated:sender edited:YES];
+  [self fieldEditedOrActivated:sender edited:YES];
 }
 
 - (void)didEndEditing:(id)sender {
   delegate_->FocusMoved();
   [validationDelegate_ hideErrorBubble];
   [self validateFor:autofill::VALIDATE_EDIT];
   [self updateEditability];
 }
 
 - (void)updateSuggestionState {
@@ skipping 101 matching lines @@
 - (void)addInputsToArray:(NSMutableArray*)array {
   [array addObjectsFromArray:[inputs_ subviews]];
 
   // Only credit card sections can have a suggestion input.
   if ([self isCreditCardSection])
     [array addObject:[suggestContainer_ inputField]];
 }
 
 #pragma mark Internal API for AutofillSectionContainer.
 
-- (void)textfieldEditedOrActivated:(NSControl<AutofillInputField>*)field
-                            edited:(BOOL)edited {
-  AutofillTextField* textfield =
-      base::mac::ObjCCastStrict<AutofillTextField>(field);
-
-  // This only applies to textfields.
-  if (!textfield)
-    return;
-
+- (void)fieldEditedOrActivated:(NSControl<AutofillInputField>*)field
+                        edited:(BOOL)edited {
   autofill::ServerFieldType type = [self fieldTypeForControl:field];
-  base::string16 fieldValue = base::SysNSStringToUTF16([textfield fieldValue]);
+  base::string16 fieldValue = base::SysNSStringToUTF16([field fieldValue]);
 
   // Get the frame rectangle for the designated field, in screen coordinates.
   NSRect textFrameInScreen = [field convertRect:[field bounds] toView:nil];
   textFrameInScreen.origin =
       [[field window] convertBaseToScreen:textFrameInScreen.origin];
 
   // And adjust for gfx::Rect being flipped compared to OSX coordinates.
   NSScreen* screen = [[NSScreen screens] objectAtIndex:0];
   textFrameInScreen.origin.y =
       NSMaxY([screen frame]) - NSMaxY(textFrameInScreen);
   gfx::Rect textFrameRect(NSRectToCGRect(textFrameInScreen));
 
   delegate_->UserEditedOrActivatedInput(section_,
                                         type,
                                         [self view],
                                         textFrameRect,
                                         fieldValue,
                                         edited);
 
-  // If the field is marked as invalid, check if the text is now valid.
-  // Many fields (i.e. CC#) are invalid for most of the duration of editing,
-  // so flagging them as invalid prematurely is not helpful. However,
-  // correcting a minor mistake (i.e. a wrong CC digit) should immediately
-  // result in validation - positive user feedback.
-  if ([textfield invalid] && edited) {
-    base::string16 message = delegate_->InputValidityMessage(section_,
-                                                       type,
-                                                       fieldValue);
-    [textfield setValidityMessage:base::SysUTF16ToNSString(message)];
-    [validationDelegate_ updateMessageForField:textfield];
+  AutofillTextField* textfield = base::mac::ObjCCast<AutofillTextField>(field);
 
-    // If the field transitioned from invalid to valid, re-validate the group,
-    // since inter-field checks become meaningful with valid fields.
-    if (![textfield invalid])
-      [self validateFor:autofill::VALIDATE_EDIT];
+  // This only applies to textfields.
+  if (textfield) {

[groby-ooo-7-16, 2014/01/14 19:37:07]

You can skip this if - [textfield invalid] will evaluate to 'nil' for
non-textfields, because textfield is nil.

In fact, I suspect you don't even need to cast to AutofillTextField - this
behavior is only invoked via didChange, and keeping the same behavior for
comboboxes seems correct. Wondering whether the explanatory function of the cast
is worth the extra code.

[Dan Beam, 2014/01/15 03:10:48]

we talked about this offline and will change after this lands if we need to in
interest of keeping the same behavior for now

+    // If the field is marked as invalid, check if the text is now valid.
+    // Many fields (i.e. CC#) are invalid for most of the duration of editing,
+    // so flagging them as invalid prematurely is not helpful. However,
+    // correcting a minor mistake (i.e. a wrong CC digit) should immediately
+    // result in validation - positive user feedback.
+    if ([textfield invalid] && edited) {
+      base::string16 message = delegate_->InputValidityMessage(section_,
+                                                               type,
+                                                               fieldValue);
+      [textfield setValidityMessage:base::SysUTF16ToNSString(message)];
+      [validationDelegate_ updateMessageForField:textfield];
+
+      // If the field transitioned from invalid to valid, re-validate the group,
+      // since inter-field checks become meaningful with valid fields.
+      if (![textfield invalid])
+        [self validateFor:autofill::VALIDATE_EDIT];
+    }
   }
 
   // Update the icon if necessary.
   if (delegate_->FieldControlsIcons(type))
     [self updateFieldIcons];
   [self updateEditability];
 }
 
 - (autofill::ServerFieldType)fieldTypeForControl:(NSControl*)control {
   DCHECK([control tag]);
   return static_cast<autofill::ServerFieldType>([control tag]);
 }
 
 - (const autofill::DetailInput*)detailInputForType:
     (autofill::ServerFieldType)type {
   for (size_t i = 0; i < detailInputs_.size(); ++i) {
     if (detailInputs_[i]->type == type)
       return detailInputs_[i];
   }
   // TODO(groby): Needs to be NOTREACHED. Can't, due to the fact that tests
-  // blindly call setFieldValue:forInput:, even for non-existing inputs.
+  // blindly call setFieldValue:forType:, even for non-existing inputs.
   return NULL;
 }
 
 - (void)fillDetailOutputs:(autofill::FieldValueMap*)outputs
              fromControls:(NSArray*)controls {
   for (NSControl<AutofillInputField>* input in controls) {
     DCHECK([input isKindOfClass:[NSControl class]]);
     DCHECK([input conformsToProtocol:@protocol(AutofillInputField)]);
     outputs->insert(std::make_pair(
         [self fieldTypeForControl:input],
         base::SysNSStringToUTF16([input fieldValue])));
   }
 }
 
 - (NSTextField*)makeDetailSectionLabel:(NSString*)labelText {
   base::scoped_nsobject<NSTextField> label([[NSTextField alloc] init]);
   [label setFont:
       [[NSFontManager sharedFontManager] convertFont:[label font]
                                          toHaveTrait:NSBoldFontMask]];
   [label setStringValue:labelText];
   [label setEditable:NO];
   [label setBordered:NO];
   [label setDrawsBackground:NO];
   [label sizeToFit];
   return label.autorelease();
 }
 
 - (void)updateAndClobber:(BOOL)shouldClobber {
-  const autofill::DetailInputs& updatedInputs =
-      delegate_->RequestedFieldsForSection(section_);
+  if (shouldClobber) {
+    [self makeInputControls];
 
-  for (autofill::DetailInputs::const_iterator iter = updatedInputs.begin();
-       iter != updatedInputs.end();
-       ++iter) {
-    NSControl<AutofillInputField>* field = [inputs_ viewWithTag:iter->type];
-    DCHECK(field);
+    id delegate = [[view_ window] windowController];
+    if ([delegate respondsToSelector:@selector(requestRelayout)]) {
+      [delegate performSelector:@selector(requestRelayout)];
+    }
+  } else {
+    const autofill::DetailInputs& updatedInputs =
+        delegate_->RequestedFieldsForSection(section_);
 
-    if (shouldClobber || [field isDefault]) {
-      [field setFieldValue:base::SysUTF16ToNSString(iter->initial_value)];
+    for (autofill::DetailInputs::const_iterator iter = updatedInputs.begin();
+         iter != updatedInputs.end();
+         ++iter) {
+      NSControl<AutofillInputField>* field = [inputs_ viewWithTag:iter->type];
+      DCHECK(field);
+      if ([field isDefault])
+        [field setFieldValue:base::SysUTF16ToNSString(iter->initial_value)];
     }
-    if (shouldClobber)
-      [field setValidityMessage:@""];
+    [self updateFieldIcons];
   }
+
   [self updateEditability];
-  [self updateFieldIcons];
   [self modelChanged];
 }
 
 - (BOOL)isCreditCardSection {
   return section_ == autofill::SECTION_CC ||
       section_ == autofill::SECTION_CC_BILLING;
 }
 
 - (MenuButton*)makeSuggestionButton {
   base::scoped_nsobject<MenuButton> button([[MenuButton alloc] init]);
@@ skipping 20 matching lines @@
   [[button cell] setImage:image
            forButtonState:image_button_cell::kDisabledState];
 
   // ImageButtonCell's cellSize is not working. (http://crbug.com/298501)
   [button setFrameSize:[image size]];
   return button.autorelease();
 }
 
 // TODO(estade): we should be using Chrome-style constrained window padding
 // values.
-- (LayoutView*)makeInputControls {
+- (void)makeInputControls {
+  detailInputs_.clear();
+
+  // Keep a list of weak pointers to DetailInputs.
+  const autofill::DetailInputs& inputs =
+      delegate_->RequestedFieldsForSection(section_);
+
+  // Reverse the order of all the inputs.
+  for (int i = inputs.size() - 1; i >= 0; --i) {
+    detailInputs_.push_back(&(inputs[i]));
+  }
+
+  // Then right the reversal in each row.
+  std::vector<const autofill::DetailInput*>::iterator it;
+  for (it = detailInputs_.begin(); it < detailInputs_.end(); ++it) {
+    std::vector<const autofill::DetailInput*>::iterator start = it;
+    while (it != detailInputs_.end() &&
+           (*it)->length != autofill::DetailInput::LONG) {
+      ++it;
+    }
+    std::reverse(start, it);
+  }
+
   base::scoped_nsobject<LayoutView> view([[LayoutView alloc] init]);
   [view setLayoutManager:
       scoped_ptr<SimpleGridLayout>(new SimpleGridLayout(view))];
   SimpleGridLayout* layout = [view layoutManager];
 
   int column_set_id = 0;
   for (size_t i = 0; i < detailInputs_.size(); ++i) {
     const autofill::DetailInput& input = *detailInputs_[i];
 
     if (input.length == autofill::DetailInput::LONG)
@@ skipping 33 matching lines @@
           inputModel->GetItemAt(inputModel->GetDefaultIndex()))];
       control.reset(popup.release());
     } else {
       base::scoped_nsobject<AutofillTextField> field(
           [[AutofillTextField alloc] init]);
       [[field cell] setPlaceholderString:
           l10n_util::FixUpWindowsStyleLabel(input.placeholder_text)];
       NSString* tooltipText =
           base::SysUTF16ToNSString(delegate_->TooltipForField(input.type));
       if ([tooltipText length] > 0) {
-        DCHECK(!tooltipController_);
-        DCHECK(!tooltipField_);
-        tooltipController_.reset(
-            [[AutofillTooltipController alloc]
-                 initWithArrowLocation:info_bubble::kTopRight]);
+        if (!tooltipController_) {
+          tooltipController_.reset(
+              [[AutofillTooltipController alloc]
+                   initWithArrowLocation:info_bubble::kTopRight]);
+        }
         tooltipField_ = field.get();
         NSImage* icon =
             ui::ResourceBundle::GetSharedInstance().GetNativeImageNamed(
                 IDR_AUTOFILL_TOOLTIP_ICON).ToNSImage();
         [tooltipController_ setImage:icon];
         [tooltipController_ setMessage:tooltipText];
         [[field cell] setDecorationSize:[icon size]];
       }
       [field setDefaultValue:@""];
       control.reset(field.release());
     }
     [control setFieldValue:base::SysUTF16ToNSString(input.initial_value)];
     [control sizeToFit];
     [control setTag:input.type];
     [control setInputDelegate:self];
     // Hide away fields that cannot be edited.
     if (kColumnSetId == -1) {
       [control setFrame:NSZeroRect];
       [control setHidden:YES];
     }
     layout->AddView(control);
 
     if (input.length == autofill::DetailInput::LONG ||
         input.length == autofill::DetailInput::SHORT_EOL) {
       ++column_set_id;
     }
   }
 
   [self updateFieldIcons];
-  return view.autorelease();
+
+  if (inputs_)
+    [[self view] replaceSubview:inputs_ with:view];

[groby-ooo-7-16, 2014/01/14 19:37:07]

I'd post requestRelayout from here.

[Dan Beam, 2014/01/15 03:10:48]

Done.

+
+  inputs_ = view;
 }
 
 - (void)updateFieldIcons {
   autofill::FieldValueMap fieldValues;
   for (NSControl<AutofillInputField>* input in [inputs_ subviews]) {
     DCHECK([input isKindOfClass:[NSControl class]]);
     DCHECK([input conformsToProtocol:@protocol(AutofillInputField)]);
     autofill::ServerFieldType fieldType = [self fieldTypeForControl:input];
     NSString* value = [input fieldValue];
     fieldValues[fieldType] = base::SysNSStringToUTF16(value);
   }
 
   autofill::FieldIconMap fieldIcons = delegate_->IconsForFields(fieldValues);
   for (autofill::FieldIconMap::const_iterator iter = fieldIcons.begin();
        iter!= fieldIcons.end(); ++iter) {
     AutofillTextField* textfield = base::mac::ObjCCastStrict<AutofillTextField>(
         [inputs_ viewWithTag:iter->first]);
     [[textfield cell] setIcon:iter->second.ToNSImage()];
   }
 }
 
 - (void)updateEditability {
-
   base::scoped_nsobject<NSMutableArray> controls([[NSMutableArray alloc] init]);
   [self addInputsToArray:controls];
   for (NSControl<AutofillInputField>* control in controls.get()) {
     autofill::ServerFieldType type = [self fieldTypeForControl:control];
     const autofill::DetailInput* input = [self detailInputForType:type];
-    [control setEnabled:delegate_->InputIsEditable(*input, section_)];
+    if (input)
+      [control setEnabled:delegate_->InputIsEditable(*input, section_)];
   }
 }
 
 @end
 
 
 @implementation AutofillSectionContainer (ForTesting)
 
 - (NSControl*)getField:(autofill::ServerFieldType)type {
   return [inputs_ viewWithTag:type];
 }
 
 - (void)setFieldValue:(NSString*)text
               forType:(autofill::ServerFieldType)type {
   NSControl<AutofillInputField>* field = [inputs_ viewWithTag:type];
   if (field)
     [field setFieldValue:text];
 }
 
 - (void)setSuggestionFieldValue:(NSString*)text {
   [[suggestContainer_ inputField] setFieldValue:text];
 }
 
 - (void)activateFieldForType:(autofill::ServerFieldType)type {
   NSControl<AutofillInputField>* field = [inputs_ viewWithTag:type];
   if (field) {
     [[field window] makeFirstResponder:field];
-    [self textfieldEditedOrActivated:field edited:NO];
+    [self fieldEditedOrActivated:field edited:NO];
   }
 }
 
 @end